标准日期和时间格式字符串

标准日期和时间格式字符串使用单个字符作为格式说明符来定义时间和日期值的文本表示形式。 任何包含一个以上字符（包括空白）的日期和时间格式字符串都会作为自定义日期和时间格式字符串进行解释。 标准或自定义格式字符串可用于定义格式设置操作产生的文本表示形式。

格式说明符表

下表描述了标准日期和时间格式说明符。

标准格式字符串的工作原理

在格式设置操作中，标准格式字符串只是自定义格式字符串的别名。 使用别名引用自定义格式字符串的优点是：尽管别名保持固定不变，自定义格式字符串自身也可以变化。 这很重要，因为日期和时间值的字符串表示形式通常会因区域性而异。 例如，“d”标准格式字符串指示应使用短日期模式显示日期和时间值。 对于固定区域性，此模式为“MM/dd/yyyy”。 对于 fr-FR 区域性，此模式为“dd/MM/yyyy”。 对于 ja-JP 区域性，此模式为“yyyy/MM/dd”。

如果格式设置操作中的标准格式字符串映射到某个特定区域性的自定义格式字符串，则应用程序可定义该特定区域性，并通过以下方式之一使用其自定义格式字符串：

• 可使用默认的（或当前的）区域性。 下面的示例使用当前区域性的短日期格式显示日期。 在此情况下，当前区域性为 en-US。

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d"])
          //Displays 3/15/2024
      }
  in
      Source
  

• 可以根据该特定区域性的规则传递用于设置日期格式的区域性。 下面的示例使用 pt-BR 区域性的短日期格式显示日期。

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d", Culture = "pt-BR"])
          //Displays 15/03/2024
     }
  in
      Source
  

某些情况下，标准格式字符串用作固定不变的较长自定义格式字符串的简便缩写。 有四个标准格式字符串属于这一类别：“O”（或“o”）、“R”（或“r”）、“s”和“u”。 这些字符串对应于由固定区域性定义的自定义格式字符串。 通过这些字符串得到的日期和时间值的字符串表示形式在各个区域性中都应是相同的。 下表提供了有关这四个标准日期和时间格式字符串的信息。

标准格式字符串也可用于分析操作，这要求输入字符串完全符合特定模式，使分析操作成功。 许多标准格式字符串映射到多个自定义格式字符串，因此日期和时间值可以用各种格式表示，分析操作仍然成功。

以下部分介绍 Date、DateTime、DateTimeZone 和 Time 值的标准格式说明符。

日期格式

此组包括以下格式：

• 短日期（“d”）格式说明符
• 长日期（“D”）格式说明符

短日期（“d”）格式说明符

“d”标准格式说明符表示由特定区域性定义的自定义日期格式。 例如，固定区域性返回的自定义格式文本为“MM/dd/yyy”。

以下示例使用“d”格式说明符显示日期值。

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = ""]),
        // Displays 04/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-US"]),
        // Displays 4/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-NZ"]),
        // Displays 10/4/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "de-DE"])
        // Displays 10.4.2024
    }
in
    Source

返回表首

长日期（“D”）格式说明符

“D”标准格式说明符表示由特定区域性定义的自定义日期格式。 例如，用于固定区域性的自定义格式字符串为“dddd, dd MMMM yyyy”。

下面的示例使用“D”格式说明符来显示日期和时间值。

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = ""]),
        // Displays Wednesday, 10 April, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "pt-BR"]),
        // Displays quarta-feira, 10 de abril de 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "es-MX"])
        // Displays miércoles, 10 de abril de 2024
    }
in
    Source

返回表首

日期和时间格式

此组包括以下格式：

• 完整日期短时间（“f”）格式说明符
• 完整日期长时间（“F”）格式说明符
• 常规日期短时间（“g”）格式说明符
• 常规日期长时间（“G”）格式说明符
• 往返（“O”、“o”）格式说明符
• RFC1123（“R”、“r”）格式说明符
• 可排序（“s”）格式说明符
• 通用可排序（“u”）格式说明符

