Megosztás a következőn keresztül:

operátorban

  • Cikk

A következőkre vonatkozik: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Egy rekordhalmazt szűr egy kis- és nagybetűket megkülönböztető sztringgel.

Az alábbi táblázat a in operátorok összehasonlítását tartalmazza:

Operátor Leírás Case-Sensitive Példa (hozamok true)
in Egyenlő az egyik elemével Igen "abc" in ("123", "345", "abc")
!in Nem egyenlő az elemek egyikével sem Igen "bca" !in ("123", "345", "abc")
in~ Egyenlő az elemek bármelyikével Nem "Abc" in~ ("123", "345", "abc")
!in~ Nem egyenlő az elemek egyikével sem Nem "bCa" !in~ ("123", "345", "ABC")

Jegyzet

A beágyazott tömbök egyetlen értéklistába vannak beolvasva. x in (dynamic([1,[2,3]])) például x in (1,2,3)lesz.

További információ a többi operátorról, és annak meghatározásához, hogy melyik operátor a legmegfelelőbb a lekérdezéshez, tekintse meg adattípus-sztring operátorait.

A kis- és nagybetűket nem megkülönböztető operátorok jelenleg csak ASCII-szöveg esetén támogatottak. Nem ASCII összehasonlításhoz használja a tolower() függvényt.

Teljesítménytippek

Jegyzet

Ha több mint 128 keresési kifejezést használ, a szövegindex keresési optimalizálása le van tiltva, ami a lekérdezési teljesítmény csökkenéséhez vezethet.

Jegyzet

A teljesítmény a keresés típusától és az adatok szerkezetétől függ. Az ajánlott eljárásokért tekintse meg lekérdezési ajánlott eljárásokat.

Szintaxis

T|wherecolin(kifejezés, ... )

További információ szintaxiskonvenciákról.

Paraméterek

Név Típus Szükséges Leírás
T string ✔️ A szűrendő táblázatos bemenet.
col string ✔️ Az oszlop, amely alapján szűrni kell.
kifejezés skaláris vagy táblázatos ✔️ Egy kifejezés, amely meghatározza azokat az értékeket, amelyekre keresni szeretne. Minden kifejezés lehet egy skaláris érték, vagy egy táblázatos kifejezés,, amely értékkészletet hoz létre. Ha egy táblázatos kifejezés több oszlopot tartalmaz, az első oszlopot használja a rendszer. A keresés legfeljebb 1 000 000 különböző értéket tekint.

Visszatér

A T azon sorai, amelyeknél a predikátum true.

Példák

Skalárisok listája

Az alábbi lekérdezés bemutatja, hogyan használható in a skaláris értékek listájával.

StormEvents 
| where State in ("FLORIDA", "GEORGIA", "NEW YORK") 
| count

kimeneti

Gróf
4775

Dinamikus tömb

Az alábbi lekérdezés bemutatja, hogyan használható in dinamikus tömbökkel.

let states = dynamic(['FLORIDA', 'ATLANTIC SOUTH', 'GEORGIA']);
StormEvents 
| where State in (states)
| count

kimeneti

Gróf
3218

Táblázatos kifejezés

Az alábbi lekérdezés bemutatja, hogyan használható in táblázatos kifejezéssel.

let Top_5_States = 
    StormEvents
    | summarize count() by State
    | top 5 by count_; 
StormEvents 
| where State in (Top_5_States) 
| count

Ugyanez a lekérdezés beágyazott táblázatos kifejezési utasítással is írható.

StormEvents 
| where State in (
    StormEvents
    | summarize count() by State
    | top 5 by count_
    ) 
| count

kimeneti

Gróf
14242

Felül más példával

Az alábbi példa villámeseményekkel azonosítja az első öt állapotot, és a iff() függvénnyel és in operátorral osztályozza a villámeseményeket az első öt állapot szerint, államnév szerint címkézve, és az összes többi "Egyéb" címkével.

let Lightning_By_State = materialize(StormEvents
    | summarize lightning_events = countif(EventType == 'Lightning') by State);
let Top_5_States = Lightning_By_State | top 5 by lightning_events | project State; 
Lightning_By_State
| extend State = iff(State in (Top_5_States), State, "Other")
| summarize sum(lightning_events) by State

kimeneti

Állam sum_lightning_events
ALABAMA 29
WISCONSIN 31
TEXAS 55
FLORIDA 85
GRÚZIA 106
Más 415

Függvény által visszaadott statikus lista használata

Az alábbi példa a StormEvents táblából származó eseményeket számlálja meg az érdekes állapotok előre definiált listája alapján. Az érdekes állapotokat a InterestingStates() függvény határozza meg.

StormEvents 
| where State in (InterestingStates()) 
| count

kimeneti

Gróf
4775

Az alábbi lekérdezés megjeleníti, hogy a InterestingStates() függvény mely állapotokat tekinti érdekesnek.

.show function InterestingStates

kimeneti

Név Paraméterek Test Mappa DocString
InterestingStates () { dynamic(["WASHINGTON", "FLORIDA", "GEORGIA", "NEW YORK"]) }

Kapcsolódó tartalom