Metode Session.Invoke

Memanggil metode dan mengembalikan hasil panggilan metode.

Sintaks

Session.Invoke( _
  ByVal actionUri, _
  ByVal resourceUri, _
  ByVal parameters, _
  [ ByVal flags ] _
)

Parameter

actionUri [in]

URI metode untuk dipanggil.

resourceUri [in]

Pengidentifikasi sumber daya yang akan diambil.

Parameter ini dapat berisi salah satu hal berikut:

• URI dengan atau tanpa pemilih. Dalam contoh Visual Basic Scripting Edition (VBScript) berikut, kunci ditentukan oleh Win32_Service?Name=winmgmt.

  strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/" _ 
     & "Win32_Service?Name=winmgmt"
  

• Objek ResourceLocator yang mungkin berisi pemilih, fragmen, atau opsi.

• Referensi titik akhir WS-Addressing seperti yang dijelaskan dalam standar Protokol Manajemen WS. Untuk informasi selengkapnya tentang spesifikasi publik untuk protokol WS-Management, lihat Halaman Indeks Spesifikasi Manajemen.

parameter [ in]

Representasi XML dari input untuk metode . String ini harus disediakan atau metode ini akan gagal.

bendera [in, opsional]

Dicadangkan. Harus diatur ke 0.

Nilai kembali

Representasi XML dari output metode.

Contoh

Contoh kode VBScript berikut memulai proses Calc.exe. Parameter strInputParameters berisi parameter input dalam format XML. Satu-satunya parameter input yang diperlukan untuk metode Buat kelas Win32_Process WMI adalah baris perintah untuk dijalankan.

Set objWsman = CreateObject( "WSMan.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" & _
    "wmi/root/cimv2/Win32_Process"

strInputParameters = "<p:Create_INPUT " & _
    "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/Win32_Process"">" & _
    "<p:CommandLine>" & "calc.exe" & _
    "</p:CommandLine>" & _
    "</p:Create_INPUT>"

strOutputParameters = objSession.Invoke( "Create", _
    strResource, strInputParameters )

DisplayOutput( strOutputParameters )

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Contoh kode VBScript berikut memanggil metode Session.Invoke untuk menjalankan metode StopServiceWin32_Service. Metode StopService tidak memiliki parameter input. Namun, metode Panggil memerlukan string XML dalam parameter .

Option Explicit

Dim objWsman
Dim objSession
Dim strResponse
Dim strActionURI
Dim strInputXml
Dim strResourceURI
Dim strMethodName

set objWsman = CreateObject("Wsman.Automation")
set objSession = objWsman.CreateSession
strResourceURI = "http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service?Name=w32time"
strMethodName = "StopService"
strActionURI = strMethodName                                      

strInputXml = "<p:StopService_INPUT " _
    & "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service""/>"

strResponse = objSession.Invoke(strMethodName, strResourceURI, strInputXml)

call DisplayOutput(strResponse)
 
strMethodName = "StartService" 
strActionURI = strResourceURI & "/" & strMethodName  
strInputXml = "<p:StartService_INPUT " _
    & "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service""/>"
strResponse = objSession.Invoke(strMethodName, _
    strResourceURI, strInputXml)

call DisplayOutput(strResponse)

 
'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************

Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" )    
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile )           
End Sub

Persyaratan

Lihat juga

Sesi