ALLSELECTED

Şunlar için geçerlidir:Hesaplanan sütunHesaplanan tabloÖlçüGörsel hesaplama

Geçerli sorgudaki sütun ve satırlardaki bağlam filtrelerini kaldırırken diğer tüm bağlam filtrelerini veya açık filtreleri korur.

ALLSELECTED işlevi sorgudaki tüm satır ve sütunları temsil eden bağlamı alır ve satır ve sütun filtreleri dışındaki açık filtreleri ve bağlamları tutar. Bu işlev sorgularda görsel toplamları almak için kullanılabilir.

Sözdizimi

ALLSELECTED([<tableName> | <columnName>[, <columnName>[, <columnName>[,…]]]] )

Parametre

Dönüş değeri

Herhangi bir sütun ve satır filtresi olmayan sorgunun bağlamı.

Açıklamalar

• Bir bağımsız değişken varsa, bağımsız değişken tableName veya columnNameolur. Birden fazla bağımsız değişken varsa, bunlar aynı tablodan sütunlar olmalıdır.

• Bu işlev, sorguda açıkça ayarlanan tüm filtreleri koruduğundan ve satır ve sütun filtreleri dışındaki tüm bağlam filtrelerini koruduğundan ALL() işlevinden farklıdır.

• Bu işlev, hesaplanan sütunlarda veya satır düzeyi güvenlik (RLS) kurallarında kullanıldığında DirectQuery modunda kullanılmak üzere desteklenmez.

Örnek

Aşağıdaki örnekte, DAX ifadeleri kullanarak tablo raporunda farklı görsel toplam düzeyleri oluşturma gösterilmektedir. Raporda Bayi Satışları verilerine iki (2) önceki filtre uygulanmıştır; Biri Sales Territory Group = Europe ve diğeri Promosyon Türü = Toplu İndirim. Filtreler uygulandıktan sonra raporun tamamı, Tüm Yıllar veya Tüm Ürün Kategorileri için görsel toplamlar hesaplanabilir. Ayrıca, çizim amacıyla Tüm Bayi Satışları için genel toplam da elde edilir ve rapordaki tüm filtreler kaldırılır. Aşağıdaki DAX ifadesinin değerlendirilmesi, Visual Totals içeren bir tablo oluşturmak için gereken tüm bilgileri içeren bir tabloya neden olur.

define
measure 'Reseller Sales'[Reseller Sales Amount]=sum('Reseller Sales'[Sales Amount])
measure 'Reseller Sales'[Reseller Grand Total]=calculate(sum('Reseller Sales'[Sales Amount]), ALL('Reseller Sales'))
measure 'Reseller Sales'[Reseller Visual Total]=calculate(sum('Reseller Sales'[Sales Amount]), ALLSELECTED())
measure 'Reseller Sales'[Reseller Visual Total for All of Calendar Year]=calculate(sum('Reseller Sales'[Sales Amount]), ALLSELECTED('Date'[Calendar Year]))
measure 'Reseller Sales'[Reseller Visual Total for All of Product Category Name]=calculate(sum('Reseller Sales'[Sales Amount]), ALLSELECTED('Product Category'[Product Category Name]))
evaluate
CalculateTable(
    //CT table expression
    summarize(
//summarize table expression
crossjoin(distinct('Product Category'[Product Category Name]), distinct('Date'[Calendar Year]))
//First Group by expression
, 'Product Category'[Product Category Name]
//Second Group by expression
, 'Date'[Calendar Year]
//Summary expressions
, "Reseller Sales Amount", [Reseller Sales Amount]
, "Reseller Grand Total", [Reseller Grand Total]
, "Reseller Visual Total", [Reseller Visual Total]
, "Reseller Visual Total for All of Calendar Year", [Reseller Visual Total for All of Calendar Year]
, "Reseller Visual Total for All of Product Category Name", [Reseller Visual Total for All of Product Category Name]
)
//CT filters
, 'Sales Territory'[Sales Territory Group]="Europe", 'Promotion'[Promotion Type]="Volume Discount"
)
order by [Product Category Name], [Calendar Year]

Yukarıdaki ifadeyi SQL Server Management Studio'da AdventureWorks DW Tablolu Modeli'ne karşı yürüttkten sonra aşağıdaki sonuçları alırsınız:

Rapordaki sütunlar şunlardır:

Bayi Satış Tutarı Yıl ve ürün kategorisi için Bayi Satışlarının gerçek değeri. Bu değer raporunuzun merkezindeki bir hücrede, yıl ve catergory'nin kesişiminde görünür.

Tüm Takvim Yılı için Kurumsal Bayi Görsel Toplamı Tüm yıllar boyunca bir ürün kategorisinin toplam değeri. Bu değer, belirli bir ürün kategorisi için bir sütunun veya satırın sonunda ve rapordaki tüm yıllar boyunca görünür.

Tüm Ürün Kategorisi Adı için Bayi Görsel Toplamı Tüm ürün kategorilerinde bir yılın toplam değeri. Bu değer, belirli bir yılın sütun veya satırının sonunda ve rapordaki tüm ürün kategorilerinde görünür.

Bayi Görsel Toplamı Tüm yılların ve ürün kategorilerinin toplam değeri. Bu değer genellikle tablonun en sağ alt köşesinde görünür.

Bayi Genel Toplamı Bu, herhangi bir filtre uygulanmadan önce tüm bayi satışları için genel toplamdır; [Reseller Visual Total] ile aradaki farkı fark etmelisiniz. Bu raporun biri Ürün Kategorisi Grubu'nda, diğeri Promosyon Türü'nde iki (2) filtre içerdiğini unutmayın.