CONCATENATE
Unisce due stringhe di testo in una stringa di testo.
Sintassi
CONCATENATE(<text1>, <text2>)
Parametri
| Termine | Definizione |
|---|---|
text1 |
Prima stringa di testo da unire in una singola stringa di testo. La stringa può includere testo o numeri. È anche possibile usare riferimenti a colonne. |
text2 |
Seconda stringa di testo da unire in una singola stringa di testo. La stringa può includere testo o numeri. È anche possibile usare riferimenti a colonne. |
Valore restituito
Stringa concatenata.
Osservazioni
La funzione CONCATENATE unisce due stringhe di testo in una stringa di testo. Gli elementi uniti possono essere testo, numeri, valori booleani rappresentati come testo o una combinazione di tali elementi. È anche possibile usare un riferimento a una colonna se la colonna contiene valori appropriati.
La funzione CONCATENATE in DAX accetta solo due argomenti, mentre la funzione CONCATENATE di Excel accetta fino a 255 argomenti. Se è necessario concatenare più colonne, è possibile creare una serie di calcoli o usare l'operatore di concatenazione (
&) per unirli a tutti in un'espressione più semplice.Se si desidera utilizzare direttamente stringhe di testo, anziché usare un riferimento a una colonna, è necessario racchiudere ogni stringa tra virgolette doppie.
Questa funzione non è supportata per l'uso in modalità DirectQuery quando viene usata nelle colonne calcolate o nelle regole di sicurezza a livello di riga.
Esempio: Concatenazione di valori letterali
La formula di esempio crea un nuovo valore stringa combinando due valori stringa specificati come argomenti.
= CONCATENATE("Hello ", "World")
Esempio: Concatenazione di stringhe nelle colonne
La formula di esempio restituisce il nome completo del cliente, come indicato in una rubrica telefonica. Si noti come viene usata una funzione nidificata come secondo argomento. Questo è un modo per concatenare più stringhe quando sono presenti più di due valori da usare come argomenti.
= CONCATENATE(Customer[LastName], CONCATENATE(", ", Customer[FirstName]))
Esempio: Concatenazione condizionale di stringhe nelle colonne
La formula di esempio crea una nuova colonna calcolata nella tabella Customer con il nome completo del cliente come combinazione di nome, iniziali intermedio e cognome. Se non è presente alcun secondo nome, il cognome viene direttamente dopo il nome. Se è presente un secondo nome, viene usata solo la prima lettera del secondo nome e la lettera iniziale è seguita da un punto.
= CONCATENATE( [FirstName]&" ", CONCATENATE( IF( LEN([MiddleName])>1, LEFT([MiddleName],1)&". ", ""), [LastName]))
Questa formula usa funzioni annidate CONCATENATE e IF, insieme all'operatore e commerciale (&), per concatenare in modo condizionale tre valori stringa e aggiungere spazi come separatori.
Esempio: Concatenazione di colonne con tipi di dati diversi
Nell'esempio seguente viene illustrato come concatenare valori in colonne con tipi di dati diversi. Se il valore concatenato è numerico, il valore verrà convertito in modo implicito in testo. Se entrambi i valori sono numerici, entrambi i valori verranno eseguiti nel testo e concatenati come se fossero stringhe.
| Descrizione del prodotto | Abbreviazione del prodotto (colonna 1 della chiave composita) | Numero prodotto (colonna 2 della chiave composita) | Nuova colonna chiave generata |
|---|---|---|---|
| Rampichino | MTN | 40 | MTN40 |
| Rampichino | MTN | 42 | MTN42 |
= CONCATENATE('Products'[Product abbreviation],'Products'[Product number])
La funzione CONCATENATE in DAX accetta solo due argomenti, mentre la funzione CONCATENATE di Excel accetta fino a 255 argomenti. Se è necessario aggiungere altri argomenti, è possibile usare l'operatore e commerciale (&). Ad esempio, la formula seguente produce i risultati, MTN-40 e MTN-42.
= [Product abbreviation] & "-" & [Product number]