Az ASCDeviceEvents tábla lekérdezései

A lekérdezések Azure Portalon való használatáról további információt a Log Analytics oktatóanyagában talál. A REST API-val kapcsolatban lásd a Lekérdezést.

Azure Sphere-eszközhitelesítési és igazolási hibák

Az Azure Sphere eszközhitelesítési és igazolási hibáinak listája az elmúlt héten, idő szerint rendezve.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and
        Properties.EventType == "DeviceAttestationFailure" or Properties.EventType == "DeviceCertificateEvent" and
        ResultType == "Failure" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| project TimeGenerated, DeviceId, Properties, ResultDescription, Location
| sort by TimeGenerated desc
| limit 100

Azure Sphere-eszközesemények idővonala

Az Azure Sphere-eszköz által az elmúlt héten létrehozott összes esemény rendezett ütemterve a váratlan hibák monitorozásához és elhárításához.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" or Properties.DeviceTelemetryEventCategory == "AppCrash" // Remove/Add filters to see all/specific events. Filter data by Device by adding " | where DeviceId == "Your Device ID" " 
| project TimeGenerated, OperationName, ResultType, ResultDescription, Properties, Location
| sort by TimeGenerated desc
| limit 100

Azure Sphere-eszköz szívverési eseményeinek idődiagramja

Az Azure Sphere-eszközök által az elmúlt héten kezdeményezett összes tanúsítványgenerálási esemény idődiagramja az eszköz állapotának folyamatos monitorozásához és a trendek megtekintéséhez.

let Interval = timespan(1d); // Interval for the Chart 
ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and 
        Properties.EventType == "DeviceCertificatesGenerate" and 
        ResultType == "Success"
| summarize Device_Heartbeat_Events=count() by bin(TimeGenerated, Interval)
| render timechart

Az Azure Sphere-eszközök nem frissülnek a legújabb operációs rendszerre

Azoknak az Azure Sphere-eszközöknek a listája, amelyek az elmúlt héten nem frissültek a legújabb operációsrendszer-verzióra.

ASCDeviceEvents
| where OperationName == "DeviceUpdateEvent" and  
        todouble(Properties.InstalledOSVersion) != todouble(Properties.TargetedOSVersion) // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize by DeviceId
| limit 100

Az Azure Sphere-eszköz telemetriai eseményeinek összegzése

Az Azure Sphere-eszközök által az elmúlt héten létrehozott eseménykategóriák részarányát összegző kördiagram az eszköz általános állapotának monitorozásához.

ASCDeviceEvents
| where OperationName == "DeviceTelemetryEvent" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize count() by tostring(Properties.DeviceTelemetryEventCategory)
| render piechart