Olvasás angol nyelven

Megosztás a következőn keresztül:

A StorageBlobLogs tábla lekérdezései

  • Cikk

A lekérdezések Azure Portalon való használatáról további információt a Log Analytics oktatóanyagában talál. A REST API-val kapcsolatban lásd a Lekérdezést.

A leggyakoribb hibák

Listázz 10 leggyakoribb hibát az elmúlt 3 napban.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

A legtöbb hibát okozó műveletek

Az elmúlt 3 nap során a legtöbb hibát okozó 10 művelet listázása.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

A legnagyobb késéssel rendelkező műveletek

Listázhatja az első 10 műveletet, amely az elmúlt 3 nap leghosszabb végpontok közötti késését tartalmazza.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

Kiszolgálóoldali szabályozást okozó műveletek

Sorolja fel az összes olyan műveletet, amely kiszolgálóoldali szabályozási hibákat okoz az elmúlt 3 napban.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

Névtelen kérések megjelenítése

Sorolja fel az összes névtelen hozzáféréssel rendelkező kérést az elmúlt 3 napban.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

Gyakori műveleti diagram

Az elmúlt 3 napban használt műveletek kördiagramja.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart