Azure İzleyici Günlükleriyle Site Recovery’yi izleme

Bu makalede, Azure İzleyici Günlükleri ve Log Analytics kullanılarak Azure Site Recovery tarafından çoğaltılan makinelerin nasıl izleneceği açıklanır.

Azure İzleyici Günlükleri, diğer izleme verilerinin yanı sıra etkinlik ve kaynak günlüklerini toplayan bir günlük veri platformu sağlar. Azure İzleyici Günlükleri'nin içinde log sorgularını yazmak ve test etmek ve günlük verilerini etkileşimli olarak analiz etmek için Log Analytics'i kullanırsınız. Günlük sonuçlarını görselleştirebilir ve sorgulayabilir ve izlenen verilere göre eylemler gerçekleştirecek uyarıları yapılandırabilirsiniz.

Site Recovery için, aşağıdakileri yapmanıza yardımcı olması için Azure İzleyici Günlükleri'ni kullanabilirsiniz:

• Site Recovery'nin sistem durumunu ve durumunu izleyin. Örneğin, çoğaltma durumunu, yük devretme test durumunu, Site Recovery olaylarını, korumalı makineler için kurtarma noktası hedeflerini (RPC) ve disk/veri değişim oranlarını izleyebilirsiniz.
• Site Recovery için uyarılar ayarlayın. Örneğin, makine durumu, yük devretme testi durumu veya Site Recovery iş durumu için uyarılar yapılandırabilirsiniz.

Site Recovery ile Azure İzleyici Günlükleri'nin kullanılması, Azure'da Azure çoğaltması ve VMware sanal makinesi/fiziksel sunucusu ile Azure çoğaltması için desteklenir.

Önkoşullar

İşte gerekenler:

• Kurtarma Hizmetleri kasasında en az bir makine korunur.
• Site Recovery günlüklerini depolamak için log analytics çalışma alanı. Çalışma alanı ayarlama hakkında bilgi edinin.
• Log Analytics'te günlük sorgularını yazma, çalıştırma ve analiz etme hakkında temel bilgiler. Daha fazla bilgi edinin.

Başlamadan önce sık sorulan izleme sorularını gözden geçirmenizi öneririz.

Azure Site Recovery için kullanılabilir olay günlükleri

Azure Site Recovery aşağıdaki kaynağa özgü ve eski tabloları sağlar. Her olay, belirli bir site kurtarma ile ilgili yapıt kümesiyle ilgili ayrıntılı veriler sağlar.

Kaynağa özgü tablolar:

• AzureSiteRecoveryJobs
• Azure Site Recovery Çoğaltılan Öğeler Ayrıntıları

Eski tablolar:

• Azure Site Recovery Olayları
• Azure Site Recovery Çoğaltılan Öğeler
• Azure Site Recovery Çoğaltma İstatistikleri
• Azure Site Recovery Noktaları
• Azure Site Recovery Çoğaltma Verileri Karşıya Yükleme Oranı
• Azure Site Recovery Korumalı Disk Veri Değişim Sıklığı
• Azure Site Recovery Çoğaltılan Öğe Ayrıntıları

Site Recovery'yi günlükleri gönderecek şekilde yapılandırma

1. Kasada Tanılama ayarları Tanılama ayarı> ekle'yi seçin.

   

2. Tanılama ayarlarında bir ad belirtin ve Log Analytics'e Gönder kutusunu işaretleyin.

3. Azure İzleyici Günlükleri aboneliğini ve Log Analytics çalışma alanını seçin.

4. İki durumlu düğmedeki Azure Tanılama seçin.

5. Günlük listesinden AzureSiteRecovery ön ekiyle tüm günlükleri seçin. Ardından Tamam'ı seçin.

   

Site Recovery günlükleri, seçili çalışma alanında bir tabloya (AzureDiagnostics) beslemeye başlar.

değişim sıklığı ve karşıya yükleme hızı günlükleri göndermek için İşlem Sunucusu'nda Microsoft izleme aracısını yapılandırma

VMware/fiziksel makineleriniz için veri değişim sıklığı bilgilerini ve kaynak verileri karşıya yükleme hızı bilgilerini şirket içinde yakalayabilirsiniz. Bunu etkinleştirmek için İşlem Sunucusu'na bir Microsoft izleme aracısının yüklenmesi gerekir.

1. Log Analytics çalışma alanına gidin ve Gelişmiş Ayarlar'ı seçin.

