Metode Session.Enumerate

Menghitung tabel, pengumpulan data, atau sumber daya log. Untuk membuat kueri, sertakan parameter filter dan parameter dialek dalam enumerasi. Anda juga dapat menggunakan objek ResourceLocator untuk membuat kueri. Untuk informasi selengkapnya, lihat Menghitung atau Mencantumkan Semua Instans Sumber Daya.

Sintaks

Session.Enumerate( _
  ByVal resourceUri, _
  [ ByVal filter ], _
  [ ByVal dialect ], _
  [ ByVal flags ] _
)

Parameter

resourceUri [in]

Pengidentifikasi sumber daya yang akan diambil.

Parameter ini dapat berisi salah satu hal berikut:

• URI sumber daya.

  strResourceUri = "http://schemas.microsoft.com/" _ 
      & "wbem/wsman/1/wmi/root/cimv2/Win32_Service"
  

• Objek ResourceLocator .

• Referensi titik akhir WS-Addressing seperti yang dijelaskan dalam standar protokol WS-Management. Untuk informasi selengkapnya tentang spesifikasi publik untuk Protokol Manajemen WS, lihat Halaman Indeks Spesifikasi Manajemen.

filter [in, opsional]

Filter yang menentukan item apa dalam sumber daya yang dikembalikan oleh enumerasi. Saat sumber daya dijumlahkan, hanya item yang cocok dengan kriteria filter yang dikembalikan. Menyertakan parameter filter dan parameter dialek dalam enumerasi mengonversi enumerasi menjadi kueri. Misalnya, lihat Mengkueri Instans Tertentu dari Sumber Daya.

Jika Anda memiliki objek ResourceLocator untuk parameter resourceURI , parameter ini tidak boleh digunakan.

dialek [in, opsional]

Bahasa yang digunakan oleh filter. WQL, subset SQL yang digunakan oleh WMI, adalah satu-satunya bahasa yang didukung.

Jika Anda memiliki objek ResourceLocator untuk parameter resourceURI , parameter ini tidak boleh digunakan.

bendera [in, opsional]

Parameter yang harus berisi bendera dalam enumerasi __WSManEnumFlags . Untuk informasi selengkapnya, lihat Konstanta Enumerasi.

Mengembalikan nilai

Objek Enumerator yang berisi hasil enumerasi.

Keterangan

Untuk informasi selengkapnya tentang membatasi panggilan jaringan selama enumerasi, lihat properti BatchItems .

Ketahuilah bahwa jika bendera termasuk Enumeration ConstantsWSManFlagHierarchyDeepBasePropsOnly atau WSManFlagHierarchyShallow , maka layanan Manajemen Jarak Jauh Windows mengembalikan kode kesalahan ERROR_WSMAN_POLYMORPHISM_MODE_UNSUPPORTED.

Jika filter ditentukan, filter harus berupa dokumen yang valid sehubungan dengan skema sumber daya. Parameter dialek bersifat opsional. Namun, jika string filter dimulai dengan <, tetapi bukan fragmen XML, maka sertakan parameter dialek atau atur bendera WSManFlagNonXmlText di parameter bendera . Untuk informasi selengkapnya, lihat Konstanta Enumerasi.

Metode C++ yang sesuai adalah IWSManSession::Enumerate.

Contoh

Contoh kode VBScript berikut menghitung instans Win32_LogicalDisk pada komputer jarak jauh yang ditentukan oleh nama domain yang sepenuhnya memenuhi syarat (servername.domain.com). Ketahuilah bahwa membebaskan objek enumerasi menghapus permintaan enumerasi yang tertunda. Subroutine DisplayOutput menggunakan file transformasi XML alat baris perintah Winrm (WsmTxt.xsl) untuk menghasilkan data dalam bentuk tabular.

Const RemoteComputer = "servername.domain.com"
Set objWsman = CreateObject( "WSMan.Automation" )

Set objSession = objWsman.CreateSession( "https://" & REMOTECOMPUTER )

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" &_
              "wmi/root/cimv2/Win32_LogicalDisk"

Set objResultSet = objSession.Enumerate( strResource )

While Not objResultSet.AtEndOfStream
 
 DisplayOutput( objResultSet.ReadItem ) 

Wend

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Persyaratan

Lihat juga

Sesi

Mengkueri untuk Instans Tertentu dari Sumber Daya

BatchItems

ResourceLocator