Properti Session.Timeout

Mengatur dan mendapatkan jumlah waktu maksimum, dalam milidetik, bahwa aplikasi klien menunggu Windows Remote Management untuk menyelesaikan operasinya.

Properti ini bersifat baca/tulis.

Sintaks

Session.Timeout As long

Nilai properti

Nilai waktu habis, dalam milidetik. Ketika nilai waktu habis terlampaui, kesalahan run-time terjadi.

Keterangan

Nilai waktu habis dapat diatur sebelum setiap operasi dilakukan oleh agen. Jika nilai waktu habis tidak ditentukan, agen menetapkan nilai waktu habis.

Selama operasi enumerasi, nilai waktu habis tidak dapat direset saat sumber daya sedang dijumlahkan.

Contoh

Contoh kode VBScript berikut memulai proses Calc.exe menggunakan metode Create dari kelas Win32_Process WMI. Parameter strInputParameters berisi parameter input dalam format XML. Skrip menentukan waktu habis untuk sesi.

Set objWsman = CreateObject( "WSMan.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" & _
    "wmi/root/cimv2/Win32_Process"

'Reset timeout to 10,000 milliseconds
objSession.Timeout = 10000     

strInputParameters = "<p:Create_INPUT " & _
    "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/Win32_Process"">" & _
    "<p:CommandLine>" & "calc.exe" & _
    "</p:CommandLine>" & _
    "</p:Create_INPUT>"

strOutputParameters = objSession.Invoke( "Create", _
    strResource, strInputParameters )

DisplayOutput( strOutputParameters )

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Persyaratan

Lihat juga

Sesi