Aracılığıyla paylaş

in işleci

  • Makale

Şunlar için geçerlidir: ✅Microsoft Fabric✅

Büyük/küçük harfe duyarlı bir dize ile bir kayıt kümesini veriler için filtreler.

Aşağıdaki tabloda işleçlerin karşılaştırması in sağlanır:

Operator Açıklama Büyük/Küçük Harfe Duyarlı Örnek (verimler true)
in Öğelerden birine eşittir Yes "abc" in ("123", "345", "abc")
!in Öğelerin hiçbirine eşit değildir Yes "bca" !in ("123", "345", "abc")
in~ Öğelerden herhangi birine eşittir Hayır "Abc" in~ ("123", "345", "abc")
!in~ Öğelerin hiçbirine eşit değildir Hayır "bCa" !in~ ("123", "345", "ABC")

Not

İç içe diziler tek bir değer listesinde düzleştirilir. Örneğin x in (dynamic([1,[2,3]])), x in (1,2,3) olur.

Diğer işleçler hakkında daha fazla bilgi edinmek ve sorgunuz için en uygun işleci belirlemek için bkz . veri türü dize işleçleri.

Büyük/küçük harfe duyarsız işleçler şu anda yalnızca ASCII metin için desteklenmektedir. ASCII olmayan karşılaştırma için tolower() işlevini kullanın.

Performans ipuçları

Not

128'den fazla arama terimi kullanıldığında, metin dizini arama iyileştirmesi devre dışı bırakılır ve bu da sorgu performansının düşmesine neden olabilir.

Not

Performans, arama türüne ve verilerin yapısına bağlıdır. En iyi yöntemler için bkz . Sorgu en iyi yöntemleri.

Sözdizimi

T|wheresütunin( ifadesi, ...)

Söz dizimi kuralları hakkında daha fazla bilgi edinin.

Parametreler

Ad Tür Zorunlu Açıklama
T string ✔️ Filtre uygulamak için tablosal giriş.
Col string ✔️ Filtreleneceği sütun.
ifade skaler veya tablosal ✔️ Aranacak değerleri belirten ifade. Her ifade bir skaler değer veya bir dizi değer üreten bir tablosal ifade olabilir. Tablosal ifadede birden çok sütun varsa, ilk sütun kullanılır. Aramada en fazla 1.000.000 ayrı değer dikkate alınır.

Döndürülenler

Koşulun olduğu T'deki satırlartrue.

Örnekler

Skalerlerin listesi

Aşağıdaki sorguda skaler değerlerin listesiyle nasıl kullanılacağı in gösterilmektedir.

StormEvents 
| where State in ("FLORIDA", "GEORGIA", "NEW YORK") 
| count

Çıktı

Sayı
4775

Dinamik dizi

Aşağıdaki sorguda dinamik dizi ile nasıl kullanılacağı in gösterilmektedir.

let states = dynamic(['FLORIDA', 'ATLANTIC SOUTH', 'GEORGIA']);
StormEvents 
| where State in (states)
| count

Çıktı

Sayı
3218

Tablosal ifade

Aşağıdaki sorguda tablosal ifadeyle nasıl kullanılacağı in gösterilmektedir.

let Top_5_States = 
    StormEvents
    | summarize count() by State
    | top 5 by count_; 
StormEvents 
| where State in (Top_5_States) 
| count

Aynı sorgu satır içi tablosal ifade deyimiyle yazılabilir.

StormEvents 
| where State in (
    StormEvents
    | summarize count() by State
    | top 5 by count_
    ) 
| count

Çıktı

Sayı
14242

Diğer örnekle birlikte üst

Aşağıdaki örnek, şimşek olaylarıyla ilk beş durumu tanımlar ve yıldırım olaylarını eyalet adıyla etiketlenmiş ilk beş duruma ve diğer tüm diğer durumları "Diğer" olarak sınıflandırmak için iff() işlevini ve in işlecini kullanır.

let Lightning_By_State = materialize(StormEvents
    | summarize lightning_events = countif(EventType == 'Lightning') by State);
let Top_5_States = Lightning_By_State | top 5 by lightning_events | project State; 
Lightning_By_State
| extend State = iff(State in (Top_5_States), State, "Other")
| summarize sum(lightning_events) by State

Çıktı

State sum_lightning_events
ALABAMA 29
WISCONSIN 31
TEXAS 55
FLORIDA 85
GEORGIA 106
Diğer Kategori 415

İşlev tarafından döndürülen statik bir liste kullanma

Aşağıdaki örnek, StormEvents tablosundaki olayları, önceden tanımlanmış ilgi çekici durumların listesine göre sayar. İlginç durumlar InterestingStates() işlevi tarafından tanımlanır.

StormEvents 
| where State in (InterestingStates()) 
| count

Çıktı

Sayı
4775

Aşağıdaki sorgu, InterestingStates() işlevi tarafından ilgi çekici olarak kabul edilen durumları görüntüler.

.show function InterestingStates

Çıktı

Ad Parametreler Gövde Klasör DocString
InterestingStates () { dynamic(["WASHINGTON", "FLORIDA", "GEORGIA", "NEW YORK"]) }

İlgili içerik