Zadania usługi WMI: sieć

Artykuł
03/18/2025

Zadania usługi WMI zarządzają siecią i uzyskują informacje o połączeniach oraz adresach IP lub MAC. Inne przykłady można znaleźć w witrynie TechNet ScriptCenter pod adresem https://www.microsoft.com/technet.

Przykłady skryptów pokazane w tym temacie uzyskują dane tylko z komputera lokalnego. Aby uzyskać więcej informacji o sposobie uzyskiwania danych z komputerów zdalnych za pomocą skryptu, zobacz Connecting to WMI on a Remote Computer.

Poniższa procedura opisuje sposób uruchamiania skryptu.

Aby uruchomić skrypt

Skopiuj kod i zapisz go w pliku z rozszerzeniem vbs, takim jak nazwa pliku.vbs. Upewnij się, że edytor tekstów nie dodaje rozszerzenia .txt do pliku.
Otwórz okno wiersza polecenia i przejdź do katalogu, w którym zapisano plik.
Wpisz cscript nazwapliku.vbs w wierszu poleceń.
Jeśli nie możesz uzyskać dostępu do dziennika zdarzeń, sprawdź, czy korzystasz z wiersza polecenia z podwyższonym poziomem uprawnień. Niektóre dzienniki zdarzeń, takie jak dziennik zdarzeń zabezpieczeń, mogą być chronione przez kontrolę dostępu użytkowników (UAC).

Notatka

Domyślnie skrypt cscript wyświetla dane wyjściowe skryptu w oknie wiersza polecenia. Ponieważ skrypty usługi WMI mogą generować duże ilości danych wyjściowych, może być konieczne przekierowanie danych wyjściowych do pliku. Wpisz cscript filename.vbs > outfile.txt w wierszu polecenia, w celu przekierowania wyniku skryptu filename.vbs do outfile.txt.

W poniższej tabeli wymieniono przykłady skryptów, których można użyć do uzyskania różnych typów danych z komputera lokalnego.

Jak mogę... Klasy lub metody WMI

...czy wyłączyć połączenie sieciowe za pomocą WMI?

Jeśli używasz protokołu DHCP, użyj Win32_NetworkAdapterConfiguration i metody ReleaseDHCPLease, aby zwolnić adres IP. Jeśli nie używasz protokołu DHCP, nie możesz użyć usługi WMI, aby wyłączyć połączenie sieciowe. Aby ponownie włączyć połączenie sieciowe, użyj polecenia objNetCard.RenewDHCPLease. Można również zwolnić lub odnowić wszystkie dzierżawy DHCP przy użyciu metod ReleaseDHCPLeaseAll i RenewDHCPLeaseAll.

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetCards = objWMIService.ExecQuery _
    ("Select * From Win32_NetworkAdapterConfiguration " _
        & "Where IPEnabled = True")
For Each objNetCard in colNetCards
    objNetCard.ReleaseDHCPLease()
Next

PowerShell

$Computer = "."
$net = Get-WMIObject -class Win32_NetworkAdapterConfiguration -ComputerName $computer
$netenabled = $net | where {$_.IPenabled}
foreach ($NetCard in $netenabled) {
    "Releasing lease on: {0}" -f $netcard.caption
 $netcard.ReleaseDHCPLease()
}

... wyłączyć lub włączyć kartę sieciową?

Użyj klasy Win32_NetworkAdapter oraz metod Disable lub Enable.

... określić, który adres IP został przypisany do danego połączenia sieciowego?

Użyj klasy Win32_NetworkAdapter i właściwości NetConnectionID, aby określić adres MAC połączenia sieciowego. Następnie użyj klasy Win32_NetworkAdapterConfiguration, aby znaleźć adres IP skojarzony z adresem MAC.

strComputer = "." Set objWMIService = GetObject(_ "winmgmts:\" & strComputer & "\r" oot\cimv2") Set colItems = objWMIService.ExecQuery _ ("Select * From Win32_NetworkAdapter " _ & "Where NetConnectionID = " & _ "'Local Area Connection 2'") Dla każdego objItem w kolumnie colItems strMACAddress = objItem.MACAddress Next Set colItems = objWMIService.ExecQuery _ ("Select * From Win32_NetworkAdapterConfiguration")

For Each objItem in colItems If objItem.MACAddress = strMACAddress Then For Each strIPAddress in objItem.IPAddress Wscript.Echo "IP Address: " & strIPAddress Next End If Next

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNics = objWMIService.ExecQuery _
    ("Select * From Win32_NetworkAdapter " _
        & "Where NetConnectionID = " & _
        "'Local Area Connection'")
 
For Each objNic in colNics
    Set colNicConfigs = objWMIService.ExecQuery _
      ("ASSOCIATORS OF " _
          & "{Win32_NetworkAdapter.DeviceID='" & _
      objNic.DeviceID & "'}" & _
      " WHERE AssocClass=Win32_NetworkAdapterSetting")
    For Each objNicConfig In colNicConfigs
        For Each strIPAddress in objNicConfig.IPAddress
            Wscript.Echo "IP Address: " &  strIPAddress
        Next
    Next
Next

... ustalić adres MAC karty sieciowej?

Użyj klasy Win32_NetworkAdapterConfiguration i sprawdź wartość właściwości MACAddress.

... określić adres IP komputera?

Użyj klasy Win32_NetworkAdapterConfiguration i sprawdź wartość właściwości IPAddress. Jest to zwracane jako tablica, dlatego użyj pętli For-Each, aby uzyskać wartość.

strComputer = "."
Set objWMIService = GetObject( _ 
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
    ("Select IPAddress from Win32_NetworkAdapterConfiguration ")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i=LBound(IPConfig.IPAddress) _
            to UBound(IPConfig.IPAddress)
                WScript.Echo IPConfig.IPAddress(i)
        Next
    End If
Next

PowerShell

$Computer = "."
$IPconfigset = Get-WmiObject Win32_NetworkAdapterConfiguration
  
# Iterate and get IP address
$count = 0
foreach ($IPConfig in $IPConfigSet) {
   if ($Ipconfig.IPaddress) {
      foreach ($addr in $Ipconfig.Ipaddress) {
   "IP Address   : {0}" -f  $addr;
   $count++ 
   }
   }
}
if ($count -eq 0) {"No IP addresses found"}
else {"$Count IP addresses found on this system"}

...jak skonfigurować komputer, aby uzyskać adres IP za pośrednictwem protokołu DHCP?

Użyj klasy Win32_NetworkAdapterConfiguration i metody EnableDHCP.

strComputer = "."
Set objWMIService = GetObject(_
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration " _
        & "where IPEnabled=TRUE")
 
For Each objNetAdapter In colNetAdapters
    errEnable = objNetAdapter.EnableDHCP()
Next

... przypisać komputerowi statyczny adres IP?

Użyj klasy Win32_NetworkAdapterConfiguration i metody EnableStatic.

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration " _
        & "where IPEnabled=TRUE")
strIPAddress = Array("192.168.1.141")
strSubnetMask = Array("255.255.255.0")
strGateway = Array("192.168.1.100")
strGatewayMetric = Array(1)
 
For Each objNetAdapter in colNetAdapters
    errEnable = objNetAdapter.EnableStatic( _
        strIPAddress, strSubnetMask)
    errGateways = objNetAdapter.SetGateways(_
        strGateway, strGatewaymetric)
Next

... uzyskać informacje o kartach sieciowych bez pobierania informacji o takich sytuacjach jak połączenia RAS i VPN?

Użyj klasy Win32_NetworkAdapterConfiguration. W zapytaniu WQL użyj tej klauzuli: Gdzie IPEnabled = True.

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
    ("Select IPAddress from Win32_NetworkAdapterConfiguration" _
        & " where IPEnabled=TRUE")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i=LBound(IPConfig.IPAddress) _
        to UBound(IPConfig.IPAddress)
            WScript.Echo IPConfig.IPAddress(i)
        Next
    End If
Next

... ping komputera bez korzystania z Ping.exe?

Użyj klasy Win32_PingStatus.

Win32_PingStatus może zwracać dane dla komputerów z adresami IPv4 i adresami IPv6.

              
              strComputer = "." Set objWMIService = GetObject(_ "winmgmts:\" & strComputer & "\root\cimv2") Set colPings = objWMIService.ExecQuery _ ("Select * From Win32_PingStatus where Address = '192.168.1.1'") For Each objStatus in colPings
If IsNull(objStatus.StatusCode) _
or objStatus.StatusCode<>0 Then
WScript.Echo "Computer did not respond."
Else
Wscript.Echo "Computer responded."
End If
Next

strComputer = "client1"
Set objShell = CreateObject("WScript.Shell")
Set objScriptExec = objShell.Exec( _
    "ping -n 2 -w 1000 " & strComputer)
strPingResults = LCase(objScriptExec.StdOut.ReadAll)
If InStr(strPingResults, "reply from") Then
    If InStr(strPingResults, "destination net unreachable") Then
        WScript.Echo strComputer & "did not respond to ping."
    Else
        WScript.Echo strComputer & " responded to ping."
    End If 
Else
    WScript.Echo strComputer & " did not respond to ping."
End If

Zadania WMI dla skryptów i aplikacji
przykłady aplikacji WMI C++
TechNet ScriptCenter

Udostępnij za pośrednictwem

Zadania usługi WMI: sieć

Opinia

Dodatkowe zasoby

Udostępnij za pośrednictwem

Zadania usługi WMI: sieć

Tematy pokrewne

Opinia

Dodatkowe zasoby