Telemetrijas notikumi mobilās programmas sinhronizācijai un darbībām

Power Apps Mobilo lietojumprogrammu dati, kas saistīti ar bezsaistes sinhronizācijas notikumiem, ir pieejami modeļa vadītām un audekla programmām. Šos datus var izmantot, lai novērtētu bezsaistes sinhronizācijas notikumu darbspēju un veiktspēju jūsu organizācijā.

Šie dati tiek ievietoti Power Apps>mobilās programmas sinhronizācijas un darbību tabulā Application Insights. Ieraksts tiek reģistrēts, kad lietotājs piekļūst mobilajai Power Apps lietotnei, kas ir konfigurēta bezsaistes režīmam. Vairāk datu, kas saistīti ar kļūmju notikumiem modeļa vadītās lietotnēs, ir pieejami Power Apps>UCI.

Lai iegūtu papildu vaicājumu piemērus un informācijas paneļa paraugu, apmeklējiet vietni Telemetrijas informācijas paneļa paraugs Field Service mobilās programmas bezsaistes profila lietojumam.

Mobilo programmu sinhronizācijas un darbību notikumu definīcijas

• id: notikuma ID.
• mērķis: notikuma izsekotā scenārija nosaukums.
• veids: notikuma avota tabula.
• nosaukums: notikuma izsekotā scenārija nosaukums.
• ilgums: scenārija ilgums milisekundēs. Ilgums var ietvert ilgus laika periodus, kad lietotne ir neaktīva.
• operation_Id: sesijas unikālais identifikators.
• operation_ParentId: notikuma izsekotā scenārija unikālais identifikators.
• user_Id: Microsoft Entra lietotāja ID.
• application_Version: Lietotnes versija.
• customDimensions: satur šādus atribūtus:
  • "EventName": notikuma izsekotā scenārija kopsavilkums (ScenarioEnd).
  • "ScenarioResult": VEIKSME vai NEVEIKSME.
  • ErrorCode: sinhronizācijas kļūmes gadījumā ģenerēts kļūdas kods. Papildinformāciju skatiet rakstā Kļūdu kodu kartēšanas tabula.
  • ErrorMessage: iztukšots pēc veiksmīgas darbības vai virknes, kas apraksta kļūdu.
  • FailureType: definē sinhronizācijas kļūmes tipu.
  • LogLevel: notikuma nopietnība vai ziņošanas līmenis. Derīgas vērtības ir informācija, kļūda, brīdinājums, kļūda vai izvērsts.
  • DataSyncMode: kāda veida bezsaistes sinhronizāciju lietotājs ir piedzīvojis.
    • DELTA_SYNC: automātiska inkrementāla sinhronizācija.
    • GRID_SYNC: aktivizē režģa skata atsvaidzināšana.
    • FIRST_SYNC: Sākotnējā sinhronizācija ierīcē (vai pēc izrakstīšanās/pārkonfigurēšanas).
    • FORCED_SYNC: aktivizēts no lapas pogas Ierīces statuss.
    • SINGLE_RECORD_SYNC: Aktivizē pašpiegādes paziņojums.
  • AppFlavor: ierīcēs instalēta vietējā lietotne. Derīgas vērtības ir FieldService un PowerApps.
  • AppInfo_Version: vietējās lietotnes versija, kā redzams lietotņu veikalā.
  • ActiveDuration: scenārija ilgums milisekundēs, ieskaitot tikai laiku, kamēr programma ir aktīva.
  • DeviceInfo_Id: ierīces unikālais identifikators.
  • DeviceInfo_model: Ierīces modelis (piemēram, iPhone 13).
  • DeviceInfo_make: ierīces marka (piemēram, Apple).
  • DeviceInfo_OsName: Ierīces operētājsistēma (piemēram Android).
  • DeviceInfo_OsVersion: operētājsistēmas versija (piemēram, Android 13).
  • Loc_country: Telemetrijas ierīces izcelsme.
  • eventContext: Satur šādus rekvizītus:
    • CurrentSyncId: veiksmīgas sinhronizācijas caurlaides ID. Pēc katras veiksmīgas sinhronizācijas atiestatīšanas. (Tas netiek atiestatīts pēc kļūdas.)
    • CurrentActivityId: sinhronizācijas caurlaides ID. Atiestatīšana pēc katras sinhronizēšanas.
    • entityName: datu noņemšanas notikumu tabulas nosaukums.
    • ProfileId: programmai un lietotājam konfigurētā bezsaistes profila ID.
    • RecordCount: lejupielādēto ierakstu skaits.
    • ResponseSize: ienākošās lietderīgās slodzes datu lielums, kā ziņo HTTPClient (saspiests lielums).
    • ContentLength: ienākošās lietderīgās slodzes datu lielums, kā ziņo HTTPClient (saspiests lielums).

Vienotā klienta interfeisa kļūmes notikumi

