Bagikan melalui

Access Control

  • Artikel

Kontrol akses mengacu pada pendeklarasian klien mana yang dapat menggunakan elemen program tertentu, seperti jenis, metode, dan fungsi.

Dasar-dasar Layanan Kontrol Akses

Di F#, penentu kontrol akses public, internal, dan private dapat diterapkan ke modul, jenis, metode, definisi nilai, fungsi, properti, dan bidang eksplisit.

  • public menunjukkan bahwa entitas dapat diakses oleh semua pemanggil.

  • internalmenunjukkan bahwa entitas hanya dapat diakses dari rakitan yang sama.

  • private menunjukkan bahwa entitas hanya dapat diakses dari jenis atau modul penutupan.

Catatan

Penentu akses protected tidak digunakan dalam F#, meskipun dapat diterima jika Anda menggunakan jenis yang dibuat dalam bahasa yang mendukung akses protected. Oleh karena itu, jika Anda mengambil alih metode yang dilindungi, metode Anda tetap dapat diakses dalam kelas dan turunannya saja.

Penentu akses diletakkan di depan nama entitas.

Jika tidak ada penentu akses yang digunakan, defaultnya adalah public, kecuali untuk pengikatan let dalam jenis, yang selalu private ke jenis.

Tanda tangan dalam F# menyediakan mekanisme lain untuk pengontrolan akses ke elemen program F#. Tanda tangan tidak diperlukan untuk layanan kontrol akses. Untuk informasi selengkapnya, lihat Tanda Tangan.

Aturan untuk Layanan Kontrol Akses

Kontrol akses tunduk pada aturan berikut:

  • Deklarasi pewarisan (yaitu, penggunaan inherit untuk menentukan kelas dasar untuk kelas), deklarasi antarmuka (yaitu, untuk menentukan kalau kelas mengimplementasikan antarmuka), dan anggota abstrak selalu memiliki aksesibilitas yang sama dengan jenis penutupan. Oleh karena itu, penentu kontrol akses tidak dapat digunakan pada konstruksi ini.

  • Aksesibilitas untuk setiap kasus dalam gabungan yang didiskriminasi ditentukan oleh aksesibilitas gabungan yang didiskriminasi itu sendiri. Artinya, kasus gabungan tertentu tidak kurang teraksesnya daripada gabungan itu sendiri.

  • Aksesibilitas untuk bidang individual dari jenis rekaman ditentukan berdasarkan aksesibilitas rekaman itu sendiri. Artinya, label rekaman tertentu tidak kurang teraksesnya daripada rekaman itu sendiri.

Contoh

Kode berikut mengilustrasikan penggunaan penentu kontrol akses. Ada dua file dalam proyek, Module1.fs dan Module2.fs. Setiap file secara implisit merupakan modul. Oleh karena itu, ada dua modul, Module1 dan Module2. Jenis privat dan jenis internal didefinisikan dalam Module1. Jenis privat tidak dapat diakses dari Module2, tetapi jenis internal bisa.

// Module1.fs

module Module1

// This type is not usable outside of this file
type private MyPrivateType() =
   // x is private since this is an internal let binding
   let x = 5
   // X is private and does not appear in the QuickInfo window
   // when viewing this type in the Visual Studio editor
   member private this.X() = 10
   member this.Z() = x * 100

type internal MyInternalType() =
   let x = 5
   member private this.X() = 10
   member this.Z() = x * 100

// Top-level let bindings are public by default,
// so "private" and "internal" are needed here since a
// value cannot be more accessible than its type.
let private myPrivateObj = new MyPrivateType()
let internal myInternalObj = new MyInternalType()

// let bindings at the top level are public by default,
// so result1 and result2 are public.
let result1 = myPrivateObj.Z
let result2 = myInternalObj.Z

Kode berikut menguji aksesibilitas jenis yang dibuat di Module1.fs.

// Module2.fs
module Module2

open Module1

// The following line is an error because private means
// that it cannot be accessed from another file or module
// let private myPrivateObj = new MyPrivateType()
let internal myInternalObj = new MyInternalType()

let result = myInternalObj.Z

Lihat juga