完整日期短时间（“f”）格式说明符

“f”标准格式说明符表示长日期（“D”）和短时间（“t”）模式的组合，由空格分隔。

结果字符串受特定区域性的格式设置信息的影响。

下面的示例使用“f”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30
    }
in
    Source

返回表首

完整日期长时间（“F”）格式说明符

“F”标准格式说明符表示由特定区域性定义的自定义日期和时间格式。 例如，用于固定区域性的自定义格式字符串为“dddd, dd MMMM yyyy HH:mm:ss”。

结果字符串受特定区域性的格式设置信息的影响。

下面的示例使用“F”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = ""]),
        // Displays Wednesday, 10 April, 2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30:00
    }
in
    Source

返回表首

常规日期短时间（“g”）格式说明符

“g”标准格式说明符表示短日期（“d”）和短时间（“t”）模式的组合，由空格分隔。 生成的文本受特定区域性的格式设置信息的影响。

结果字符串受特定区域性的格式设置信息的影响。

下面的示例使用“g”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = ""]),
        // Displays 04/10/2024 06:30

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "en-US"]),
        // Displays 4/10/2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "fr-BE"])
        // Displays 10-04-24 06:30
    }
in
    Source

返回表首

常规日期长时间（“G”）格式说明符

“G”标准格式说明符表示短日期（“d”）和长时间（“T”）模式的组合，由空格分隔。 生成的文本受特定区域性的格式设置信息的影响。

结果字符串受特定区域性的格式设置信息的影响。

下面的示例使用“G”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = ""]),
        // Displays 04/10/2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "en-US"]),
        // Displays 4/10/2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "nl-BE"])
        // Displays 10/04/2024 6:30:00
    }
in
    Source

返回表首

往返（“O”、“o”）格式说明符

“O”或“o”标准格式说明符表示使用保留时区信息的模式的自定义日期和时间格式字符串，并发出符合 ISO8601 的结果字符串。 对于 DateTimeZone 值，此格式说明符旨在保留文本中的日期、时间和时区值。

“O”或“o”标准格式说明符对应于“yyyy'-'MM'-'dd'T'HH'：'mm'：'ss'”。DateTimeZone 值的 fffffffxxx“自定义格式字符串。 在此文本中，分隔各个字符的单引号对，如连字符、冒号和字母“T”，表示单个字符是无法更改的文本。 撇号不会显示在输出字符串中。

“O”或“o”标准格式说明符（以及“yyyy'-'MM'-'dd'T'HH'：'mm'：'ss'”。fffffffxxx“自定义格式）利用 ISO 8601 表示时区信息的方式来保留 DateTimeZone 值：

• DateTimeZone.ToLocal 日期和时间值的时区组件是 UTC 的偏移量（例如，+01：00、-07：00）。

• DateTimeZone.ToUtc 日期和时间值的时区组件使用 +00.00 表示 UTC。

由于“O”或“o”标准格式说明符遵循国际标准，使用说明符的格式设置或分析操作始终使用固定区域性和公历。

以下示例使用“o”格式说明符在美国太平洋时区的系统上显示一系列 DateTimeZone 值。

