Aracılığıyla paylaş

Table.TransformColumnTypes

  • Makale

Sözdizimi

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

Hakkında

İsteğe bağlı bir kültür kullanarak belirtilen sütunlara dönüştürme işlemlerini uygulayarak bir tablo döndürür.

  • table: Dönüştürülecek giriş tablosu.
  • typeTransformations: Uygulanacak tür dönüşümleri. Tek bir dönüştürmenin biçimi { sütun adı, tür değeri } şeklindedir. Dönüştürmelerin listesi, aynı anda birden fazla sütun türünü değiştirmek için kullanılabilir. Eğer bir sütun yoksa, bir hata verilir.
  • culture: (İsteğe bağlı) Sütun türlerini dönüştürürken kullanılacak kültür (örneğin, "en-US").

typeTransformations parametresindeki tür değeri any, tüm number türleri, text, tüm date, time, datetime, datetimezoneve duration türleri, logicalveya binaryolabilir. list, record, tableveya function türleri bu parametre için geçerli değildir.

Örnek 1

İlk sütundaki sayı değerlerini metin değerlerine dönüştürün.

Kullanım

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

çıkış

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Örnek 2

Tablodaki tarihleri Fransızca metin eşdeğerlerine dönüştürün.

Kullanım

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

çıkış

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

Örnek 3

Tablodaki tarihleri Almanca metin eşdeğerlerine ve tablodaki değerleri yüzdelere dönüştürün.

Kullanım

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

çıkış

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

İlgili içerik