Metode Enumerator.ReadItem

Mengambil item dari sumber daya dan mengembalikan representasi XML item.

Sintaks

Enumerator.ReadItem( _
  ByVal resource _
)

Parameter

resource

URI item.

Menampilkan nilai

Representasi XML item.

Keterangan

Untuk membatasi jumlah item yang dibaca, atur properti Session.BatchItems .

Perhatikan bahwa membebaskan objek enumerasi membersihkan permintaan enumerasi yang tertunda.

Metode Session.Enumerate tidak mendapatkan koleksi dengan cara yang sama seperti kueri WMI, seperti SELECT * from Win32_LogicalDisk, mengembalikan koleksi dalam SWbemObjectSet. Untuk membaca file sebagai aliran teks, Anda membuat objek TextStream skrip dan memanggil metode TextStream.Readline untuk membaca setiap baris file. Dengan cara yang sama, Anda memanggil metode Session.Enumerate untuk mendapatkan objek Enumerator lalu memanggil metode Enumerator.ReadItem . Seperti dalam membaca dari file teks, Anda dapat memeriksa properti Enumerator.AtEndOfStream untuk memeriksa apakah Anda telah mencapai akhir item data.

Contoh

Contoh VBScript berikut memanggil metode Session.Enumerate untuk mendapatkan daftar pekerjaan terjadwal. Sub-rutin DisplayOutput menggunakan file transformasi XML alat baris perintah Winrm (WsmTxt.xsl) untuk menghasilkan data dalam bentuk tabular.

Const RemoteComputer = "servername.domain.com"

Set objWsman = CreateObject( "WSMan.Automation" )
Set objSession = objWsman.CreateSession( "https://" & RemoteComputer )

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" &_
              "wmi/root/cimv2/Win32_ScheduledJob"

Set objResultSet = objSession.Enumerate( strResource )
NumOfJobs = 0

While Not objResultSet.AtEndOfStream
    NumOfJobs = NumOfJobs + 1
    DisplayOutput( objResultSet.ReadItem ) 
Wend

Wscript.Echo "There are " & NumOfJobs & " jobs scheduled."

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Persyaratan

Lihat juga

Enumerator

Menghitung atau Mencantumkan Semua Instans Sumber Daya