• laika zīmogs [UTC]: kad notikums notika.
• problemId: "uci_trace" vai "uciMonitorFailure" (No kurienes tika iegūti dati.)
• ierakstiet: "uci_trace" vai "uciMonitorFailure" (No kurienes tika iegūti dati.)
• outType: "uci_trace" vai "uciMonitorFailure" (No kurienes nāk dati.)
• outerMessage: kļūdas ziņojums.
• vienumsTips: "izņēmums"
• Pielāgoti izmēri:
  • eventContext: Papildinformācija par kļūdu.
  • ServerConnectivityState: vai lietotājs darbojas bezsaistes režīmā? (Bezsaistē/tiešsaistē)
  • NetworkConnectivityState: vai lietotājam ir interneta savienojums? Ņemiet vērā, ka lietotājs var būt bezsaistes režīmā, bet viņam ir interneta savienojums.
  • IsOfflineByDefaultApp: ja tas ir aplams, tas nozīmē, ka līdzeklis Darbs bezsaistes režīmā ir ieslēgts. Ja tas ir patiess, tas nozīmē, ka vispirms ir ieslēgts bezsaistē .
  • callStack: programmēšanas kods, kurā radās kļūda.
  • hostSubType: "PowerApps-Player-iOS-fieldservice"
  • hostType: "MobileApplication"
• Operation_ID: sesijas ID virknes konkatenācija, kam seko "_" un ārējās korelācijas ID, piemēram, e11e8465-bc8f-4319-b64a-9c1e42453148_0da90a33-ad68-4a4e-bd45-5728d5da719a.
• Operation_ParentID: ar kļūdu saistīts darbības ID.
• SessionId: sesijas kļūdas ID.
• UserId: Dynamics 365 lietotāja ID.
• User_authenticatedID: Dynamics 365 lietotāja ID.
• Application_version: Lietotnes versija, piemēram ,9.2.24045.00212.
• Client_Type: operētājsistēmas versija, piemēram iOS , or Android.

Scenārija piemērs

Bezsaistes sinhronizācijas kļūmes pēc kļūdas koda

Šis vaicājums ļauj redzēt, ar kāda veida kļūmēm frontes darbinieki saskaras, ja sinhronizācija neizdodas. Dažas kļūmes ir izņēmums, piemēram, ja sinhronizācijas laikā mobilā lietojumprogramma ir aizvērta vai ja sinhronizācijas laikā tīkls atvienojas un neļauj pabeigt sinhronizāciju. Kļūmju kodu definīcija ir parādīta kļūdu kodu kartēšanas tabulā.

dependencies
| where name == "Offline.SyncDatabase"
| where success == false
| extend cd = parse_json(customDimensions)
| extend AppVersion = tostring(cd.AppInfo_Version)
| extend ErrorCode = tostring(cd.ErrorCode)
| extend ErrorMessage = tostring(cd.ErrorMessage)
| extend FailureType = tostring(cd.FailureType)
| summarize dcount(user_Id), count() by ErrorCode, ErrorMessage, FailureType, bin(timestamp, 1d)

Vidējie ieraksti, kas sinhronizēti ar tabulu

Šis vaicājums ļauj novērtēt, kuras tabulas sinhronizē lielāko daļu ierakstu. Izmantojot šos datus, varat mēģināt vēl vairāk optimizēt savu bezsaistes profilu , lai samazinātu ierakstus vai datus katrā tabulā.

dependencies
| where name endswith_cs "Offline.DdsClient.GetRecords"
| extend cd = parse_json(customDimensions)
| extend ec = parse_json(tostring(cd.eventContext))
| extend RecordCount = toint(ec.RecordCount)
| extend EntityName = tostring(ec.EntityName)
| extend syncid = tostring(ec.CurrentSyncId)
| extend DataSyncMode = tostring(cd.DataSyncMode)
//| where DataSyncMode == "FIRST_SYNC" //This is used to pivot on the type of sync being executed.
| summarize sum(RecordCount) by syncid, EntityName, DataSyncMode, user_Id
| summarize percentile(sum_RecordCount, 50), arg_max(sum_RecordCount, user_Id), count() by EntityName, DataSyncMode

Vidējais sinhronizācijas ilgums sinhronizācijas režīmā

Šis vaicājums ļauj novērtēt vidējo sinhronizācijas ilgumu lietotājiem jūsu organizācijā.

dependencies
| where name == "Offline.SyncDatabase"
| extend cd = parse_json(customDimensions)
| extend ActiveDuration = toint(tostring(cd.ActiveDuration))
| extend WithBackgroundTime = duration
| extend DataSyncMode = tostring(cd.DataSyncMode)
| summarize percentile(ActiveDuration, 50), percentile(WithBackgroundTime, 50) by client_Type, DataSyncMode

Lietotāja detalizētas informācijas sinhronizēšana

Šis vaicājums katram lietotājam nodrošina sinhronizācijas skatu, tostarp pēdējās sinhronizācijas datumu, pēdējo kļūdu, sinhronizācijas ilgumu un sinhronizētos ierakstus.

dependencies
| where name == "Offline.SyncDatabase"
| extend cd = parse_json(customDimensions)
| extend ActiveDuration = toint(tostring(cd.ActiveDuration))
| extend WithBackgroundTime = duration
| extend DataSyncMode = tostring(cd.DataSyncMode)
| extend ErrorMessage = tostring(cd.ErrorMessage)
| summarize percentile(ActiveDuration, 50), percentile(WithBackgroundTime, 50), arg_max(timestamp, ErrorMessage), countif(success == false) by user_Id, DataSyncMode

Lietotāji pēc ierīces veida un lietotnes versijas

Šis vaicājums sniedz papildinformāciju par lietotājiem jūsu organizācijā, kuri piekļūst mobilajai lietojumprogrammai savā ierīces modelī.

dependencies
| where name == "Offline.SyncDatabase"
| extend cd = parse_json(customDimensions)
| extend AppVersion = tostring(cd.AppInfo_Version)
| summarize dcount(user_Id) by AppVersion, client_Type

Kļūdu kodu kartēšana