WMI-taken: netwerken

Artikel
03/14/2025

WMI-taken voor netwerken beheren en verkrijgen informatie over verbindingen en IP- of MAC-adressen. Zie het TechNet ScriptCenter op https://www.microsoft.com/technetvoor andere voorbeelden.

De scriptvoorbeelden die in dit onderwerp worden weergegeven, verkrijgen alleen gegevens van de lokale computer. Zie Verbinding maken met WMI op een externe computervoor meer informatie over het gebruik van het script om gegevens op te halen van externe computers.

In de volgende procedure wordt beschreven hoe u een script uitvoert.

Een script uitvoeren

Kopieer de code en sla deze op in een bestand met de extensie .vbs, zoals bestandsnaam.vbs. Zorg ervoor dat uw teksteditor geen .txt extensie aan het bestand toevoegt.
Open een opdrachtpromptvenster en navigeer naar de map waarin u het bestand hebt opgeslagen.
Typ cscript bestandsnaam.vbs bij de opdrachtprompt.
Als u geen toegang hebt tot een gebeurtenislogboek, controleer dan of u vanaf een opdrachtprompt met verhoogde rechten werkt. Sommige gebeurtenislogboeken, zoals het beveiligingslogboek, kunnen worden beveiligd door UAC (User Access Controls).

Notitie

In cscript wordt standaard de uitvoer van een script weergegeven in het opdrachtpromptvenster. Omdat WMI-scripts grote hoeveelheden uitvoer kunnen produceren, kunt u de uitvoer omleiden naar een bestand. Typ cscript bestandsnaam.vbs > outfile.txt bij de opdrachtprompt om de uitvoer van de bestandsnaam.vbs script om te leiden naar outfile.txt.

De volgende tabel bevat scriptvoorbeelden die kunnen worden gebruikt voor het verkrijgen van verschillende typen gegevens van de lokale computer.

Hoe kan ik... WMI-klassen of -methoden

... een netwerkverbinding uitschakelen met WMI?

Als u DHCP gebruikt, gebruikt u de Win32_NetworkAdapterConfiguration en de methode ReleaseDHCPLease om het IP-adres vrij te geven. Als u geen DHCP gebruikt, kunt u WMI niet gebruiken om een netwerkverbinding uit te schakelen. Gebruik objNetCard.RenewDHCPLeaseom de netwerkverbinding opnieuw in te schakelen. U kunt ook alle DHCP-leases vrijgeven of vernieuwen met behulp van de ReleaseDHCPLeaseAll en RenewDHCPLeaseAll methoden.

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetCards = objWMIService.ExecQuery _
    ("Select * From Win32_NetworkAdapterConfiguration " _
        & "Where IPEnabled = True")
For Each objNetCard in colNetCards
    objNetCard.ReleaseDHCPLease()
Next

PowerShell

$Computer = "."
$net = Get-WMIObject -class Win32_NetworkAdapterConfiguration -ComputerName $computer
$netenabled = $net | where {$_.IPenabled}
foreach ($NetCard in $netenabled) {
    "Releasing lease on: {0}" -f $netcard.caption
 $netcard.ReleaseDHCPLease()
}

... een NIC uitschakelen of inschakelen?

Gebruik de Win32_NetworkAdapter-klasse en de uitschakelen of methoden inschakelen.

... bepalen welk IP-adres is toegewezen aan een bepaalde netwerkverbinding?

Gebruik de klasse Win32_NetworkAdapter en de eigenschap NetConnectionID om het MAC-adres van de netwerkverbinding te bepalen. Gebruik vervolgens de Win32_NetworkAdapterConfiguration-klasse om het IP-adres te zoeken dat is gekoppeld aan het MAC-adres.

strComputer = "." Set objWMIService = GetObject(_ "winmgmts:\\" & strComputer & "\root\cimv2") Set colItems = objWMIService.ExecQuery _ ("Select * From Win32_NetworkAdapter " _ & "Where NetConnectionID = " & _ "'Local Area Connection 2'") Voor elke objItem in colItems strMACAddress = objItem.MACAddress Next Set colItems = objWMIService.ExecQuery _ ("Select * From Win32_NetworkAdapterConfiguration")

For Each objItem in colItems If objItem.MACAddress = strMACAddress Then For Each strIPAddress in objItem.IPAddress Wscript.Echo "IP Address: " & strIPAddress Next End If Next

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNics = objWMIService.ExecQuery _
    ("Select * From Win32_NetworkAdapter " _
        & "Where NetConnectionID = " & _
        "'Local Area Connection'")
 
For Each objNic in colNics
    Set colNicConfigs = objWMIService.ExecQuery _
      ("ASSOCIATORS OF " _
          & "{Win32_NetworkAdapter.DeviceID='" & _
      objNic.DeviceID & "'}" & _
      " WHERE AssocClass=Win32_NetworkAdapterSetting")
    For Each objNicConfig In colNicConfigs
        For Each strIPAddress in objNicConfig.IPAddress
            Wscript.Echo "IP Address: " &  strIPAddress
        Next
    Next
