Table.TransformColumns

Sintaksis

Table.TransformColumns(table as table, transformOperations as list, optional defaultTransformation as nullable function, optional missingField as nullable number) as table

Tentang

Mengubah table dengan menerapkan setiap operasi kolom yang tercantum dalam transformOperations (di mana formatnya adalah { nama kolom, transformasi } atau { nama kolom, transformasi, jenis kolom baru }). Jika defaultTransformation ditentukan, defaultTransformation akan diterapkan ke semua kolom yang tidak tercantum dalam transformOperations. Jika kolom yang tercantum di transformOperations tidak ada, pengecualian akan dilemparkan kecuali parameter opsional missingField menentukan alternatif (misalnya, MissingField.UseNull atau MissingField.Ignore).

Contoh 1

Konversi nilai teks dalam kolom [A] menjadi nilai angka, dan nilai angka dalam kolom [B] menjadi nilai teks.

Penggunaan

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Output

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Contoh 2

Konversikan nilai angka dalam kolom yang hilang [X] menjadi nilai teks, mengabaikan kolom yang tidak ada.

Penggunaan

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Output

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Contoh 3

Konversi nilai angka dalam kolom yang hilang [X] menjadi nilai teks, default ke null pada kolom yang tidak ada.

Penggunaan

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Output

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Contoh 4

Tambahkan nilai angka dalam kolom [B] dan konversikan menjadi nilai teks, dan konversikan semua kolom lainnya menjadi angka.

Penggunaan

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Output

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})