let
    date1 = #datetimezone(2024, 6, 15, 13, 45, 30, 0, 0),
    Source =
    {
        Text.Format("#{0} (Unspecified) --> #{1}", {date1, DateTimeZone.ToText(date1, [Format = "O"])}),
        Text.Format("#{0} (Utc) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToUtc(date1), [Format = "O"])}),
        Text.Format("#{0} (Local) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToLocal(date1), [Format = "O"])})
    }
in
    Source

// The example displays the following output:
//    6/15/2024 1:45:30 PM +00:00 (Unspecified) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Utc) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Local) --> 2024-06-15T08:45:30.0000000-07:00

以下示例使用“o”格式说明符创建格式化字符串，然后通过调用日期和时间分析例程来还原原始日期和时间值。

let
    // Round-trip a local time
    #"Origin Local Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0)
    ),
    #"Local Date Text" = DateTimeZone.ToText(
        #"Origin Local Date", [Format = "o"]
    ),
    #"New Local Date" = DateTimeZone.FromText(#"Local Date Text"),
    #"Local Round Trip" = Text.Format(
        "Round-tripped #{0} Local to #{1} Local.", 
        {
            DateTimeZone.ToText(#"Origin Local Date"), 
            DateTimeZone.ToText(#"New Local Date")
        }
    ),

    // Round-trip a UTC time
    #"Origin UTC Date" = DateTimeZone.ToUtc(
        #datetimezone(2024, 4, 12, 9, 30, 0, 0, 0)
    ),
    #"UTC Date Text" = DateTimeZone.ToText(
        #"Origin UTC Date", [Format = "o"]
    ),
    #"New UTC Date" = DateTimeZone.FromText(#"UTC Date Text"),
    #"UTC Round Trip" = Text.Format(
        "Round-tripped #{0} UTC to #{1} UTC.", 
        {
            DateTimeZone.ToText(#"Origin UTC Date"), 
            DateTimeZone.ToText(#"New UTC Date")
        }
    ),

    // Round-trip an 18 hour offset time
    #"Origin Offset Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0) + #duration(0, 18, 0, 0)
    ),
    #"Offset Date Text" = DateTimeZone.ToText(
        #"Origin Offset Date", [Format = "o"]
    ),
    #"New Offset Date" = DateTimeZone.FromText(#"Offset Date Text"),
    #"Offset Round Trip" = Text.Format(
        "Round-tripped #{0} to #{1}.", 
        {
            DateTimeZone.ToText(#"Origin Offset Date"), 
            DateTimeZone.ToText(#"New Offset Date")
        }
    ),

    #"Round Trip Results" = 
        {#"Local Round Trip", #"UTC Round Trip", #"Offset Round Trip"}
in
    #"Round Trip Results"

// The example displays the following output in Power Query Desktop:
//    Round-tripped 4/9/2024 11:30:00 PM -07:00 Local to 4/9/2024 11:30:00 PM -07:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/10/2024 5:30:00 PM -07:00 to 4/10/2024 5:30:00 PM -07:00.

// The example displays the following output in Power Query Online:
//    Round-tripped 4/10/2024 6:30:00 AM +00:00 Local to 4/10/2024 6:30:00 AM +00:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/11/2024 12:30:00 AM +00:00 to 4/11/2024 12:30:00 AM +00:00.

返回表首

RFC1123（“R”、“r”）格式说明符

“R”或“r”标准格式说明符表示未由特定区域性定义的自定义日期和时间格式字符串。 无论使用的区域性还是提供的格式提供程序，它始终相同。 定义格式字符串为“ddd, dd MMM yyyy HH':'mm':'ss 'GMT'”。 当使用此标准格式说明符时，格式设置或分析操作始终使用固定区域性。

尽管 RFC 1123 标准将时间表示为协调世界时（UTC），但格式设置操作不会修改正在设置格式的日期和时间的值。 因此，在执行格式设置操作之前，必须通过调用 DateTimeZone.ToUtc 函数方法将 DateTime 值转换为 UTC。

以下示例使用“r”格式说明符在美国太平洋时区（UTC 落后 7 小时）的系统上显示时间和日期值。

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source = 
    {
        DateTimeZone.ToText(date1, [Format = "r"]),
        // Displays Wed, 10 Apr 2024 13:30:00 GMT

        DateTimeZone.ToText(dateOffset, [Format = "r"])
        // Displays Wed, 10 Apr 2024 13:30:00 GMT
    }
in
    Source

返回表首

可排序（“s”）格式说明符

“s”标准格式说明符表示一个自定义日期和时间格式字符串，该字符串反映定义的标准（ISO 8601），并且是只读的。 因此，无论所使用的区域性或所提供的格式提供程序是什么，它总是相同的。 自定义格式字符串为“yyyy'-'MM'-'dd'T'HH':'mm':'ss”。 使用“s”格式说明符的目的是使生成的结果字符串基于日期和时间值一致按升序或降序顺序进行排序。

当使用此标准格式说明符时，格式设置或分析操作始终使用固定区域性。

以下示例使用“s”格式说明符在美国太平洋时区的系统上显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "s", Culture = "en-US"])
        // Displays 2024-04-10T06:30:00
    }