2. Bağlı Kaynaklar sayfasını seçin ve ardından Windows Sunucuları'ı seçin.

3. İşlem Sunucusu'nda Windows Aracısı'nı (64 bit) indirin.

4. Çalışma alanı kimliğini ve anahtarını alma

5. Aracıyı TLS 1.2 kullanacak şekilde yapılandırma

6. Alınan çalışma alanı kimliğini ve anahtarını sağlayarak aracı yüklemesini tamamlayın.

7. Yükleme tamamlandıktan sonra Log Analytics çalışma alanına gidin ve Eski aracı yönetimi'ni seçin. Veri sayfasına gidin ve Windows Performans Sayaçları'nı seçin.

8. Örnek aralığı 300 saniye olan aşağıdaki iki sayacı eklemek için '+' öğesini seçin:

   • ASRAnalytics(*)\SourceVmChurnRate
   • ASRAnalytics(*)\SourceVmThrpRate

   Değişim sıklığı ve karşıya yükleme hızı verileri çalışma alanına beslenmeye başlar.

9. Aşağıdaki Site Recovery sayaçları şu anda aranamaz:

   • ASRAnalytics(*)\SourceVmChurnRate
   • ASRAnalytics(*)\SourceVmThrpRate
     Ancak, adları tam olarak yapıştırarak eklenebilirler.

   

Günlükleri sorgulama - örnekler

Kusto sorgu diliyle yazılmış günlük sorgularını kullanarak günlüklerden veri alırsınız. Bu bölümde, Site Recovery izlemesi için kullanabileceğiniz yaygın sorgulara birkaç örnek verilmiştir.

Sorgu çoğaltma durumu

Bu sorgu, tüm korumalı Azure sanal makinelerinin geçerli çoğaltma durumu için üç duruma ayrılmış bir pasta grafik çizer: Normal, Uyarı veya Kritik.

AzureDiagnostics  
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s  
| project name_s , replicationHealth_s  
| summarize count() by replicationHealth_s  
| render piechart   

Sorgu Ulaşım hizmeti sürümü

Bu sorgu, Site Recovery ile çoğaltılan Azure sanal makineleri için çalıştırdıkları Mobility aracısının sürümüne göre ayrılmış bir pasta grafik çizer.

AzureDiagnostics  
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s  
| project name_s , agentVersion_s  
| summarize count() by agentVersion_s  
| render piechart 

RPO süresini sorgulama

Bu sorgu, Site Recovery ile çoğaltılan Azure sanal makinelerinin kurtarma noktası hedefi (RPO) ile ayrılmış çubuk grafiğini çizer: 15 dakikadan kısa, 15-30 dakika arasında ve 30 dakikadan fazla.

AzureDiagnostics 
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)  
| extend RPO = case(rpoInSeconds_d <= 900, "<15Min",   
rpoInSeconds_d <= 1800, "15-30Min", ">30Min")  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s  
| project name_s , RPO  
| summarize Count = count() by RPO  
| render barchart 

Site Recovery işlerini sorgulama

Bu sorgu, son 72 saat içinde tetiklenen tüm Site Recovery işlerini (tüm olağanüstü durum kurtarma senaryoları için) ve tamamlanma durumlarını alır.

AzureDiagnostics  
| where Category == "AzureSiteRecoveryJobs"  
| where TimeGenerated >= ago(72h)   
| project JobName = OperationName , VaultName = Resource , TargetName = affectedResourceName_s, State = ResultType  

Site Recovery olaylarını sorgulama

Bu sorgu, son 72 saat içinde tetiklenen tüm Site Recovery olaylarını (tüm olağanüstü durum kurtarma senaryoları için) ve bunların önem derecesini alır.

AzureDiagnostics   
| where Category == "AzureSiteRecoveryEvents"   
| where TimeGenerated >= ago(72h)   
| project AffectedObject=affectedResourceName_s , VaultName = Resource, Description_s = healthErrors_s , Severity = Level  

Sorgu testi yük devretme durumu (pasta grafik)

Bu sorgu, Site Recovery ile çoğaltılan Azure sanal makinelerinin yük devretme testi durumu için bir pasta grafik çizer.

AzureDiagnostics  
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)  
| where isnotempty(failoverHealth_s) and isnotnull(failoverHealth_s)  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s  
| project name_s , Resource, failoverHealth_s  
| summarize count() by failoverHealth_s  
| render piechart 

