다음을 통해 공유

ISINSCOPE

  • 아티클

적용 대상:계산 열계산 테이블측정값시각적 계산

지정된 열이 수준 계층 구조의 수준인 경우 true를 반환합니다.

통사론

ISINSCOPE(<columnName>)

매개 변수

학기 정의
columnName 표준 DAX 구문을 사용하는 기존 열의 이름입니다. 식일 수 없습니다.

반환 값

지정된 열이 수준 계층 구조의 수준인 경우 TRUE.

발언

이 함수는 계산 열 또는 RLS(행 수준 보안) 규칙에서 사용되는 경우 DirectQuery 모드에서 사용할 수 없습니다.

본보기

DEFINE
MEASURE FactInternetSales[% of Parent] =
  SWITCH (TRUE(),
    ISINSCOPE(DimProduct[Subcategory]),
      DIVIDE(
        SUM(FactInternetSales[Sales Amount]),
        CALCULATE(
          SUM(FactInternetSales[Sales Amount]),
          ALLSELECTED(DimProduct[Subcategory]))
      ),
    ISINSCOPE(DimProduct[Category]),
      DIVIDE(
        SUM(FactInternetSales[Sales Amount]), 
        CALCULATE(
          SUM(FactInternetSales[Sales Amount]),
          ALLSELECTED(DimProduct[Category]))
      ),
    1
  ) * 100
EVALUATE
  SUMMARIZECOLUMNS
  (
    ROLLUPADDISSUBTOTAL
    (
      DimProduct[Category], "Category Subtotal",
      DimProduct[Subcategory], "Subcategory Subtotal"
    ),
    TREATAS(
      {"Bike Racks", "Bike Stands", "Mountain Bikes", "Road Bikes", "Touring Bikes"},
      DimProduct[Subcategory]),
    "Sales", SUM(FactInternetSales[Sales Amount]),
    "% of Parent", [% of Parent]
  )
  ORDER BY
    [Category Subtotal] DESC, [Category],
    [Subcategory Subtotal] DESC, [Subcategory]

반환

DimProduct[범주] DimProduct[SubCategory] [범주 부분합] [하위 범주 부분합] [판매액] [ 부모%]
TRUE TRUE 28,397,095.65 100.00
액세서리 FALSE TRUE 78,951.00 0.28
액세서리 자전거 랙 FALSE FALSE 39,360.00 49.85
액세서리 자전거 스탠드 FALSE FALSE 39,591.00 50.15
자전거 FALSE TRUE 28,318,144.65 99.72
자전거 산악 자전거 FALSE FALSE 9,952,759.56 35.15
자전거 로드 바이크 FALSE FALSE 14,520,584.04 51.28
자전거 투어링 바이크 FALSE FALSE 3,844,801.05 13.58

관련 콘텐츠

SUMMARIZECOLUMNS 함수CALCULATE 함수