AppRequests tablosu için sorgular

Makale
02/18/2025

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

Yanıt süresi eğilimi

Son 12 saat içindeki grafik isteği süresi.

// To create an alert for this query, click '+ New alert rule'
AppRequests
| where TimeGenerated > ago(12h) 
| summarize avgRequestDuration=avg(DurationMs) by bin(TimeGenerated, 10m), _ResourceId // use a time grain of 10 minutes
| render timechart

İstek sayısı eğilimi

Grafik İsteği sayısı son güne göredir.

// To create an alert for this query, click '+ New alert rule'
AppRequests
| summarize totalCount=sum(ItemCount) by bin(TimeGenerated, 30m), _ResourceId
| render timechart

Yanıt süresi demetleri

Her performans demetinde kaç istek olduğunu gösterin.

AppRequests
| summarize requestCount=sum(ItemCount), avgDuration=avg(DurationMs) by PerformanceBucket
| order by avgDuration asc // sort by average request duration
| project-away avgDuration // no need to display avgDuration, we used it only for sorting results
| render barchart

İşlem performansı

İşlemlere göre istek sayısını ve süresini hesaplayın.

// To create an alert for this query, click '+ New alert rule'
AppRequests
| summarize RequestsCount=sum(ItemCount), AverageDuration=avg(DurationMs), percentiles(DurationMs, 50, 95, 99) by OperationName, _ResourceId // you can replace 'OperationName' with another value to segment by a different property
| order by RequestsCount desc // order from highest to lower (descending)

Trafiğe göre ilk 10 ülke

İlk 10 ülkeden gelen istek miktarını grafikleyin.

AppRequests
| summarize CountByCountry=count() by ClientCountryOrRegion
| top 10 by CountByCountry
| render piechart

Başarısız istekler – ilk 10

En yavaş 3 sayfa nedir ve ne kadar yavaş?

AppRequests
| where Success == false
| summarize failedCount=sum(ItemCount) by Name
| top 10 by failedCount desc
| render barchart

Başarısız işlemler

İşlemlerin kaç kez başarısız olduğunu ve kaç kullanıcının etkilendiğini hesaplayın.

// To create an alert for this query, click '+ New alert rule'
AppRequests
| where Success == false
| summarize failedCount=sum(ItemCount), impactedUsers=dcount(UserId) by OperationName, _ResourceId
| order by failedCount desc

İstek hatalarına neden olan özel durumlar

Son bir saat içinde başarısız isteklere neden olan özel durumları bulun.

AppRequests
| where TimeGenerated > ago(1h) and Success == false
| join kind= inner (
AppExceptions
| where TimeGenerated > ago(1h)
) on OperationId
| project exceptionType = Type, failedMethod = Method, requestName = Name, requestDuration = DurationMs, _ResourceId

Aracılığıyla paylaş