Megosztás a következőn keresztül:

Az ACSBillingUsage tábla lekérdezései

  • Cikk

A lekérdezések Azure Portalon való használatáról további információt a Log Analytics oktatóanyagában talál. A REST API-val kapcsolatban lásd a Lekérdezést.

Hosszú hívások lekérése

Próbálkozzon újra az összes olyan hívástal, amely egy óránál tovább tartott.

ACSBillingUsage
| tolower(UsageType) == "audio" // only look at records that are calls
| extend Length = EndTime - StartTime
| where Length > 1h // return if the call is greater than an hour

Felhasználás részletezése

Lekérheti az óránkénti összes módot (vegye figyelembe, hogy a megjelenített első és utolsó órák részleges adatokat fognak jelölni).

ACSBillingUsage
| summarize Usage=sum(Quantity) by UsageType, bin(TimeGenerated, 1h) // count the number of units for each type of usage, per hour
| render columnchart

Rekordszám lebontása

Lekérheti az egyes üzemmódok óránkénti használati rekordjainak egyedi számát (vegye figyelembe, hogy a megjelenített első és utolsó órák részleges adatokat fognak jelölni).

ACSBillingUsage
| summarize Occurences=dcount(RecordId) by UsageType, bin(TimeGenerated, 1h) // count the number of unique records for each type of usage, per hour
| render columnchart

Résztvevő telefonszámai

A hívás résztvevőinek telefonszámait sorolja fel. (A telefonszámok az ACSBillingUsage táblából származnak).

ACSCallSummary
// Get the calls with CallType as Group
| where CallType == 'Group'
| project CorrelationId, ParticipantId, ParticipantStartTime, ParticipantDuration, EndpointType, CallType, CallStartTime, PstnParticipantCallType
// Join with ACSBillingUsage data on ParticipantId
| join kind=leftouter (ACSBillingUsage
                        | where isnotempty(ParticipantId)
                        | project ParticipantId, UserIdA, UserIdB, StartTime, Quantity)
    on ParticipantId
// Combine with calls of CallType P2P
| union (ACSCallSummary
| where CallType == 'P2P'
| project CorrelationId, ParticipantId, ParticipantStartTime, ParticipantDuration, EndpointType, CallType, CallStartTime, PstnParticipantCallType
// Join with ACSBillingUsage data on CorrelationId
| join kind=leftouter (ACSBillingUsage
                        | where isnotempty(ParticipantId)
                        | project CorrelationId, ParticipantId, UserIdA, UserIdB, StartTime, Quantity)
    on CorrelationId)
| order by CallStartTime, ParticipantStartTime