Metode Session.Put

Updates sumber daya.

Sintaks

Session.Put( _
  ByVal resourceUri, _
  ByVal resource, _
  [ ByVal flags ] _
)

Parameter

resourceUri [in]

Pengidentifikasi sumber daya yang akan diperbarui.

Parameter ini dapat berisi salah satu elemen yang terkandung dalam daftar berikut:

• URI dengan atau tanpa pemilih. Saat memanggil metode Put untuk mendapatkan sumber daya WMI, gunakan properti kunci atau properti objek. Misalnya, dalam contoh kode Visual Basic Scripting Edition (VBScript) berikut, kunci ditentukan oleh Win32_Service?Name=winmgmt.

  strResourceUri = "http://schemas.microsoft.com/" & _ 
    "wbem/wsman/1/wmi/root/cimv2/Win32_Service?Name=winmgmt"
  

• Objek ResourceLocator yang mungkin berisi pemilih, fragmen, atau opsi.

• Referensi titik akhir WS-Addressing seperti yang dijelaskan dalam standar Protokol Manajemen WS. Untuk informasi selengkapnya tentang spesifikasi publik untuk protokol WS-Management, lihat Halaman Indeks Spesifikasi Manajemen.

resource [in]

Konten sumber daya yang diperbarui.

bendera [in, opsional]

Dicadangkan. Harus diatur ke 0.

Nilai kembali

XML yang berisi konten sumber daya yang diperbarui.

Contoh

Contoh kode VBScript berikut menulis data ke objek Win32_WMISetting . Anda harus menyertakan semua properti non-array objek dalam XML parameter Sumber Daya . Urutan properti tidak signifikan.

'Create a WSMan object.
Set objWsman = CreateObject( "WSMAN.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

'Create a Session object.
Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

'Change the property value by putting
'the new XML content into the resource.
Dim strResourceUri, strReturnedResourceUri, newXmlContent
strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/" _
  & "wmi/root/cimv2/Win32_WMISetting"
newXmlContent = _
  "<p:Win32_WMISetting xmlns:p=""http://schemas.microsoft.com/" & _
  "wbem/wsman/1/wmi/root/cimv2/Win32_WMISetting"">" & _
  "<p:LoggingLevel>2</p:LoggingLevel></p:Win32_WMISetting>" 

On Error Resume Next
strReturnedResourceUri = objSession.Put(reourceUri, newXmlContent)
WScript.Echo "Returned resource Uri:" & Chr(10) & _
  strReturnedResourceUri
If Err.Number <> 0 Then
    DisplayErrorInfo
End If
On Error Goto 0

Sub DisplayErrorInfo()
    WScript.Echo "An error has occurred."     
    WScript.Echo
    WScript.Echo "Error Info"
    WScript.Echo "-----------"
    WScript.Echo "Number      : 0x" & hex(Err.number)
    WScript.Echo "Description : " & Err.Description
    WScript.Echo "Source      : " & Err.Source
    WScript.Echo "HelpFile    : " & Err.helpfile
    WScript.Echo "HelpContext : " & Err.HelpContext    
    WScript.Echo Err.Clear    
End Sub

Persyaratan

Lihat juga

Sesi