Sorgu testi yük devretme durumu (tablo)

Bu sorgu, Site Recovery ile çoğaltılan Azure sanal makinelerinin yük devretme testi durumu için bir tablo çizer.

AzureDiagnostics   
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)   
| where isnotempty(failoverHealth_s) and isnotnull(failoverHealth_s)   
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| project VirtualMachine = name_s , VaultName = Resource , TestFailoverStatus = failoverHealth_s 

Sorgu makinesi RPO's

Bu sorgu, son 72 saat boyunca belirli bir Azure sanal makinesinin (ContosoVM123) RPO'sunu izleyen bir eğilim grafiği çizer.

AzureDiagnostics   
| where replicationProviderName_s == "A2A"   
| where TimeGenerated > ago(72h)  
| where isnotempty(name_s) and isnotnull(name_s)   
| where name_s == "ContosoVM123"  
| project TimeGenerated, name_s , RPO_in_seconds = rpoInSeconds_d   
| render timechart 

Azure sanal makinesi için veri değişim hızını (değişim sıklığı) ve karşıya yükleme hızını sorgulama

Bu sorgu, belirli bir Azure sanal makinesi (ContosoVM123) için veri değişim hızını (Saniyede Yazma Bayt sayısı) ve veri yükleme hızını temsil eden bir eğilim grafiği çizer.

AzureDiagnostics   
| where Category in ("AzureSiteRecoveryProtectedDiskDataChurn", "AzureSiteRecoveryReplicationDataUploadRate")   
| extend CategoryS = case(Category contains "Churn", "DataChurn",   
Category contains "Upload", "UploadRate", "none")  
| extend InstanceWithType=strcat(CategoryS, "_", InstanceName_s)   
| where TimeGenerated > ago(24h)   
| where InstanceName_s startswith "ContosoVM123"   
| project TimeGenerated , InstanceWithType , Churn_MBps = todouble(Value_s)/1048576   
| render timechart  

VMware veya fiziksel makine için veri değişim hızını (değişim sıklığı) ve karşıya yükleme hızını sorgulama

Bu sorgu, veri değişim oranını (Saniye Başına Yazma Baytları) ve veri yükleme hızını temsil eden win-9r7sfh9qlru çoğaltılmış bir öğenin belirli bir disk, disk0 için eğilim grafiğini çizer. Disk adını, kurtarma hizmetleri kasasında çoğaltılan öğenin Diskler dikey penceresinde bulabilirsiniz. Sorguda kullanılacak örnek adı, makinenin DNS adı, ardından _ ve bu örnekte olduğu gibi disk adıdır.

Perf
| where ObjectName == "ASRAnalytics"
| where InstanceName contains "win-9r7sfh9qlru_disk0"
| where TimeGenerated >= ago(4h) 
| project TimeGenerated ,CounterName, Churn_MBps = todouble(CounterValue)/5242880 
| render timechart

İşlem Sunucusu bu verileri her 5 dakikada bir Log Analytics çalışma alanına gönderir. Bu veri noktaları, 5 dakika boyunca hesaplanan ortalamayı temsil edilir.

Sorgu olağanüstü durum kurtarma özeti (Azure'da Azure'a)

Bu sorgu, ikincil bir Azure bölgesine çoğaltılan Azure sanal makineleri için bir özet tablosu çizer. Sanal makine adı, çoğaltma ve koruma durumu, RPO, yük devretme testi durumu, Mobility aracısı sürümü, etkin çoğaltma hataları ve kaynak konumu gösterir.

AzureDiagnostics 
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)   
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| project VirtualMachine = name_s , Vault = Resource , ReplicationHealth = replicationHealth_s, Status = protectionState_s, RPO_in_seconds = rpoInSeconds_d, TestFailoverStatus = failoverHealth_s, AgentVersion = agentVersion_s, ReplicationError = replicationHealthErrors_s, SourceLocation = primaryFabricName_s 

Sorgu olağanüstü durum kurtarma özeti (VMware/fiziksel sunucular)

Bu sorgu, VMware sanal makineleri ve Azure'a çoğaltılan fiziksel sunucular için bir özet tablosu çizer. Makine adı, çoğaltma ve koruma durumu, RPO, yük devretme testi durumu, Mobility aracısı sürümü, etkin çoğaltma hataları ve ilgili işlem sunucusu gösterilir.