Next

... bepaalt u het MAC-adres van een netwerkadapter?

Gebruik de klasse Win32_NetworkAdapterConfiguration en controleer de waarde van de eigenschap MACAddress.

... bepaalt u het IP-adres van een computer?

Gebruik de klasse Win32_NetworkAdapterConfiguration en controleer de waarde van de eigenschap IPAddress. Dit wordt geretourneerd als een matrix, dus gebruik een For-Each lus om de waarde op te halen.

strComputer = "."
Set objWMIService = GetObject( _ 
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
    ("Select IPAddress from Win32_NetworkAdapterConfiguration ")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i=LBound(IPConfig.IPAddress) _
            to UBound(IPConfig.IPAddress)
                WScript.Echo IPConfig.IPAddress(i)
        Next
    End If
Next

PowerShell

$Computer = "."
$IPconfigset = Get-WmiObject Win32_NetworkAdapterConfiguration
  
# Iterate and get IP address
$count = 0
foreach ($IPConfig in $IPConfigSet) {
   if ($Ipconfig.IPaddress) {
      foreach ($addr in $Ipconfig.Ipaddress) {
   "IP Address   : {0}" -f  $addr;
   $count++ 
   }
   }
}
if ($count -eq 0) {"No IP addresses found"}
else {"$Count IP addresses found on this system"}

... een computer configureren om het IP-adres via DHCP op te halen?

Gebruik de Win32_NetworkAdapterConfiguration-klasse en de methode EnableDHCP.

strComputer = "."
Set objWMIService = GetObject(_
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration " _
        & "where IPEnabled=TRUE")
 
For Each objNetAdapter In colNetAdapters
    errEnable = objNetAdapter.EnableDHCP()
Next

... een statisch IP-adres toewijzen aan een computer?

Gebruik de klasse Win32_NetworkAdapterConfiguration en de methode EnableStatic.

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration " _
        & "where IPEnabled=TRUE")
strIPAddress = Array("192.168.1.141")
strSubnetMask = Array("255.255.255.0")
strGateway = Array("192.168.1.100")
strGatewayMetric = Array(1)
 
For Each objNetAdapter in colNetAdapters
    errEnable = objNetAdapter.EnableStatic( _
        strIPAddress, strSubnetMask)
    errGateways = objNetAdapter.SetGateways(_
        strGateway, strGatewaymetric)
Next

... informatie over netwerkadapters ophalen zonder ook informatie op te halen over bijvoorbeeld RAS- en VPN-verbindingen?

Gebruik de klasse Win32_NetworkAdapterConfiguration. Gebruik in uw WQL-query deze clausule: Waar IPEnabled = True.

strComputer = "."
Set objWMIService = GetObject( _
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
    ("Select IPAddress from Win32_NetworkAdapterConfiguration" _
        & " where IPEnabled=TRUE")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For i=LBound(IPConfig.IPAddress) _
        to UBound(IPConfig.IPAddress)
            WScript.Echo IPConfig.IPAddress(i)
        Next
    End If
Next

... een computer pingen zonder Ping.exete gebruiken?

Gebruik de klasse Win32_PingStatus.

Win32_PingStatus kan gegevens retourneren voor computers met zowel IPv4-adressen als IPv6-adressen.

              
              strComputer = "." Set objWMIService = GetObject(_ "winmgmts:\\" & strComputer & "\root\cimv2") Set colPings = objWMIService.ExecQuery _ ("Select * From Win32_PingStatus where Address = '192.168.1.1'") For Each objStatus in colPings
If IsNull(objStatus.StatusCode) _
or objStatus.StatusCode<>0 Then
WScript.Echo "Computer did not respond."
Else
Wscript.Echo "Computer responded."
End If
Next

strComputer = "client1"
Set objShell = CreateObject("WScript.Shell")
Set objScriptExec = objShell.Exec( _
    "ping -n 2 -w 1000 " & strComputer)
strPingResults = LCase(objScriptExec.StdOut.ReadAll)
If InStr(strPingResults, "reply from") Then
    If InStr(strPingResults, "destination net unreachable") Then
        WScript.Echo strComputer & "did not respond to ping."
    Else
        WScript.Echo strComputer & " responded to ping."
    End If 
Else
    WScript.Echo strComputer & " did not respond to ping."
End If

WMI-taken voor scripts en toepassingen
WMI C++-toepassingsvoorbeelden
TechNet ScriptCenter

Delen via

WMI-taken: netwerken

Feedback

Aanvullende resources

Delen via

WMI-taken: netwerken

Verwante onderwerpen

Feedback

Aanvullende resources