Mengonfigurasi SQL Server yang diaktifkan oleh Azure Arc

Berlaku untuk:SQL Server

Setiap server berkemampuan Azure Arc menyertakan sekumpulan properti yang berlaku untuk semua instans SQL Server yang diinstal di server tersebut. Anda dapat mengonfigurasi properti ini setelah Ekstensi Azure untuk SQL Server diinstal pada komputer. Namun, properti hanya berlaku jika instans SQL Server diinstal. Di portal Azure, panel Gambaran Umum untuk SQL Server yang diaktifkan oleh Azure Arc mencerminkan bagaimana konfigurasi SQL Server memengaruhi instans tertentu.

Prasyarat

• Anda memiliki peran Kontributor di setidaknya salah satu langganan Azure yang dibuat organisasi Anda. Pelajari cara membuat berlangganan tagihan baru.

• Anda memiliki peran Kontributor untuk grup sumber daya tempat instans SQL Server akan didaftarkan. Untuk detailnya, lihat Grup sumber daya Azure Terkelola.

• Penyedia Microsoft.AzureArcData sumber daya dan Microsoft.HybridCompute terdaftar di setiap langganan yang Anda gunakan untuk penagihan prabayar SQL Server.

Mendaftarkan penyedia sumber daya

Untuk mendaftarkan penyedia sumber daya, gunakan salah satu metode berikut:

Register-AzResourceProvider -ProviderNamespace Microsoft.AzureArcData

az provider register --namespace 'Microsoft.AzureArcData'

Mengubah konfigurasi SQL Server

Anda dapat menggunakan portal Azure, Azure PowerShell, atau Azure CLI untuk mengubah semua atau beberapa pengaturan konfigurasi pada server tertentu dengan dukungan Azure Arc ke status yang diinginkan.

Untuk mengubah konfigurasi SQL Server untuk cakupan yang lebih besar (seperti grup sumber daya, langganan, atau beberapa langganan) dengan satu perintah, gunakan modify-license-type.ps1 skrip PowerShell. Ini diterbitkan sebagai sampel SQL Server sumber terbuka dan menyertakan instruksi langkah demi langkah.

Kami menyarankan agar Anda menjalankan skrip dari Azure Cloud Shell karena:

• Ini memiliki modul Azure PowerShell yang diperlukan yang telah diinstal sebelumnya.
• Ini secara otomatis mengautentikasi Anda.

Untuk detailnya, lihat Menjalankan skrip menggunakan Cloud Shell.

# Updated settings object
$Settings = @{
    SqlManagement = @{ IsEnabled = $true };
    ExcludedSqlInstances = @( "Foo", "Bar");
    LicenseType = "PAYG";
    enableExtendedSecurityUpdates = $True;
    esuLastUpdatedTimestamp = [DateTime]::UtcNow.ToString('yyyy-MM-ddTHH:mm:ss.fffZ')
}

# Command stays the same as before; only Settings is changed
New-AzConnectedMachineExtension -Name "WindowsAgent.SqlServer" -ResourceGroupName { your resource group name } -MachineName { your machine name } -Location { azure region } -Publisher "Microsoft.AzureData" -Settings $Settings -ExtensionType "WindowsAgent.SqlServer"

az connectedmachine extension update --machine-name "simple-vm" -g "<resource-group>" --name "WindowsAgent.SqlServer" --type "WindowsAgent.SqlServer" --publisher "Microsoft.AzureData" --settings '{"LicenseType":"PAYG", "SqlManagement": {"IsEnabled":true}}'

Berlangganan Pembaruan Keamanan Diperpanjang dalam skala besar dengan menggunakan Azure Policy

Anda dapat mengaktifkan langganan ESU pada beberapa mesin yang diaktifkan Azure Arc dengan menggunakan definisi Azure Policy yang disebut Berlangganan instans SQL Server yang diaktifkan Arc dan memenuhi syarat ke Pembaruan Keamanan yang Diperpanjang.

Saat Anda membuat penetapan definisi kebijakan ini ke cakupan pilihan Anda, ESUs diaktifkan pada semua mesin yang didukung Azure Arc yang terpasang Ekstensi Azure untuk SQL Server. Jika salah satu komputer ini memiliki instans SQL Server yang memenuhi syarat, langganan ESU segera diaktifkan.

Gunakan langkah-langkah berikut untuk mengaktifkan kebijakan ini:

1. Di portal Azure, buka Azure Policy, lalu pilih Definisi.

