Del via

Table.TransformColumnTypes

  • Artikkel

Syntaks

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

Om

Returnerer en tabell ved å bruke transformeringsoperasjonene på de angitte kolonnene ved hjelp av en valgfri kultur.

  • table: Inndatatabellen som skal transformeres.
  • typeTransformations: Typen transformasjoner som skal brukes. Formatet for én enkelt transformasjon er { kolonnenavn, type verdi }. En liste over transformasjoner kan brukes til å endre typene for mer enn én kolonne om gangen. Hvis en kolonne ikke finnes, utløses en feil.
  • culture: (Valgfritt) Kulturen som skal brukes når du transformerer kolonnetypene (for eksempel "en-US").

Typeverdien i parameteren typeTransformations kan være any, alle number typer, text, alle date, time, datetime, datetimezoneog duration typer, logicaleller binary. Typene list, record, tableeller function er ikke gyldige for denne parameteren.

Eksempel 1

Transformer tallverdiene i den første kolonnen til tekstverdier.

bruk

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

utdata

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Eksempel 2

Transformer datoene i tabellen til de franske tekstekvivalentene.

bruk

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

utdata

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

Eksempel 3

Transformer datoene i tabellen til de tyske tekstekvivalentene, og verdiene i tabellen til prosent.

bruk

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

utdata

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Relatert innhold