range işleci

Şunlar için geçerlidir: ✅Microsoft Fabric✅

Tek sütunlu bir değer tablosu oluşturur.

Sözdizimi

range columnNamefrombaşlamaktodurmakstepadım

Söz dizimi kuralları hakkında daha fazla bilgi edinin.

Parametreler

Döndürülenler

Değerleri , ... olan columnName adlı tek sütunlu bir tablo. kadar ve durana kadar.

Örnekler

Bu bölümdeki örnekte, kullanmaya başlamanıza yardımcı olması için söz diziminin nasıl kullanılacağı gösterilmektedir.

Son yedi gün içindeki aralık

Aşağıdaki örnek, geçerli zaman damgasının girdilerinin günde bir kez olmak üzere son yedi gün içinde uzatılmış olduğu bir tablo oluşturur.

range LastWeek from ago(7d) to now() step 1d

Çıktı

Farklı durdurma sürelerini birleştirme

Aşağıdaki örnekte, union işlecini kullanarak aralıkları birden çok durdurma süresini kullanacak şekilde genişletme gösterilmektedir.

let Range1 = range Time from datetime(2024-01-01) to datetime(2024-01-05) step 1d;
let Range2 = range Time from datetime(2024-01-06) to datetime(2024-01-10) step 1d;
union Range1, Range2
| order by Time asc

Çıktı

Parametreleri kullanan aralık

Aşağıdaki örnekte, işlecinin range daha sonra genişletilmiş ve tablo olarak kullanılan parametrelerle nasıl kullanılacağı gösterilmektedir.

let toUnixTime = (dt:datetime) 
{ 
    (dt - datetime(1970-01-01)) / 1s 
};
let MyMonthStart = startofmonth(now()); //Start of month
let StepBy = 4.534h; //Supported timespans
let nn = 64000; // Row Count parametrized
let MyTimeline = range MyMonthHour from MyMonthStart to now() step StepBy
| extend MyMonthHourinUnixTime = toUnixTime(MyMonthHour), DateOnly = bin(MyMonthHour,1d), TimeOnly = MyMonthHour - bin(MyMonthHour,1d)
; MyTimeline | order by MyMonthHour asc | take nn

Çıktı

Artımlı adımlar

Aşağıdaki örnek, türü Steps olan long adlı tek bir sütuna sahip bir tablo oluşturur ve bir ila sekiz arasında değerlerin üç artırılarak sonuçlanır.

range Steps from 1 to 8 step 3

Çıktı

Bir zaman aralığı üzerindeki izlemeler

Aşağıdaki örnekte, range işlecinin kaynak verilerin hiçbir değeri olmayan sıfırları tanıtmak için kullanılan bir boyut tablosu oluşturmak için nasıl kullanılabileceğini gösterir. Son dört saatin zaman damgalarını alır ve her bir dakikalık aralık için izlemeleri sayar. Belirli bir aralık için izleme olmadığında, sayı sıfır olur.

range TIMESTAMP from ago(4h) to now() step 1m
| join kind=fullouter
  (Traces
      | where TIMESTAMP > ago(4h)
      | summarize Count=count() by bin(TIMESTAMP, 1m)
  ) on TIMESTAMP
| project Count=iff(isnull(Count), 0, Count), TIMESTAMP
| render timechart