CALCULATE

Vzťahuje sa na:vypočítaný stĺpecvypočítanej tabuľkyvizuálového výpočtu

Vyhodnotí výraz v kontexte upraveného filtra.

Syntax

CALCULATE(<expression>[, <filter1> [, <filter2> [, …]]])

Parametre

Výraz použitý ako prvý parameter je v podstate rovnaký ako mierka.

Filtre môžu byť:

• Booleovské výrazy filtra
• Tabuľkové výrazy filtra
• Funkcie modifikovania filtra

Ak existuje viacero filtrov, možno ich vyhodnotiť pomocou AND (&&) logického operátora, čo znamená, že všetky podmienky musia byť TRUE, alebo logickým operátorom OR (||), čo znamená, že obe podmienky môžu mať hodnotu true.

Booleovské výrazy filtra

Filter booleovského výrazu je výraz, ktorý sa vyhodnotí ako TRUE alebo FALSE. Existuje niekoľko pravidiel, ktoré musia dodržiavať:

• Môžu odkazovať na stĺpce z jednej tabuľky.
• Nemôžu odkazovať na mierky.
• Nemôžu použiť vnorenú funkciu CALCULATE.

Od vydania aplikácie Power BI Desktop zo septembra 2021 platí nasledujúce:

• Nemôžu používať funkcie, ktoré kontrolujú alebo vracajú tabuľku, pokiaľ nie sú odovzdané ako argumenty do agregačných funkcií.
• Môžu obsahovať agregačnú funkciu, ktorá vracia skalárnu hodnotu. Napríklad

  Total sales on the last selected date =
  CALCULATE (
      SUM ( Sales[Sales Amount] ),
      'Sales'[OrderDateKey] = MAX ( 'Sales'[OrderDateKey] )
  )
  

Tabuľkové výrazy filtra

Filter výrazov tabuľky použije objekt tabuľky ako filter. Môže ísť o odkaz na tabuľku modelu, ale pravdepodobnejšie je to funkcia, ktorá vracia objekt tabuľky. Funkciu FILTER môžete použiť na použitie zložitých podmienok filtrov vrátane tých, ktoré nie je možné definovať pomocou booleovského výrazu filtra.

Funkcie modifikátora filtra

Funkcie modifikátora filtrov umožňujú viac než len pridávať filtre. Pri úprave kontextu filtra vám poskytnú ďalšie ovládacie prvky.

¹ Funkcia ALL a jej varianty sa správajú ako modifikátory filtrov aj ako funkcie, ktoré vracajú objekty tabuľky. Ak váš nástroj podporuje funkciu REMOVEFILTERS, použite ju na odstránenie filtrov.

Vrátená hodnota

Hodnota, ktorá je výsledkom výrazu.

Poznámky

• Ak sú zadané výrazy filtra, funkcia CALCULATE upraví kontext filtra tak, aby vyhodnotil výraz. Pre každý výraz filtra existujú dva možné štandardné výstupy, keď výraz filtra nie je zabalený vo funkcii KEEPFILTERS:

  • Ak sa stĺpce (alebo tabuľky) nenachádzajú v kontexte filtra, do kontextu filtra sa pridajú nové filtre na vyhodnotenie výrazu.
  • Ak sa stĺpce (alebo tabuľky) už v kontexte nachádzajú, existujúce filtre sa prepíšu novými filtrami, aby sa vyhodnotil výraz CALCULATE.

• Funkcia CALCULATE použitá bez filtrov dosiahne špecifickú požiadavku. Kontext riadka sa presunie na kontext filtra. Vyžaduje sa, keď sa výraz (nie modelová mierka), ktorý sumarizuje modelové údaje, musí vyhodnotiť v kontexte riadka. Tento scenár môže nastať vo vzorci vypočítaného stĺpca alebo pri vyhodnocovaní výrazu v iterátorovej funkcii. Všimnite si, že keď sa v kontexte riadka používa modelová mierka, kontextový prechod je automatický.

• Táto funkcia nie je podporovaná na použitie v režime DirectQuery, keď sa používa vo vypočítaných stĺpcoch alebo v pravidlách zabezpečenia na úrovni riadkov (RLS).

Príklady

Nasledujúci definícia mierky Sales tabuľke vypočíta výsledok výnosov, ale iba pre produkty, ktoré majú modrú farbu.

Príklady v tomto článku možno použiť so vzorovým modelom aplikácie Power BI Desktop Adventure Works DW 2020. Ak chcete získať model, pozrite si DAX ukážkový model.

Blue Revenue =
CALCULATE(
    SUM(Sales[Sales Amount]),
    'Product'[Color] = "Blue"
)

Funkcia CALCULATE vyhodnotí súčet tabuľky SalesStĺpca Čiastka predaja v upravenom kontexte filtra. Nový filter sa pridá do tabuľky Product stĺpci Color ( Farba) alebo filter prepíše všetky filtre, ktoré už boli použité v stĺpci.

Nasledujúca definícia mierky Sales tabuľkovej mierky produkuje pomer predaja vo všetkých kanáloch predaja k predaju.

Revenue % Total Channel =
DIVIDE(
    SUM(Sales[Sales Amount]),
    CALCULATE(
        SUM(Sales[Sales Amount]),
        REMOVEFILTERS('Sales Order'[Channel])
    )
)

Funkcia DIVIDE delí výraz, ktorý je súčtom tabuľky SalesČiastka predaja hodnotou stĺpca (v kontexte filtra) rovnakým výrazom v upravenom kontexte filtra. Je to funkcia CALCULATE, ktorá upraví kontext filtra pomocou funkcie REMOVEFILTERS, čo je funkcia modifikátora filtra. Odstráni filtre z tabuľky Sales Orderstĺpci Kanál.

Nasledujúca definícia vypočítaného stĺpca Customer klasifikuje zákazníkov podľa vernostnej triedy. Je to veľmi jednoduchý scenár: Keď sú výnosy, ktoré zákazník vytvoril, menšie ako 2 500 USD, sú klasifikované ako Low; V opačnom prípade sú Vysoké.

Customer Segment =
IF(
    CALCULATE(SUM(Sales[Sales Amount]), ALLEXCEPT(Customer, Customer[CustomerKey])) < 2500,
    "Low",
    "High"
)

V tomto príklade sa kontext riadka konvertuje na kontext filtra. Označuje sa ako kontextová transformácia. Funkcia ALLEXCEPT odstráni filtre zo všetkých stĺpcov tabuľky Customer s výnimkou stĺpca CustomerKey.

Súvisiaci obsah

Kontext filtrakontextu riadkaCALCULATETABLE funkciefunkcie filtrovania