Azure Güncelleştirme Yöneticisi işlem verilerine erişmek için örnek Azure Kaynak Grafı sorguları

Makale
12/04/2024

Aşağıda, yönetilen makinelerinizden toplanan güncelleştirme değerlendirmesini ve dağıtım bilgilerini sorgulamaya başlamanıza yardımcı olacak bazı örnek sorgular verilmiştir. Güncelleştirme değerlendirmeleri ve yüklemeler gibi işlemlerden oluşturulan günlükler hakkında daha fazla bilgi için bkz . Sorgu günlüklerine genel bakış.

Tüm makineleriniz için kullanılabilir güncelleştirmeleri, güncelleştirme kategorisine göre listeleme

Aşağıdaki sorgu; değerlendirmenin gerçekleştirildiği zaman, değerlendirmenin kaynak kimliği, makinedeki işletim sistemi türü ve güncelleştirme sınıflandırmasına göre kullanılabilen işletim sistemi güncelleştirmeleriyle makineniz için bekleyen güncelleştirmelerin listesini döndürür.

patchassessmentresources
| where type !has "softwarepatches"
| extend prop = parse_json(properties)
| extend lastTime = properties.lastModifiedDateTime
| extend updateRollupCount = prop.availablePatchCountByClassification.updateRollup, featurePackCount = prop.availablePatchCountByClassification.featurePack, servicePackCount = prop.availablePatchCountByClassification.servicePack, definitionCount = prop.availablePatchCountByClassification.definition, securityCount = prop.availablePatchCountByClassification.security, criticalCount = prop.availablePatchCountByClassification.critical, updatesCount = prop.availablePatchCountByClassification.updates, toolsCount = prop.availablePatchCountByClassification.tools, otherCount = prop.availablePatchCountByClassification.other, OS = prop.osType
| project lastTime, id, OS, updateRollupCount, featurePackCount, servicePackCount, definitionCount, securityCount, criticalCount, updatesCount, toolsCount, otherCount

Güncelleştirme yüklemelerinin sayısı:

Aşağıdaki sorgu, makinelerinizin son yedi güne ait durumunu içeren güncelleştirme yüklemelerinin listesini döndürür. Sonuçlar güncelleştirme dağıtımının çalıştırıldığı zamanı, yüklemenin kaynak kimliğini, makine ayrıntılarını ve durumuna ve seçiminize göre yüklenen işletim sistemi güncelleştirmelerinin sayısını içerir.

patchinstallationresources
| where type !has "softwarepatches"
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), OS = tostring(prop.osType), installedPatchCount = tostring(prop.installedPatchCount), failedPatchCount = tostring(prop.failedPatchCount), pendingPatchCount = tostring(prop.pendingPatchCount), excludedPatchCount = tostring(prop.excludedPatchCount), notSelectedPatchCount = tostring(prop.notSelectedPatchCount)
| where lTime > ago(7d)
| project lTime, RunID=name,machineName, rgName, resourceType, OS, installedPatchCount, failedPatchCount, pendingPatchCount, excludedPatchCount, notSelectedPatchCount

Windows Server işletim sistemi güncelleştirme yüklemelerinin listesi

Aşağıdaki sorgu, Windows Server için makinelerinizin son yedi güne ait durumunu içeren güncelleştirme yüklemelerinin listesini döndürür. Sonuçlar güncelleştirme dağıtımının çalıştırıldığı zamanı, yüklemenin kaynak kimliğini, makine ayrıntılarını ve diğer ilgili dağıtım ayrıntılarını içerir.

patchinstallationresources
| where type has "softwarepatches" and isnull(properties.version)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), kbId = tostring(prop.kbId), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, kbId, classifications, installationState
| sort by RunID

Linux işletim sistemi güncelleştirme yüklemelerinin listesi

Aşağıdaki sorgu, Linux için makinelerinizin son yedi güne ait durumunu içeren güncelleştirme yüklemelerinin listesini döndürür. Sonuçlar güncelleştirme dağıtımının çalıştırıldığı zamanı, yüklemenin kaynak kimliğini, makine ayrıntılarını ve diğer ilgili dağıtım ayrıntılarını içerir.

patchinstallationresources
| where type has "softwarepatches" and isnotnull(properties.version) and isnull(properties.kbId)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), version = tostring(prop.version), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, version, classifications, installationState
| sort by RunID

VM düzeyinde bakım çalıştırma kaydının listesi

Aşağıdaki sorgu bir VM için tüm bakım çalıştırma kayıtlarının listesini döndürür

maintenanceresources 
| where ['id'] contains "/subscriptions/<subscription-id>/resourcegroups/<resource-group>/providers/microsoft.compute/virtualmachines/<vm-name>" //VM Id here
| where ['type'] == "microsoft.maintenance/applyupdates" 
| where properties.maintenanceScope == "InGuestPatch"

Sonraki adımlar

Azure Kaynak Grafı kullanarak Azure'da Update Manager'dan günlükleri ve arama sonuçlarını gözden geçirin.
Güncelleştirme Yöneticisi'ndeki sorunları giderme konusuna bakın.

Aracılığıyla paylaş