in
    Source

返回表首

通用可排序（“u”）格式说明符

“u”标准格式说明符表示一个自定义日期和时间格式字符串，无论使用哪种区域性或提供的格式提供程序都相同。 自定义格式字符串为“yyyy'-'MM'-'dd HH':'mm':'ss'Z'”。 该模式反映已定义的标准，并且属性是只读的。 当使用此标准格式说明符时，格式设置或分析操作始终使用固定区域性。

尽管结果字符串应将时间表示为协调世界时（UTC），但在格式设置操作期间不会执行原始 DateTimeZone 值转换。 因此，必须先通过调用 DateTimeZone.ToUtc 函数来将 DateTimeZone 值转换为 UTC，然后才能设置其格式。

下面的示例使用“u”格式说明符来显示日期和时间值。

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source =
    {
        DateTimeZone.ToText(dateOffset, [Format = "u"]),
        // Displays 2024-04-10 13:30:00Z
    }
in
    Source

返回表首

时间格式

此组包括以下格式：

• 短时间（“t”）格式说明符
• 长时间（“T”）格式说明符

短时间（“t”）格式说明符

“t”标准格式说明符表示由指定区域性定义的自定义日期和时间格式字符串。 例如，用于固定区域性的自定义格式字符串为“HH:mm”。

结果字符串受特定区域性的格式设置信息的影响。

下面的示例使用“t”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = ""]),
        // Displays 06:30
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "en-US"]),
        // Displays 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "es-ES"])
        // Displays 6:30
    }
in
    Source

返回表首

长时间（“T”）格式说明符

“T”标准格式说明符表示由特定区域性定义的自定义日期和时间格式字符串。 例如，用于固定区域性的自定义格式字符串为“HH:mm:ss”。

下面的示例使用“T”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = ""]),
        // Displays 06:30:00
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "en-US"]),
        // Displays 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "es-ES"])
        // Displays 6:30:00
    }
in
    Source

返回表首

部分日期格式

此组包括以下格式：

• 月（“M”、“m”）格式说明符
• 年月（“Y”、“y”）格式说明符

月（“M”、“m”）格式说明符

“M”或“m”标准格式说明符表示由特定区域性定义的自定义日期和时间格式字符串。 例如，用于固定区域性的自定义格式字符串为“MMMM dd”。

下面的示例使用“m”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = ""]),
        // Displays April 10
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "en-US"]),
        // Displays April 10

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "ms-MY"])
        // Displays 10 April
    }
in
    Source

返回表首

年月（“Y”、“y”）格式说明符

“Y”或“y”标准格式说明符表示由特定区域性定义的自定义日期格式字符串。 例如，用于固定区域性的自定义格式字符串为“yyyy MMMM”。

下面的示例使用“y”格式说明符来显示日期和时间值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = ""]),
        // Displays 2024 April
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = "en-US"]),
        // Displays April 2024

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "y", Culture = "af-ZA"])
        // Displays April 2024
    }
in
    Source

返回表首

相关内容

• 区域性如何影响文本格式
• Date、Time、DateTime 和 DateTimeZone 类型转换
• 日期函数
• 日期/时间函数
• 日期/时间/时区函数
• 时间函数
• 自定义日期和时间格式字符串