Megosztás a következőn keresztül:

A FunctionAppLogs tábla lekérdezései

  • Cikk

A lekérdezések Azure Portalon való használatáról további információt a Log Analytics oktatóanyagában talál. A REST API-val kapcsolatban lásd a Lekérdezést.

Alkalmazásnaplók megjelenítése a Függvényalkalmazásokból

Az alkalmazásnaplók listája, idő szerint rendezve (a legújabb naplók jelennek meg először).

FunctionAppLogs 
| project TimeGenerated, HostInstanceId, Message, _ResourceId
| sort by TimeGenerated desc

Naplók megjelenítése figyelmeztetésekkel vagy kivételekkel

A figyelmeztetéseket vagy kivételeket tartalmazó naplók listája (a legújabb naplók jelennek meg először).

FunctionAppLogs
| where Level == "Warning" or Level == "Error"
| project TimeGenerated, HostInstanceId, Level, Message, _ResourceId
| sort by TimeGenerated desc

Hiba- és kivételszám

Az elmúlt órában figyelmeztetéseket vagy hibákat tartalmazó naplók számát ábrázoló oszlopdiagram megjelenítése alkalmazásonként.

FunctionAppLogs 
| where TimeGenerated > ago(1h)
| where Level == "Warning" or Level == "Error"
| summarize count_per_app = count() by _ResourceId
| sort by count_per_app desc 
| render columnchart

Függvénytevékenység idővel

A függvénykérelmek mennyiségének időbeli alakulását ábrázoló vonaldiagram.

FunctionAppLogs
//| where _ResourceId == "MyResourceId" // Uncomment and enter a resource ID to get results for a specific resource
| where Category startswith "Function." and Message startswith "Executed "
| summarize count() by bin(TimeGenerated, 1h), FunctionName // Aggregate by hour
| render timechart

Függvényeredmények

Az egyéni függvényhívás eredménye az utolsó óra (a legújabb naplók jelennek meg először).

FunctionAppLogs
| where TimeGenerated > ago(1h)
| where Category startswith "Function." and Message startswith "Executed "
| parse Message with "Executed '" Name "' ("  Result ", Id=" Id ", Duration=" Duration:long "ms)"
| project TimeGenerated, FunctionName, Result, FunctionInvocationId, Duration, _ResourceId
| sort by TimeGenerated desc

Függvényhibák aránya

A függvények sikeres és óránkénti hibáinak összegzése.

FunctionAppLogs
| where Category startswith "Function." and Message startswith "Executed "
| parse Message with "Executed '" Name "' ("  Result ", Id=" Id ", Duration=" Duration:long "ms)"
// | where Name == "MyFunction" // Use this to restrict to a specific function
| summarize count() by bin(TimeGenerated, 1h), Name, Result, _ResourceId
| order by TimeGenerated desc