2. Cari instans SQL Server berkemampuan Arc yang memenuhi syarat untuk Pembaruan Keamanan yang Diperpanjang dan daftarkan, lalu klik kanan pada kebijakan tersebut.

3. Pilih Tetapkan kebijakan.

4. Pilih langganan dan secara opsional grup sumber daya sebagai cakupan.

5. Pastikan penegakan kebijakan diatur ke Diaktifkan.

6. Pada tab Parameter , atur nilai Aktifkan Pembaruan Keamanan diperpanjang ke True.

7. Pada tab Remediasi :

   1. Pilih Buat tugas remediasi agar kebijakan ini diterapkan ke sumber daya yang ada. Jika Anda tidak memilih opsi ini, kebijakan diterapkan ke sumber daya yang baru dibuat saja.
   2. Pilih Buat Identitas Terkelola, lalu pilih Identitas terkelola yang ditetapkan sistem (disarankan) atau Identitas terkelola yang ditetapkan pengguna, yang memiliki Ekstensi Azure untuk izin Penyebaran dan Pembaca SQL Server.
   3. Pilih lokasi identitas.

8. Pilih Tinjau + Buat.

9. Pilih Buat.

Mengkueri konfigurasi SQL Server

Anda dapat menggunakan Azure Resource Graph untuk mengkueri pengaturan konfigurasi SQL Server dalam cakupan yang dipilih. Lihat contoh berikut.

Mendapatkan hitungan menurut jenis lisensi

Contoh ini mengembalikan hitungan menurut jenis lisensi:

resources
| where type == "microsoft.hybridcompute/machines/extensions"
| where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
| extend licenseType = iff(properties.settings.LicenseType == '', 'Configuration needed', properties.settings.LicenseType)
| summarize count() by tostring(licenseType)

Mengidentifikasi instans di mana jenis lisensi tidak terdefinisi

Kueri ini mengembalikan daftar instans di mana jenis lisensi adalah null:

resources
| where type == "microsoft.hybridcompute/machines/extensions"
| where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
| where isnull(properties.settings.LicenseType)
| project ['id'], resourceGroup, subscriptionId

Mencantumkan detail konfigurasi untuk setiap instans SQL Server

Kueri ini mengidentifikasi banyak detail tentang setiap instans, termasuk jenis lisensi, pengaturan ESU, dan fitur yang diaktifkan:

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
| extend machineIdHasSQLServerDiscovered = id
| project name, machineIdHasSQLServerDiscovered, resourceGroup, subscriptionId
| join kind= leftouter (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"    | where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
    | extend machineIdHasSQLServerExtensionInstalled = iff(id contains "/extensions/WindowsAgent.SqlServer" or id contains "/extensions/LinuxAgent.SqlServer", substring(id, 0, indexof(id, "/extensions/")), "")
    | project Extension_State = properties.provisioningState,
    License_Type = properties.settings.LicenseType,
    ESU = iff(notnull(properties.settings.enableExtendedSecurityUpdates), iff(properties.settings.enableExtendedSecurityUpdates == true,"enabled","disabled"), ""),
    Extension_Version = properties.instanceView.typeHandlerVersion,
    Excluded_instances = properties.ExcludedSqlInstances,
    Purview = iff(notnull(properties.settings.ExternalPolicyBasedAuthorization),"enabled",""),
    Entra = iff(notnull(properties.settings.AzureAD),"enabled",""),
    BPA = iff(notnull(properties.settings.AssessmentSettings),"enabled",""),
    machineIdHasSQLServerExtensionInstalled)on $left.machineIdHasSQLServerDiscovered == $right.machineIdHasSQLServerExtensionInstalled
| where isnotempty(machineIdHasSQLServerExtensionInstalled)
| project-away machineIdHasSQLServerDiscovered, machineIdHasSQLServerExtensionInstalled

Mencantumkan server berkemampuan Azure Arc dengan instans SQL Server

Kueri ini mengidentifikasi server dengan dukungan Azure Arc dengan instans SQL Server yang ditemukan di dalamnya:

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
//| summarize count()

Kueri ini mengembalikan server dengan dukungan Azure Arc yang memiliki instans SQL Server, tetapi ekstensi Azure Arc SQL Server tidak diinstal. Kueri ini hanya berlaku untuk server Windows.

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
| project machineIdHasSQLServerDiscovered = id
| join kind= leftouter (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"
    | where properties.type == "WindowsAgent.SqlServer"
    | project machineIdHasSQLServerExtensionInstalled = substring(id, 0, indexof(id, "/extensions/WindowsAgent.SqlServer")))
