Aracılığıyla paylaş


pivot eklentisi

Şunlar için geçerlidir: ✅Microsoft FabricAzure Veri Gezgini

Giriş tablosundaki bir sütundaki benzersiz değerleri çıkış tablosundaki birden çok sütuna dönüştürerek tabloyu döndürür ve son çıktıda görünecek kalan sütun değerlerinde gerektiği gibi toplamalar gerçekleştirir.

Not

OutputSchema belirtilmezse, eklentinin pivot çıkış şeması giriş verilerini temel alır. Bu nedenle, eklentinin farklı veri girişleri kullanılarak birden çok yürütülmesi farklı çıkış şeması üretebilir. Bu, paketlenmemiş sütunlara başvuran sorgunun her zaman 'bozulabileceği' anlamına da gelir. Bu nedenle, OutputSchema işlevini belirtmeden otomasyon işleri için bu eklentiyi kullanmanızı önermeyiz.

Sözdizimi

T | evaluate pivot(pivotColumn aggregationFunction] [,column1[, column2 ... ]]) [: OutputSchema][,

Söz dizimi kuralları hakkında daha fazla bilgi edinin.

Parametreler

Ad Tür Zorunlu Açıklama
pivotColumn string ✔️ Döndürülecek sütun. Bu sütundaki her benzersiz değer, çıkış tablosundaki bir sütun olacaktır.
aggregationFunction string Giriş tablosundaki birden çok satırı çıkış tablosundaki tek bir satıra toplamak için kullanılan toplama işlevi. Şu anda desteklenen işlevler: , , , , , dcount(), avg(), , make_bag()variance()make_list()stdev()make_set(), . count()sum()take_any()max()min() Varsayılan değer: count().
sütun1, sütun2, ... string Sütun adı veya virgülle ayrılmış sütun adları listesi. Çıkış tablosu, belirtilen her sütun için ek bir sütun içerir. Varsayılan değer, özetlenmiş sütun ve toplama sütunu dışındaki tüm sütunlardır.
OutputSchema Eklenti çıkışının beklenen sütunları pivot için adlar ve türler.

Sözdizimi: ( ColumnName : ColumnType [, ...] )

Beklenen şemanın belirtilmesi, önce şemayı keşfetmek için gerçek sorguyu çalıştırmak zorunda kalmadan sorgu yürütmeyi iyileştirir. Çalışma zamanı şeması OutputSchema şemasıyla eşleşmiyorsa bir hata oluşur.

Döndürülenler

Özet, belirtilen sütunlara (sütun1, sütun2, ...) ve özet sütunların tüm benzersiz değerlerine sahip döndürülmüş tabloyu döndürür. Özetlenmiş sütunların her hücresi toplama işlevi hesaplamasını içerir.

Örnekler

Sütuna göre özetle

'AL' ile başlayan her EventType ve State için bu durumdaki bu türdeki olayların sayısını sayın.

StormEvents
| project State, EventType
| where State startswith "AL"
| where EventType has "Wind"
| evaluate pivot(State)

Çıktı

EventType ALABAMA ALASKA
Gök Gürültülü Fırtına 352 1
Kuvvetli Rüzgar 0 95
Aşırı Soğuk/Rüzgar Ürpertici 0 10
Güçlü Rüzgar 22 0

Toplama işlevine sahip bir sütuna göre özetleme

'AR' ile başlayan her EventType ve State için toplam doğrudan ölüm sayısını görüntüleyin.

StormEvents
| where State startswith "AR"
| project State, EventType, DeathsDirect
| where DeathsDirect > 0
| evaluate pivot(State, sum(DeathsDirect))

Çıktı

EventType ARKANSAS ARİZONA
Şiddetli Yağmur 1 0
Gök Gürültülü Fırtına 1 0
Lightning 0 1
Flash Flood 0 6
Güçlü Rüzgar 1 0
Veri sıcaklığı 3 0

Toplama işlevi ve tek bir ek sütun içeren bir sütuna göre özetleme

Sonuç, önceki örnekle aynıdır.

StormEvents
| where State startswith "AR"
| project State, EventType, DeathsDirect
| where DeathsDirect > 0
| evaluate pivot(State, sum(DeathsDirect), EventType)

Çıktı

EventType ARKANSAS ARİZONA
Şiddetli Yağmur 1 0
Gök Gürültülü Fırtına 1 0
Lightning 0 1
Flash Flood 0 6
Güçlü Rüzgar 1 0
Veri sıcaklığı 3 0

Özetlenmiş sütunu, toplama işlevini ve birden çok ek sütunu belirtin

Her olay türü, kaynağı ve durumu için doğrudan ölüm sayısını toplama.

StormEvents
| where State startswith "AR"
| where DeathsDirect > 0
| evaluate pivot(State, sum(DeathsDirect), EventType, Source)

Çıktı

EventType Kaynak ARKANSAS ARİZONA
Şiddetli Yağmur Acil Durum Yöneticisi 1 0
Gök Gürültülü Fırtına Acil Durum Yöneticisi 1 0
Lightning Gazete 0 1
Flash Flood Eğitilmiş Gözcü 0 2
Flash Flood Yayın Medyası 0 3
Flash Flood Gazete 0 1
Güçlü Rüzgar Kolluk 1 0
Veri sıcaklığı Gazete 3 0

Sorgu tanımlı çıktı şemasıyla özetle

Aşağıdaki örnek StormEvents tablosundaki belirli sütunları seçer. Gerçek sorgu çalıştırılmadan önce çeşitli iyileştirmelerin değerlendirilmesini sağlayan açık bir şema tanımı kullanır.

StormEvents
| project State, EventType
| where EventType has "Wind"
| evaluate pivot(State): (EventType:string, ALABAMA:long, ALASKA:long)

Çıktı

EventType ALABAMA ALASKA
Gök Gürültülü Fırtına 352 1
Kuvvetli Rüzgar 0 95
Deniz Fırtına Rüzgarı 0 0
Güçlü Rüzgar 22 0
Aşırı Soğuk/Rüzgar Ürpertici 0 10
Soğuk/Rüzgar Ürpertici 0 0
Deniz Güçlü Rüzgarı 0 0
Deniz Yüksek Rüzgarı 0 0