Aracılığıyla paylaş

StorageBlobLogs tablosu için sorgular

  • Makale

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

En yaygın hatalar

Son 3 gün içindeki en yaygın 10 hatayı listeleyin.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

Çoğu hataya neden olan işlemler

Son 3 gün içinde en çok hataya neden olan ilk 10 işlemi listeleyin.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

En yüksek gecikme süresine sahip işlemler

Son 3 gün içinde en uzun uçtan uca gecikme süresine sahip ilk 10 işlemi listeleyin.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

Sunucu tarafı azaltmaya neden olan işlemler

Son 3 gün içinde sunucu tarafı azaltma hatalarının neden olduğu tüm işlemleri listeleyin.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

Anonim istekleri göster

Son 3 gün içinde anonim erişimi olan tüm istekleri listeleyin.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

Sık kullanılan işlemler grafiği

Son 3 gün içinde kullanılan işlemlerin pasta grafiği.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart