OFFSET

Dotyczy:kolumna obliczeniowatabela obliczeniowaMiarawizualizacji

Zwraca pojedynczy wiersz umieszczony przed lub po bieżącym wierszu w tej samej tabeli według danego przesunięcia. Jeśli nie można wywołać bieżącego wiersza do jednego wiersza, może zostać zwróconych wiele wierszy.

Składnia

OFFSET ( <delta>[, <relation> or <axis>][, <orderBy>][, <blanks>][, <partitionBy>][, <matchBy>][, <reset>] )

Parametry

Wartość zwracana

Co najmniej jeden wiersz z relation.

Uwagi

Z wyjątkiem kolumn dodanych przez funkcje tabeli DAX każda kolumna w relation, gdy matchBy nie jest obecna, lub każda kolumna w matchBy i partitionBy, gdy matchBy jest obecna, musi mieć odpowiednią wartość zewnętrzną, aby ułatwić zdefiniowanie bieżącego wiersza, na którym ma działać, z następującym zachowaniem:

• Jeśli jest dokładnie jedna odpowiadająca kolumnie zewnętrznej, zostanie użyta jej wartość.
• Jeśli nie ma odpowiedniej kolumny zewnętrznej, wówczas:
  • OFFSET najpierw określi wszystkie kolumny, które nie mają odpowiedniej kolumny zewnętrznej.
  • Dla każdej kombinacji istniejących wartości dla tych kolumn w kontekście nadrzędnym OFFSETjest obliczana OFFSET i zwracany jest wiersz.
  • OFFSETkońcowe dane wyjściowe to połączenie tych wierszy.
• Jeśli istnieje więcej niż jedna odpowiadająca kolumna zewnętrzna, zwracany jest błąd.

Jeśli wszystkie kolumny relationzostały dodane przez funkcje tabeli DAX, zwracany jest błąd.

Jeśli matchBy jest obecny, OFFSET spróbuje użyć kolumn matchBy i partitionBy w celu zidentyfikowania wiersza. Jeśli matchBy nie istnieje, a kolumny określone w orderBy i partitionBy nie mogą jednoznacznie zidentyfikować każdego wiersza w relation, wówczas:

• OFFSET spróbuje znaleźć najmniejszą liczbę dodatkowych kolumn wymaganych do unikatowego zidentyfikowania każdego wiersza.
• Jeśli takie kolumny zostaną znalezione, OFFSET automatycznie dołączy te nowe kolumny do orderBy, a każda partycja zostanie posortowana przy użyciu tego nowego zestawu kolumn OrderBy.
• Jeśli nie można odnaleźć takich kolumn, zostanie zwrócony błąd.

Pusta tabela jest zwracana, jeśli:

• Odpowiadająca zewnętrzna wartość kolumny OrderBy lub PartitionBy nie istnieje w relation.
• Wartość delta powoduje przejście do wiersza, który nie istnieje w partycji.

Jeśli OFFSET jest używana w kolumnie obliczeniowej zdefiniowanej w tej samej tabeli co relation, a orderBy zostanie pominięta, zwracany jest błąd.

reset można używać tylko w obliczeniach wizualnych i nie można ich używać w połączeniu z orderBy lub partitionBy. Jeśli reset jest obecny, axis można określić, ale nie można relation.

Przykład 1 — kolumna obliczeniowa

Następujące zapytanie DAX:

DEFINE
VAR vRelation = SUMMARIZECOLUMNS ( 
                    DimProductCategory[EnglishProductCategoryName], 
                    DimDate[CalendarYear], 
                    "CurrentYearSales", SUM(FactInternetSales[SalesAmount]) 
                  )
EVALUATE
ADDCOLUMNS (
    vRelation, 
    "PreviousYearSales", 
    SELECTCOLUMNS(
        OFFSET ( 
                -1, 
                vRelation, 
                ORDERBY([CalendarYear]), 
                PARTITIONBY([EnglishProductCategoryName])
        ),
        [CurrentYearSales]
    )
)

Zwraca tabelę podsumowującą łączną sprzedaż dla każdej kategorii produktów i roku kalendarzowego, a także łączną sprzedaż dla tej kategorii w poprzednim roku.

Przykład 2 — miara

Następujące zapytanie DAX:

DEFINE
MEASURE DimProduct[CurrentYearSales] = SUM(FactInternetSales[SalesAmount])
MEASURE DimProduct[PreviousYearSales] = CALCULATE(SUM(FactInternetSales[SalesAmount]), OFFSET(-1, , ORDERBY(DimDate[CalendarYear])))
EVALUATE
SUMMARIZECOLUMNS (
    DimDate[CalendarYear],
    "CurrentYearSales", DimProduct[CurrentYearSales],
    "PreviousYearSales", DimProduct[PreviousYearSales]
)

Używa OFFSET() w mierze w celu zwrócenia tabeli, która podsumowuje łączną sprzedaż dla każdego roku kalendarzowego i łączną sprzedaż w poprzednim roku.

Przykład 3 — kolumna obliczeniowa

Następujące zapytanie DAX:

EVALUATE
ADDCOLUMNS (
    FactInternetSales,
    "Previous Sales Amount",
        SELECTCOLUMNS (
            OFFSET (
                -1,
                FactInternetSales,
                ORDERBY ( FactInternetSales[SalesAmount], DESC ),
                PARTITIONBY ( FactInternetSales[ProductKey] ),
                MATCHBY( FactInternetSales[SalesOrderNumber], FactInternetSales[SalesOrderLineNumber] )
            ),
            FactInternetSales[SalesAmount]
        )
)

Zwraca tabelę FactInternetSales z dodaniem kolumny, która wskazuje, że dla każdej sprzedaży kwota poprzedniej sprzedaży, tego samego produktu, w kolejności malejącej kwoty sprzedaży, z bieżącą sprzedażą identyfikowaną przez kolumnę SalesOrderNumber i SalesOrderLineNumber. Bez MATCHBYzapytanie zwróci błąd, ponieważ w tabeli FactInternetSales nie ma żadnych kluczowych kolumn.

Przykład 4 — obliczanie wizualizacji

Następujące obliczenie wizualizacji DAX zapytanie:

SalesRelativeToPreviousMonth = [SalesAmount] - CALCULATE(SUM([SalesAmount]), OFFSET(-1, ROWS, HIGHESTPARENT))

Zwraca różnicę w łącznej sprzedaży między każdym miesiącem a poprzednim w ciągu tego samego roku.

Poniższy zrzut ekranu przedstawia macierz wizualizacji i wyrażenie obliczania wizualizacji:

obliczania wizualizacji

Powiązana zawartość

INDEX ORDERBY PARTITIONBY MATCHBY WINDOW RANK ROWNUMBER