Metode Session.Create

Membuat instans baru sumber daya dan mengembalikan referensi titik akhir (EPR) dari objek baru.

Sintaks

Session.Create( _
  ByVal resourceUri, _
  ByVal resource, _
  [ ByVal flags ] _
)

Parameter

resourceUri [in]

Pengidentifikasi sumber daya yang akan dibuat.

Parameter ini dapat berisi salah satu hal berikut:

• URI dengan satu atau beberapa pemilih. Ketahuilah bahwa plug-in WMI tidak mendukung pembuatan sumber daya apa pun selain pendengar Protokol Manajemen WS .
• Objek ResourceLocator yang mungkin berisi pemilih, fragmen, atau opsi.
• Referensi titik akhir WS-Addressing seperti yang dijelaskan dalam standar protokol WS-Management. Untuk informasi selengkapnya tentang spesifikasi publik untuk protokol WS-Management, lihat Halaman Indeks Spesifikasi Manajemen.

resource

XML yang berisi konten sumber daya.

bendera [in, opsional]

Dicadangkan. Harus diatur ke 0.

Nilai kembali

EPR sumber daya baru.

Keterangan

Session.Create hanya digunakan untuk membuat instans baru sumber daya. Gunakan metode Session.Put untuk memperbarui instans sumber daya yang ada. Setelah mendapatkan URI sumber daya baru, Anda dapat memanggil Session.Get untuk mengambil objek baru. Objek baru berisi properti apa pun yang ditetapkan penyedia sumber daya saat membuat objek baru. Misalnya, jika Anda membuat pendengar protokol WS-Management baru dan mengambil objek pendengar menggunakan Session.Get, maka Anda juga mendapatkan properti Port, Enabled, dan ListeningOn .

Ketahuilah bahwa plug-in WMI tidak mendukung pembuatan sumber daya apa pun selain pendengar protokol WS-Management.

Sintaks berikut digunakan untuk memanggil metode ini.

uri = session.Create("<resourceUri>", "<resource>")

Contoh

Contoh kode VBScript berikut memanggil Session.Create untuk membuat listener di komputer lokal.

'Create a WSMan object
Set oWsman = CreateObject( "WSMAN.Automation" )

'Create a Session object
Set oSession = oWsman.CreateSession

'Define resourceUri and inputXml 
resourceUri = "http://schemas.microsoft.com/wbem/wsman/1/"_
    & "config/Listener?Address=*+Transport=HTTP"

inputXml = _
    "<cfg:Listener xmlns:cfg=""https://schemas.dmtf.org/wbem/wsman/1/"_
    & "config/Listener.xsd"">" _
    & "<cfg:Hostname>" & GetFQDNName() & "</cfg:Hostname>" _            
    & "</cfg:Listener>"

'Perform the create operation.
response = oSession.Create( resourceUri, inputXml )
WScript.Echo "Response message: " & Chr(10) & response

Function GetFQDNName()
    Dim oShell, userDNSDomain, localComputerName
    Set oShell = CreateObject("WScript.Shell")
    userDNSDomain = oShell.ExpandEnvironmentStrings("%USERDNSDOMAIN%")

    localComputerName = _
        oShell.ExpandEnvironmentStrings("%ComputerName%")
    If userDNSDomain = "%USERDNSDOMAIN%" Then
        GetFQDNName= localComputerName
    Else
        GetFQDNName= localComputerName & "." & userDNSDomain
    End If
End Function

Persyaratan

Lihat juga

Sesi

Protokol Manajemen WS