Bagikan melalui

Table.TransformColumnTypes

  • Artikel

Sintaksis

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

Tentang

Mengembalikan tabel dengan menerapkan operasi transformasi ke kolom yang ditentukan menggunakan budaya opsional.

  • table: Tabel input yang akan diubah.
  • typeTransformations: Transformasi jenis yang akan diterapkan. Format untuk transformasi tunggal adalah { nama kolom, ketik nilai }. Daftar transformasi dapat digunakan untuk mengubah jenis lebih dari satu kolom pada satu waktu. Jika kolom tidak ada, kesalahan akan muncul.
  • culture: (Opsional) Budaya yang digunakan saat mengubah jenis kolom (misalnya, "en-US").

Nilai jenis dalam parameter typeTransformations dapat any, semua jenis number, text, semua jenis date, time, datetime, datetimezone, dan duration, logical, atau binary. Jenis list, record, table, atau function tidak valid untuk parameter ini.

Contoh 1

Ubah nilai angka di kolom pertama menjadi nilai teks.

Penggunaan

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

Output

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Contoh 2

Ubah tanggal dalam tabel menjadi teks Prancis yang setara.

Penggunaan

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

Output

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

Contoh 3

Ubah tanggal dalam tabel menjadi teks Jerman yang setara, dan nilai dalam tabel menjadi persentase.

Penggunaan

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

Output

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Konten terkait