Zdieľať cez

Table.TransformColumnTypes

  • Článok

Syntax

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

O

Vráti tabuľku použitím operácií transformácie na zadané stĺpce pomocou voliteľnej jazykovej verzie.

  • table: Vstupná tabuľka, ktorá sa má transformovať.
  • typeTransformations: Transformácie typu, ktoré sa majú použiť. Formát pre jednu transformáciu je { názov stĺpca, typ hodnota }. Zoznam transformácií možno použiť na zmenu typov viacerých stĺpcov naraz. Ak stĺpec neexistuje, vyskytne sa chyba.
  • culture: (Voliteľné) Jazyková verzia, ktorá sa má použiť pri transformácii typov stĺpcov (napríklad "en-US").

Hodnota typu v parametri typeTransformations môže byť any, všetky typy number, text, všetky date, time, datetime, datetimezonea typy duration, logicalalebo binary. Typy list, record, tablealebo function nie sú pre tento parameter platné.

Príklad č. 1

Transformovať číselné hodnoty v prvom stĺpci na textové hodnoty.

používania

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

výstupu

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Príklad č. 2

Transformujte dátumy v tabuľke na francúzske textové ekvivalenty.

používania

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

výstupu

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

Príklad č. 3

Transformovať dátumy v tabuľke na ich nemecké textové ekvivalenty a hodnoty v tabuľke na percentá.

používania

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

výstupu

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Súvisiaci obsah