on $left.machineIdHasSQLServerDiscovered == $right.machineIdHasSQLServerExtensionInstalled
| where isempty(machineIdHasSQLServerExtensionInstalled)
| project machineIdHasSQLServerDiscoveredButNotTheExtension = machineIdHasSQLServerDiscovered

Untuk contoh kueri Azure Resource Graph lainnya, lihat Sampel kueri Starter Resource Graph.

Mencantumkan instans SQL Server dengan dukungan Azure Arc yang berlangganan ESUs

Contoh berikut menunjukkan bagaimana Anda dapat melihat semua instans SQL Server 2012 (11.x) atau SQL Server 2014 (12.x) yang memenuhi syarat dan status langganan ESU-nya:

resources
| where type == 'microsoft.azurearcdata/sqlserverinstances'
| extend Version = properties.version
| extend Edition = properties.edition
| extend containerId = tolower(tostring (properties.containerResourceId))
| where Version in ("SQL Server 2012", "SQL Server 2014")
| where Edition in ("Enterprise", "Standard")
| where isnotempty(containerId)
| project containerId, SQL_instance = name, Version, Edition
| join kind=inner (
    resources
    | where type == "microsoft.hybridcompute/machines"
    | extend machineId = tolower(tostring(id))
    | project machineId, Machine_name = name
)
on $left.containerId == $right.machineId
| join kind=inner (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"
    | where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
    | extend machineIdHasSQLServerExtensionInstalled = tolower(iff(id contains "/extensions/WindowsAgent.SqlServer" or id contains "/extensions/LinuxAgent.SqlServer", substring(id, 0, indexof(id, "/extensions/")), ""))
    | project machineIdHasSQLServerExtensionInstalled,
     Extension_State = properties.provisioningState, 
     License_Type = properties.settings.LicenseType, 
     ESU = iff(notnull(properties.settings.enableExtendedSecurityUpdates), iff(properties.settings.enableExtendedSecurityUpdates == 'true',"ENABLED","disabled"), "disabled"),
     Extension_Version = properties.instanceView.typeHandlerVersion
)
on $left.machineId == $right.machineIdHasSQLServerExtensionInstalled
| project-away machineId, containerId, machineIdHasSQLServerExtensionInstalled

Mencantumkan server dengan dukungan Azure Arc yang menghosting instans SQL Server yang dapat ditagih

Kueri ini mengidentifikasi komputer yang terhubung (virtual atau fisik) yang menghosting instans SQL Server dan yang dapat ditagih atau memerlukan lisensi untuk perangkat lunak SQL Server. Ini menyediakan detail konfigurasi SQL Server, termasuk jenis lisensi, pengaturan ESU, ukuran dalam v-core atau p-core, dan parameter relevan lainnya.

resources
| where type =~ 'Microsoft.HybridCompute/machines'
| extend status = tostring(properties.status)
| where status =~ 'Connected'
| extend machineID = tolower(id)
| extend VMbyManufacturer = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "VMware" or
    properties.detectedProperties.manufacturer contains_cs "QEMU" or
    properties.detectedProperties.manufacturer contains_cs "Amazon EC2" or
    properties.detectedProperties.manufacturer contains_cs "OpenStack" or
    properties.detectedProperties.manufacturer contains_cs "Hetzner" or
    properties.detectedProperties.manufacturer contains_cs "Mission Critical Cloud" or
    properties.detectedProperties.manufacturer contains_cs "DigitalOcean" or
    properties.detectedProperties.manufacturer contains_cs "UpCloud" or
    properties.detectedProperties.manufacturer contains_cs "oVirt" or
    properties.detectedProperties.manufacturer contains_cs "Alibaba" or
    properties.detectedProperties.manufacturer contains_cs "KubeVirt" or
    properties.detectedProperties.manufacturer contains_cs "Parallels" or
    properties.detectedProperties.manufacturer contains_cs "Bochs" or
    properties.detectedProperties.manufacturer contains_cs "XEN", 1, 0))
| extend VMbyModel = toboolean(iff(
    properties.detectedProperties.model contains_cs "OpenStack" or
    properties.detectedProperties.model contains_cs "Droplet" or
    properties.detectedProperties.model contains_cs "oVirt" or
    properties.detectedProperties.model contains_cs "Hypervisor" or
    properties.detectedProperties.model contains_cs "Virtual" or
    properties.detectedProperties.model contains_cs "BHYVE" or
    properties.detectedProperties.model contains_cs "KVM", 1, 0))
| extend GoogleVM = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "Google" and
    properties.detectedProperties.model contains_cs "Google Compute Engine", 1, 0))