AzureDiagnostics  
| where replicationProviderName_s == "InMageRcm"   
| where isnotempty(name_s) and isnotnull(name_s)   
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| project VirtualMachine = name_s , Vault = Resource , ReplicationHealth = replicationHealth_s, Status = protectionState_s, RPO_in_seconds = rpoInSeconds_d, TestFailoverStatus = failoverHealth_s, AgentVersion = agentVersion_s, ReplicationError = replicationHealthErrors_s, ProcessServer = processServerName_g  

Uyarıları ayarlama - örnekler

Site Recovery uyarılarını Azure İzleyici verilerine göre ayarlayabilirsiniz. Günlük uyarılarını ayarlama hakkında daha fazla bilgi edinin.

Kritik durumdaki birden çok makine

20'den fazla çoğaltılmış Azure sanal makinesi Kritik duruma geçerse bir uyarı ayarlayın.

AzureDiagnostics   
| where replicationProviderName_s == "A2A"   
| where replicationHealth_s == "Critical"  
| where isnotempty(name_s) and isnotnull(name_s)   
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| summarize count() 

Uyarı için Eşik değerini olarak 20ayarlayın.

Kritik durumdaki tek makine

Belirli bir çoğaltılmış Azure sanal makinesi Kritik duruma geçerse bir uyarı ayarlayın.

AzureDiagnostics   
| where replicationProviderName_s == "A2A"   
| where replicationHealth_s == "Critical"  
| where name_s == "ContosoVM123"  
| where isnotempty(name_s) and isnotnull(name_s)   
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| summarize count()  

Uyarı için Eşik değerini olarak 1ayarlayın.

Birden çok makine RPO'yu aşıyor

20'den fazla Azure sanal makinesi için RPO 30 dakikayı aşarsa bir uyarı ayarlayın.

AzureDiagnostics   
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)   
| where rpoInSeconds_d > 1800  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| project name_s , rpoInSeconds_d   
| summarize count()  

Uyarı için Eşik değerini olarak 20ayarlayın.

Tek makine RPO'yu aşıyor

Tek bir Azure sanal makinesi için RPO 30 dakikayı aşarsa bir uyarı ayarlayın.

AzureDiagnostics   
| where replicationProviderName_s == "A2A"   
| where isnotempty(name_s) and isnotnull(name_s)   
| where name_s == "ContosoVM123"  
| where rpoInSeconds_d > 1800  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| project name_s , rpoInSeconds_d   
| summarize count()  

Uyarı için Eşik değerini olarak 1ayarlayın.

Birden çok makine için yük devretme testi 90 günü aşıyor

Son başarılı yük devretme testi 20'den fazla sanal makine için 90 günden fazlaysa bir uyarı ayarlayın.

AzureDiagnostics  
| where replicationProviderName_s == "A2A"   
| where Category == "AzureSiteRecoveryReplicatedItems"  
| where isnotempty(name_s) and isnotnull(name_s)   
| where lastSuccessfulTestFailoverTime_t <= ago(90d)   
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| summarize count()  

Uyarı için Eşik değerini olarak 20ayarlayın.

Tek bir makine için yük devretme testi 90 günü aşıyor

Belirli bir sanal makine için son başarılı yük devretme testi 90 günden uzun bir süre önceyse bir uyarı ayarlayın.

AzureDiagnostics  
| where replicationProviderName_s == "A2A"   
| where Category == "AzureSiteRecoveryReplicatedItems"  
| where isnotempty(name_s) and isnotnull(name_s)   
| where lastSuccessfulTestFailoverTime_t <= ago(90d)   
| where name_s == "ContosoVM123"  
| summarize hint.strategy=partitioned arg_max(TimeGenerated, *) by name_s   
| summarize count()  

Uyarı için Eşik değerini olarak 1ayarlayın.

Site Recovery işi başarısız oluyor

Bir Site Recovery işi (bu örnekte Yeniden Koruma işi) son gün içinde herhangi bir Site Recovery senaryosunda başarısız olursa bir uyarı ayarlayın.

AzureDiagnostics   
| where Category == "AzureSiteRecoveryJobs"   
| where OperationName == "Reprotect"  
| where ResultType == "Failed"  
| summarize count()  

Uyarı için, son gündeki hataları denetlemek için Eşik değerini 1 ve Nokta değerini 1440 dakika olarak ayarlayın.

Sonraki adımlar

Yerleşik Site Recovery izleme hakkında bilgi edinin.