Guia de Início Rápido: Criar e implantar um fluxo de trabalho de aplicativo lógico de Consumo nos Aplicativos Lógicos do Azure de multilocatário com o Bicep

Aplica-se a: Aplicativos Lógicos do Azure (Consumo)

Os Aplicativos Lógicos do Azure são um serviço de nuvem que ajuda você a criar e executar fluxos de trabalho automatizados que integram dados, aplicativos, serviços baseados em nuvem e sistemas locais com uma seleção de centenas de conectores. Este guia de início rápido tem como foco o processo de implantação de um arquivo Bicep para criação de um fluxo de trabalho de aplicativo lógico básico de Consumo que verifica o status do Azure de acordo com um agendamento por hora e é executado nos Aplicativos Lógicos do Azure de multilocatário.

O Bicep é um DSL (linguagem específica de domínio) que usa sintaxe declarativa para implantar recursos do Azure. Ele fornece sintaxe concisa, segurança de tipos confiável e suporte para reutilização de código. O Bicep oferece a melhor experiência de criação para suas soluções de infraestrutura como código no Azure.

Pré-requisitos

Caso você não tenha uma assinatura do Azure, crie uma conta gratuita do Azure antes de começar.

Examinar o arquivo Bicep

O arquivo Bicep usado neste guia de início rápido vem dos Modelos de início rápido do Azure.

O modelo de início rápido cria um fluxo de trabalho de aplicativo lógico de Consumo que usa o gatilho de Recorrência interno, definido para ser executado a cada hora, e uma ação HTTP interna, que chama uma URL que retorna o status para o Azure. As operações internas são executadas na plataforma Aplicativos Lógicos do Azure.

Este arquivo Bicep cria o seguinte recurso do Azure:

• Microsoft.Logic/workflows, que cria o fluxo de trabalho para um aplicativo lógico.

@description('The name of the logic app to create.')
param logicAppName string

@description('A test URI')
param testUri string = 'https://azure.status.microsoft/status/'

@description('Location for all resources.')
param location string = resourceGroup().location

var frequency = 'Hour'
var interval = '1'
var type = 'recurrence'
var actionType = 'http'
var method = 'GET'
var workflowSchema = 'https://schema.management.azure.com/providers/Microsoft.Logic/schemas/2016-06-01/workflowdefinition.json#'

resource stg 'Microsoft.Logic/workflows@2019-05-01' = {
  name: logicAppName
  location: location
  tags: {
    displayName: logicAppName
  }
  properties: {
    definition: {
      '$schema': workflowSchema
      contentVersion: '1.0.0.0'
      parameters: {
        testUri: {
          type: 'string'
          defaultValue: testUri
        }
      }
      triggers: {
        recurrence: {
          type: type
          recurrence: {
            frequency: frequency
            interval: interval
          }
        }
      }
      actions: {
        actionType: {
          type: actionType
          inputs: {
            method: method
            uri: testUri
          }
        }
      }
    }
  }
}

output name string = stg.name
output resourceId string = stg.id
output resourceGroupName string = resourceGroup().name
output location string = location

Implante o arquivo Bicep

1. Salve o arquivo Bicep como main.bicep em seu computador local.

2. Para implantar o arquivo Bicep, use a CLI do Azure ou o Azure PowerShell.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters logicAppName=<logic-name>
   

Quando a implantação for concluída, você deverá ver uma mensagem indicando que ela foi bem-sucedida.

Examinar os recursos implantados

Use o portal do Azure, a CLI do Azure ou o Azure PowerShell para listar os recursos implantados no grupo de recursos.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Limpar os recursos

Quando não precisar mais do aplicativo lógico, use o portal do Azure, a CLI do Azure ou o Azure PowerShell para excluir o grupo de recursos e os respectivos recursos.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Próximas etapas