| extend NutanixVM = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "Nutanix" and
    properties.detectedProperties.model contains_cs "AHV", 1, 0))
| extend MicrosoftVM = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "Microsoft Corporation" and
    properties.detectedProperties.model contains_cs "Virtual Machine", 1, 0))
| extend billableCores = iff(
    VMbyManufacturer or VMbyModel or GoogleVM or NutanixVM or MicrosoftVM,
    properties.detectedProperties.logicalCoreCount,
    properties.detectedProperties.coreCount)
| join kind=leftouter (
    resources
    | where type =~ 'Microsoft.HybridCompute/machines/extensions'
    | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
    | extend extMachineID = substring(id, 0, indexof(id, '/extensions'))
    | extend extensionId = id
) on $left.id == $right.extMachineID
| join kind=inner (
    resources
    | where type =~ 'microsoft.azurearcdata/sqlserverinstances'
    | extend sqlVersion = tostring(properties.version)
    | extend sqlEdition = tostring(properties.edition)
    | extend is_Enterprise = toint(iff(sqlEdition == "Enterprise", 1, 0))
    | extend sqlStatus = tostring(properties.status)
    | extend licenseType = tostring(properties.licenseType)
    | where sqlEdition in ('Enterprise', 'Standard')
    | where licenseType !~ 'HADR'
    | extend ArcServer = tolower(tostring(properties.containerResourceId))
    | order by sqlEdition
) on $left.machineID == $right.ArcServer
| where isnotnull(extensionId)
| summarize Edition = iff(sum(is_Enterprise) > 0, "Enterprise", "Standard") by machineID, name, resourceGroup, subscriptionId, Status = tostring(properties.status), Model = tostring(properties.detectedProperties.model), Manufacturer = tostring(properties.detectedProperties.manufacturer), License_Type = tostring(properties1.settings.LicenseType), ESU = iff(notnull(properties1.settings.enableExtendedSecurityUpdates), iff(properties1.settings.enableExtendedSecurityUpdates == true, "enabled", "not enabled"), "not enabled"), OS = tostring(properties.osName), Uses_UV = tostring(properties1.settings.UsePhysicalCoreLicense.IsApplied), Cores = tostring(billableCores), Version = sqlVersion, HostType = iff(VMbyManufacturer or VMbyModel or GoogleVM or NutanixVM or MicrosoftVM, "VM", "Physical")
| summarize by name, subscriptionId, resourceGroup, Model, Manufacturer, HostType, License_Type, ESU, OS, Cores, Status
| project Name = name, Model, Manufacturer, HostType, OperatingSystem = OS, Status, HostLicenseType = License_Type, ESU, BillableCores = Cores, SubscriptionID = subscriptionId, ResourceGroup = resourceGroup
| order by Name asc

Mengelola manfaat virtualisasi tanpa batas untuk SQL Server

Untuk mengaktifkan virtualisasi tanpa batas, SQL Server yang diaktifkan oleh Azure Arc mendukung jenis sumber daya khusus: SQLServerLicense. Anda dapat menggunakan sumber daya ini untuk melisensikan banyak komputer virtual dengan instans SQL Server yang diinstal. Untuk detail tentang model lisensi, lihat Melisensikan instans SQL Server dengan virtualisasi tak terbatas.

Prasyarat

Peran kontrol akses berbasis peran (RBAC) Anda mencakup izin berikut:

• Microsoft.AzureArcData/SqlLicenses/read
• Microsoft.AzureArcData/SqlLicenses/write
• Microsoft.Management/managementGroups/read
• Microsoft.Resources/subscriptions/read
• Microsoft.Resources/subscriptions/resourceGroups/read
• Microsoft.Support/supporttickets/write

Membuat lisensi SQL Server

Untuk membuat sumber daya lisensi SQL Server, gunakan salah satu metode berikut:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="sqlserverlicense.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/sqlserverlicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method put --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

"location": "westeurope",
"properties": {
    "billingPlan": "PAYG",
    "physicalCores": 32,
    "activationState": "Deactivated",
    "scopeType": "ResourceGroup",
    "licenseCategory": "Core"
}

Memperbarui sumber daya lisensi SQL Server

Untuk mengubah properti lisensi SQL Server (misalnya, aktifkan di kemudian hari), gunakan salah satu metode berikut:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="activate.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/sqlserverlicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method patch --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

{
  "activationState": "Activated"
}

Mengelola sumber daya dalam cakupan lisensi p-core

Anda dapat mengelola sumber daya dalam cakupan lisensi inti fisik SQL Server tertentu dengan menggunakan langkah-langkah berikut:

Mencantumkan server berkemampuan Azure Arc dalam cakupan lisensi SQL Server

Kueri ini mencantumkan semua server dengan dukungan Azure Arc dalam cakupan lisensi dan properti yang relevan dari masing-masing:

resources
        | where type =~ 'Microsoft.HybridCompute/machines'
        | where ('${scopeType}'!= 'Subscription' or subscriptionId == '${subscription}')
        | where ('${scopeType}' != 'ResourceGroup' or (resourceGroup == '${resourceGroup.toLowerCase()}' and subscriptionId == '${subscription}'))
        | extend status = tostring(properties.status)
        | where status =~ 'Connected'
        | join kind = leftouter
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend machineId = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.machineId
        | where isnotnull(extensionId)
        | project id, name, properties.status, resourceGroup, subscriptionId, Model = properties.detectedProperties.model, Manufacturer = properties.detectedProperties.manufacturer, kind, OSE = properties.osName, License_applied = properties1.settings.UsePhysicalCoreLicense.IsApplied
        |order by name asc

Mengelola manfaat virtualisasi tanpa batas untuk langganan SQL Server ESU

Untuk mengaktifkan virtualisasi tak terbatas untuk langganan ESU, SQL Server yang diaktifkan oleh Azure Arc mendukung jenis sumber daya khusus: SQLServerEsuLicense. Anda dapat menggunakan sumber daya ini untuk mengaktifkan langganan ESU untuk sekumpulan host fisik dengan jumlah komputer virtual yang tidak terbatas yang menjalankan instans SQL Server yang tidak didukung. Untuk detail tentang model lisensi, lihat Berlangganan SQL Server ESUs dengan menggunakan inti fisik dengan virtualisasi tak terbatas.

Prasyarat

Peran RBAC milik Anda mencakup izin berikut:

• Microsoft.AzureArcData/SqlLicenses/read
• Microsoft.AzureArcData/SqlLicenses/write
• Microsoft.Management/managementGroups/read
• Microsoft.Resources/subscriptions/read
• Microsoft.Resources/subscriptions/resourceGroups/read
• Microsoft.Support/supporttickets/write

Membuat sumber daya lisensi SQL Server ESU

Untuk membuat sumber daya lisensi SQL Server ESU, gunakan salah satu metode berikut:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="sqlserverlicense.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/SqlServerEsuLicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method put --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

"location": "westeurope",
"properties": {
    "billingPlan": "PAYG",
    "physicalCores": 32,
    "activationState": "Active",
    "scopeType": "ResourceGroup",
    "version": "2014"
}

Memperbarui sumber daya lisensi SQL Server ESU

Untuk mengubah properti lisensi SQL Server ESU (misalnya, hentikan langganan), gunakan salah satu metode berikut:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="terminate.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/SqlServerEsuLicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method patch --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

{
  "activationState": "Terminated"
}

Mengelola sumber daya dalam cakupan lisensi ESU p-core

Anda dapat mengelola sumber daya dalam cakupan lisensi ESU SQL Server tertentu dengan menggunakan langkah-langkah berikut:

Mencantumkan server dengan dukungan Azure Arc dalam cakupan lisensi ESU SQL Server

Kueri ini mencantumkan semua server dengan dukungan Azure Arc dalam cakupan lisensi dan properti yang relevan dari masing-masing:

resources
        | where type =~ 'Microsoft.HybridCompute/machines'
        | where ('${scopeType}'!= 'Subscription' or subscriptionId == '${subscription}')
        | where ('${scopeType}' != 'ResourceGroup' or (resourceGroup == '${resourceGroup.toLowerCase()}' and subscriptionId == '${subscription}'))
        | extend status = tostring(properties.status)
        | where status =~ 'Connected'
        | join kind = leftouter
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend machineId = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.machineId
        | where isnotnull(extensionId)
        | project id, name, properties.status, resourceGroup, subscriptionId, Model = properties.detectedProperties.model, Manufacturer = properties.detectedProperties.manufacturer, kind, OSE = properties.osName, License_applied = properties1.settings.UseEsuPhysicalCoreLicense.IsApplied
        |order by name asc

Konten terkait

• Mengelola lisensi dan penagihan SQL Server yang diaktifkan oleh Azure Arc
• Harga SQL Server 2022
• Panduan penginstalan SQL Server
• Apa itu Pembaruan Keamanan yang Diperpanjang untuk SQL Server?
• Tanya jawab umum
• Mengonfigurasi pembaruan otomatis untuk SQL Server yang diaktifkan oleh Azure Arc