in~ işleci
Şunlar için geçerlidir: ✅Microsoft Fabric✅Azure Veri Gezgini✅ Azure İzleyici✅Microsoft Sentinel
Büyük/küçük harfe duyarlı olmayan bir dizeyle veriler için bir kayıt kümesini filtreler.
Aşağıdaki tabloda işleçlerin karşılaştırması in sağlanır:
| Operator | Açıklama | Büyük/Küçük Harfe Duyarlı | Örnek (verimler true) |
|---|---|---|---|
in |
Öğelerden birine eşittir | Yes | "abc" in ("123", "345", "abc") |
!in |
Öğelerin hiçbirine eşit değildir | Yes | "bca" !in ("123", "345", "abc") |
in~ |
Öğelerden herhangi birine eşittir | Hayır | "Abc" in~ ("123", "345", "abc") |
!in~ |
Öğelerin hiçbirine eşit değildir | Hayır | "bCa" !in~ ("123", "345", "ABC") |
Not
İç içe diziler tek bir değer listesinde düzleştirilir. Örneğin x in (dynamic([1,[2,3]])), x in (1,2,3) olur.
Diğer işleçler hakkında daha fazla bilgi edinmek ve sorgunuz için en uygun işleci belirlemek için bkz . veri türü dize işleçleri.
Büyük/küçük harfe duyarsız işleçler şu anda yalnızca ASCII metin için desteklenmektedir. ASCII olmayan karşılaştırma için tolower() işlevini kullanın.
Performans ipuçları
Not
128'den fazla arama terimi kullanıldığında, metin dizini arama iyileştirmesi devre dışı bırakılır ve bu da sorgu performansının düşmesine neden olabilir.
Not
Performans, arama türüne ve verilerin yapısına bağlıdır. En iyi yöntemler için bkz . Sorgu en iyi yöntemleri.
Mümkün olduğunda büyük/küçük harfe duyarlı seçeneğini kullanın.
Sözdizimi
T | where sütun (in~ ifadesi, ...)
Söz dizimi kuralları hakkında daha fazla bilgi edinin.
Parametreler
| Ad | Tür | Zorunlu | Açıklama |
|---|---|---|---|
| T | string |
✔️ | Filtre uygulamak için tablosal giriş. |
| Col | string |
✔️ | Filtreleneceği sütun. |
| ifade | skaler veya tablosal | ✔️ | Aranacak değerleri belirten ifade. Her ifade bir skaler değer veya bir dizi değer üreten bir tablosal ifade olabilir. Tablosal ifadede birden çok sütun varsa, ilk sütun kullanılır. Aramada en fazla 1.000.000 ayrı değer göz önünde bulundurulacaktır. |
Döndürülenler
Koşulun olduğu T'deki satırlartrue.
Örnekler
Skalerlerin listesi
Aşağıdaki sorguda virgülle ayrılmış skaler değerler listesiyle nasıl kullanılacağı in~ gösterilmektedir.
StormEvents
| where State in~ ("FLORIDA", "georgia", "NEW YORK")
| count
Çıktı
| Sayı |
|---|
| 4775 |
Dinamik dizi
Aşağıdaki sorguda dinamik dizi ile nasıl kullanılacağı in~ gösterilmektedir.
StormEvents
| where State in~ (dynamic(["FLORIDA", "georgia", "NEW YORK"]))
| count
Çıktı
| Sayı |
|---|
| 4775 |
Aynı sorgu let deyimiyle de yazılabilir.
let states = dynamic(["FLORIDA", "georgia", "NEW YORK"]);
StormEvents
| where State has_any (states)
| summarize count() by State
Çıktı
| Sayı |
|---|
| 4775 |
Tablosal ifade
Aşağıdaki sorguda satır içi tablosal ifadeyle nasıl kullanılacağı in~ gösterilmektedir. Satır içi tablosal ifadenin çift parantez içine alınması gerektiğine dikkat edin.
StormEvents
| where State in~ (PopulationData | where Population > 5000000 | project State)
| summarize count() by State
Çıktı
| State | count_ |
|---|---|
| TEXAS | 4701 |
| ILLINOIS | 2022 |
| MISSOURI | 2016 |
| GEORGIA | 1983 |
| MINNESOTA | 1881 |
| ... | ... |
Aynı sorgu let deyimiyle de yazılabilir. Son örnekte sağlanan çift ayraçların bu örnekte gerekli olmadığını fark edin.
let large_states = PopulationData | where Population > 5000000 | project State;
StormEvents
| where State in~ (large_states)
| summarize count() by State
Çıktı
| State | count_ |
|---|---|
| TEXAS | 4701 |
| ILLINOIS | 2022 |
| MISSOURI | 2016 |
| GEORGIA | 1983 |
| MINNESOTA | 1881 |
| ... | ... |