ASCDeviceEvents tablosu için sorgular

Makale
02/18/2025

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

Azure Sphere cihaz kimlik doğrulaması ve kanıtlama hataları

Geçen haftaya ait Azure Sphere cihaz kimlik doğrulaması ve kanıtlama hatalarının zamana göre sıralanmış listesi.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and
        Properties.EventType == "DeviceAttestationFailure" or Properties.EventType == "DeviceCertificateEvent" and
        ResultType == "Failure" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| project TimeGenerated, DeviceId, Properties, ResultDescription, Location
| sort by TimeGenerated desc
| limit 100

Azure Sphere cihaz olayları zaman çizelgesi

Beklenmeyen hataları izlemek ve gidermek için geçen hafta azure Sphere cihazı tarafından oluşturulan tüm olayların sıralı zaman çizelgesi.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" or Properties.DeviceTelemetryEventCategory == "AppCrash" // Remove/Add filters to see all/specific events. Filter data by Device by adding " | where DeviceId == "Your Device ID" " 
| project TimeGenerated, OperationName, ResultType, ResultDescription, Properties, Location
| sort by TimeGenerated desc
| limit 100

Azure Sphere cihaz sinyal olayları zaman çizelgesi

Cihaz durumunu sürekli izlemek ve eğilimleri görmek için Azure Sphere cihazları tarafından geçen hafta başlatılan tüm sertifika oluşturma olaylarının zaman çizelgesi.

let Interval = timespan(1d); // Interval for the Chart 
ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and 
        Properties.EventType == "DeviceCertificatesGenerate" and 
        ResultType == "Success"
| summarize Device_Heartbeat_Events=count() by bin(TimeGenerated, Interval)
| render timechart

Azure Sphere cihazları en son işletim sistemine güncelleştirilmedi

Geçen hafta en son işletim sistemi sürümüne güncelleştirilmemiş Azure Sphere cihazlarının listesi.

ASCDeviceEvents
| where OperationName == "DeviceUpdateEvent" and  
        todouble(Properties.InstalledOSVersion) != todouble(Properties.TargetedOSVersion) // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize by DeviceId
| limit 100

Azure Sphere cihaz telemetrisi olayları özeti

Genel cihaz durumunu izlemek için Azure Sphere Cihazları tarafından geçen hafta oluşturulan olay kategorilerinin her birinin paylaşımını özetleyen bir pasta çizelgesi.

ASCDeviceEvents
| where OperationName == "DeviceTelemetryEvent" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize count() by tostring(Properties.DeviceTelemetryEventCategory)
| render piechart

Aracılığıyla paylaş