prev()
Şunlar için geçerlidir: ✅Microsoft Fabric✅Azure Veri Gezgini✅ Azure İzleyici✅Microsoft Sentinel
Belirtilen satırdaki belirli bir sütunun değerini döndürür. Belirtilen satır, serileştirilmiş bir satır kümesindeki geçerli satırdan belirtilen uzaklıkta.
Sözdizimi
prev(column, [ offset ], [ default_value ] )
Söz dizimi kuralları hakkında daha fazla bilgi edinin.
Parametreler
| Ad | Tür | Zorunlu | Açıklama |
|---|---|---|---|
| sütun | string |
✔️ | Değerlerin alındığı sütun. |
| fark | int |
Satırlarda geri dönmek için uzaklık. Varsayılan değer 1'dir. | |
| default_value | sayıl | Değerin alınacağı önceki satırlar olmadığında kullanılacak varsayılan değer. Varsayılan değer: null. |
Örnekler
Bitişik satırlar arasındaki karşılaştırmaya göre verileri filtreleme
Aşağıdaki sorgu, çağrısı sensor-9arasında saniyenin çeyreğinden uzun kesmeleri gösteren satırlar döndürür.
TransformedSensorsData
| where SensorName == 'sensor-9'
| sort by Timestamp asc
| extend timeDiffInMilliseconds = datetime_diff('millisecond', Timestamp, prev(Timestamp, 1))
| where timeDiffInMilliseconds > 250
Çıktı
| Zaman damgası | SensorName | Değer | PublisherId | MachineId | timeDiff |
|---|---|---|---|---|---|
| 2022-04-13T00:58:53.048506Z | sensor-9 | 0.39217481975439894 | fdbd39ab-82ac-4ca0-99ed-2f83daf3f9bb | M100 | 251 |
| 2022-04-13T01:07:09.63713Z | sensor-9 | 0.46645392778288297 | e3ed081e-501b-4d59-8e60-8524633d9131 | M100 | 313 |
| 2022-04-13T01:07:10.858267Z | sensor-9 | 0.693091598493419 | 278ca033-2b5e-4f2c-b493-00319b275aea | M100 | 254 |
| 2022-04-13T01:07:11.203834Z | sensor-9 | 0.52415808840249778 | 4ea27181-392d-4947-b811-ad5af02a54bb | M100 | 331 |
| 2022-04-13T01:07:14.431908Z | sensor-9 | 0.35430645405452 | 0af415c2-59dc-4a50-89c3-9a18ae5d621f | M100 | 268 |
| ... | ... | ... | ... | ... | ... |
Bitişik satırlar arasındaki karşılaştırmaya göre toplama gerçekleştirme
Aşağıdaki sorgu, çağrısı sensor-9arasındaki ortalama zaman farkını milisaniye cinsinden hesaplar.
TransformedSensorsData
| where SensorName == 'sensor-9'
| sort by Timestamp asc
| extend timeDiffInMilliseconds = datetime_diff('millisecond', Timestamp, prev(Timestamp, 1))
| summarize avg(timeDiffInMilliseconds)
Çıktı
| avg_timeDiffInMilliseconds |
|---|
| 30.726900061254298 |
Satırı önceki satırdaki verilerle genişletme
Aşağıdaki sorguda, seri hale getirme işleciyle yapılan serileştirmenin bir parçası olarak, önceki satırdaki verilerle yeni bir sütun previous_session_type eklenir. İlk oturumdan önce bir oturum olmadığından, sütun ilk satırda boş olur.
ConferenceSessions
| where conference == 'Build 2019'
| serialize previous_session_type = prev(session_type)
| project time_and_duration, session_title, session_type, previous_session_type
Çıktı
| time_and_duration | session_title | session_type | previous_session_type |
|---|---|---|---|
| Mon, 6 Mayıs 8:30-10:00 | Vision Keynote - Satya Nadella | Açılış Konuşması | |
| Pzt, 6 Mayıs 13:20-13:40 | Azure Veri Gezgini: Gelişmiş Zaman Serisi analizi | Expo Oturumu | Açılış Konuşması |
| Pzt, 6 Mayıs 2:00-15:00 | Azure'ın Veri Platformu - Petabayt Ölçeğinde Modern Uygulamaları ve Bulut Ölçeği Analizini Etkinleştirme | Koparma | Expo Oturumu |
| Pzt, 6 Mayıs 16:00-16:20 | BASF, Azure Data Services'ı nasıl kullanıyor? | Expo Oturumu | Koparma |
| Mon, 6 Mayıs 6:50 - 19:10 | Azure Veri Gezgini: ML modellerinizi kullanıma hazır hale getirme | Expo Oturumu | Expo Oturumu |
| ... | ... | ... | ... |