CALCULATE

Şunlar için geçerlidir:Hesaplanan sütunHesaplanan tabloÖlçüGörsel hesaplama

Değiştirilen filtre bağlamındaki bir ifadeyi değerlendirir.

Sözdizimi

CALCULATE(<expression>[, <filter1> [, <filter2> [, …]]])

Parametre

İlk parametre olarak kullanılan ifade temelde bir ölçüyle aynıdır.

Filtreler şu şekilde olabilir:

• Boole filtre ifadeleri
• Tablo filtresi ifadeleri
• Filtre değiştirme işlevleri

Birden çok filtre olduğunda, bunlar AND (&&) mantıksal işleçkullanılarak değerlendirilebilir. Bu, tüm koşulların TRUEolması gerektiği anlamına gelir veya OR (||) mantıksal işleci tarafından (koşullardan birinin doğru olabileceği anlamına gelir).

Boole filtre ifadeleri

Boole ifade filtresi, TRUE veya FALSEolarak değerlendirilen bir ifadedir. Uymaları gereken birkaç kural vardır:

• Tek bir tablodaki sütunlara başvurabilir.
• Ölçülere başvuramazlar.
• İç içe CALCULATE işlevi kullanamazlar.

Power BI Desktop'ın Eylül 2021 sürümünden itibaren aşağıdakiler de geçerlidir:

• Toplama işlevlerine bağımsız değişken olarak geçirilmedikçe tabloyu tarayabilen veya döndüren işlevleri kullanamazlar.
• Bunlar skaler değer döndüren bir toplama işlevi içerebilir. Mesela

  Total sales on the last selected date =
  CALCULATE (
      SUM ( Sales[Sales Amount] ),
      'Sales'[OrderDateKey] = MAX ( 'Sales'[OrderDateKey] )
  )
  

Tablo filtresi ifadesi

Tablo ifadesi filtresi, bir tablo nesnesini filtre olarak uygular. Bir model tablosuna başvuru olabilir, ancak büyük olasılıkla tablo nesnesi döndüren bir işlevdir. Boole filtre ifadesi tarafından tanımlanamayanlar da dahil olmak üzere karmaşık filtre koşulları uygulamak için FILTER işlevini kullanabilirsiniz.

Filtre değiştirici işlevleri

Filtre değiştirici işlevleri, yalnızca filtre eklemekten daha fazlasını yapmanıza olanak sağlar. Filtre bağlamı değiştirilirken size ek denetim sağlar.

¹ALL işlevi ve varyantları hem filtre değiştiricileri hem de tablo nesnelerini döndüren işlevler olarak davranır. REMOVEFILTERS işlevi aracınız tarafından destekleniyorsa filtreleri kaldırmak için kullanmak daha iyidir.

Dönüş değeri

İfadenin sonucu olan değer.

Açıklamalar

• Filtre ifadeleri sağlandığında, CALCULATE işlevi ifadeyi değerlendirmek için filtre bağlamını değiştirir. Her filtre ifadesi için, filtre ifadesi KEEPFILTERS işlevinde sarmalanmadığında iki olası standart sonuç vardır:

  • Sütunlar (veya tablolar) filtre bağlamında değilse, ifadeyi değerlendirmek için filtre bağlamlarına yeni filtreler eklenir.
  • Sütunlar (veya tablolar) zaten filtre bağlamındaysa, CALCULATE ifadesini değerlendirmek için yeni filtreler mevcut filtrelerin üzerine yazılır.

• Filtreler olmadan kullanılan CALCULATE işlevi belirli bir gereksinime ulaşır. Filtre bağlamı için satır bağlamı geçirir. Model verilerini özetleyen bir ifadenin (model ölçüsü değil) satır bağlamında değerlendirilmesi gerektiğinde gereklidir. Bu senaryo, hesaplanan sütun formülünde veya yineleyici işlevindeki bir ifade değerlendirildiğinde gerçekleşebilir. Satır bağlamında bir model ölçüsü kullanıldığında bağlam geçişinin otomatik olduğunu unutmayın.

• Bu işlev, hesaplanan sütunlarda veya satır düzeyi güvenlik (RLS) kurallarında kullanıldığında DirectQuery modunda kullanılmak üzere desteklenmez.

Örnekler

Aşağıdaki Sales tablo ölçüsü tanımı, yalnızca mavi renkli ürünler için gelir sonucu verir.

Bu makaledeki örnekler örnek Adventure Works DW 2020 Power BI Desktop modeliyle kullanılabilir. Modeli almak için bkz.örnek modeli .

Blue Revenue =
CALCULATE(
    SUM(Sales[Sales Amount]),
    'Product'[Color] = "Blue"
)

işlevi, değiştirilen filtre bağlamında sales amount sütununu Sales tablosunun toplamını değerlendirir. Product tablosuna Color sütunu yeni bir filtre eklenir veya filtre, sütuna zaten uygulanmış olan tüm filtrelerin üzerine yazılır.

Aşağıdaki Sales tablo ölçüsü tanımı, tüm satış kanalları için satışlara göre bir satış oranı oluşturur.

Revenue % Total Channel =
DIVIDE(
    SUM(Sales[Sales Amount]),
    CALCULATE(
        SUM(Sales[Sales Amount]),
        REMOVEFILTERS('Sales Order'[Channel])
    )
)

DIVIDE işlevi, Sales tablosunu Sales Amount sütun değerini (filtre bağlamında) değişen filtre bağlamındaki aynı ifadeye bölen bir ifadeyi böler. Bir filtre değiştirici işlevi olan REMOVEFILTERS işlevini kullanarak filtre bağlamını değiştiren CALCULATE işlevidir. Sales Order tablosundaki Channel sütunundaki filtreleri kaldırır.

Aşağıdaki Customer tablosu hesaplanmış sütun tanımı müşterileri bir bağlılık programı sınıfına sınıflandırır. Bu çok basit bir senaryodur: Müşteri tarafından üretilen gelir 2500 ABD dolarının altında olduğunda, Düşükolarak sınıflandırılır; aksi takdirde yüksek.

Customer Segment =
IF(
    CALCULATE(SUM(Sales[Sales Amount]), ALLEXCEPT(Customer, Customer[CustomerKey])) < 2500,
    "Low",
    "High"
)

Bu örnekte, satır bağlamı filtre bağlamı olarak dönüştürülür. bağlam geçişi olarak bilinir. ALLEXCEPT işlevi, CustomerKey sütunu dışındaki tüm Customer tablo sütunlarından filtreleri kaldırır.

İlgili içerik

Filtre bağlamıSatır bağlamıCALCULATETABLE işleviFilter işlevleri