Bagikan melalui

OFFSET

  • Artikel

Berlaku untuk: kolom terhitungTabel terhitungUkurPerhitungan visual

Mengembalikan satu baris yang diposisikan baik sebelum atau sesudah baris saat ini dalam tabel yang sama, dengan offset tertentu. Jika baris saat ini tidak dapat disimpulkan ke satu baris, beberapa baris dapat dikembalikan.

Sintaksis

OFFSET ( <delta>[, <relation> or <axis>][, <orderBy>][, <blanks>][, <partitionBy>][, <matchBy>][, <reset>] )

Parameter

Istilah Definisi
delta Jumlah baris sebelum (nilai negatif) atau setelah (nilai positif) baris saat ini untuk mendapatkan data. Ini bisa berupa ekspresi DAX apa pun yang mengembalikan nilai skalar.
relation (Opsional) Ekspresi tabel tempat baris output dikembalikan.
Jika ditentukan, semua kolom di partitionBy harus berasal dari kolom atau tabel terkait.
Jika dihilangkan:
- orderBy harus ditentukan secara eksplisit.
- Semua ekspresi orderBy dan partitionBy harus merupakan nama kolom yang sepenuhnya memenuhi syarat dan berasal dari satu tabel.
- Default ke ALLSELECTED() dari semua kolom di orderBy dan partitionBy.
axis (Opsional) Sumbu dalam bentuk visual. Hanya tersedia dalam perhitungan visual, dan menggantikan relation.
orderBy (Opsional) Klausa ORDERBY() yang berisi ekspresi yang menentukan bagaimana setiap partisi diurutkan.
Jika dihilangkan:
- relation harus ditentukan secara eksplisit.
- Default untuk mengurutkan menurut setiap kolom di relation yang belum ditentukan dalam partitionBy.
blanks (Opsional) Enumerasi yang menentukan cara menangani nilai kosong saat mengurutkan relation atau axis.
Nilai yang didukung adalah:
  • DEFAULT (nilai default), di mana perilaku untuk nilai numerik adalah nilai kosong diurutkan antara nilai nol dan negatif. Perilaku untuk string adalah nilai kosong diurutkan sebelum semua string, termasuk string kosong.
  • FIRST, kosong selalu diurutkan pada awal, terlepas dari urutan pengurutan naik atau turun.
  • LAST, kosong selalu diurutkan di akhir, terlepas dari urutan pengurutan naik atau turun.
Catatan, ketika parameter dan kosong dalam fungsi () pada ekspresi individual ditentukan, pada ekspresi orderBy individu lebih diprioritaskan untuk ekspresi orderBy yang relevan, dan ekspresi orderBy tanpa ditentukan akan mematuhi parameter pada fungsi induk.
partitionBy (Opsional) Klausa () yang berisi kolom yang menentukan bagaimana dipartisi. Jika dihilangkan, relation diperlakukan sebagai partisi tunggal.
matchBy (Opsional) Klausa () yang berisi kolom yang menentukan cara mencocokkan data dan mengidentifikasi baris saat ini.
reset (Opsional) Hanya tersedia dalam perhitungan visual. Menunjukkan apakah perhitungan diatur ulang, dan pada tingkat hierarki kolom bentuk visual mana. Nilai yang diterima adalah: referensi bidang ke kolom dalam bentuk visual saat ini, NONE (default), LOWESTPARENT, HIGHESTPARENT, atau bilangan bulat. Perilaku tergantung pada tanda bilangan bulat:
- Jika nol atau dihilangkan, perhitungan tidak direset. Setara dengan NONE.
- Jika positif, bilangan bulat mengidentifikasi kolom mulai dari biji-bijian tertinggi dan independen. HIGHESTPARENT setara dengan 1.
- Jika negatif, bilangan bulat mengidentifikasi kolom mulai dari terendah, relatif terhadap butir saat ini. LOWESTPARENT setara dengan -1.

Mengembalikan nilai

Satu atau beberapa baris dari relation.

Komentar

Kecuali untuk kolom yang ditambahkan oleh fungsi tabel DAX, setiap kolom di relation, saat matchBy tidak ada, atau setiap kolom di matchBy dan partitionBy, saat matchBy ada, harus memiliki nilai luar yang sesuai untuk membantu menentukan baris saat ini yang akan dioperasikan, dengan perilaku berikut:

  • Jika ada tepat satu kolom luar yang sesuai, nilainya akan digunakan.
  • Jika tidak ada kolom luar yang sesuai, maka:
    • OFFSET pertama-tama akan menentukan semua kolom yang tidak memiliki kolom luar yang sesuai.
    • Untuk setiap kombinasi nilai yang ada untuk kolom ini dalam konteks induk OFFSET, OFFSET dievaluasi dan baris dikembalikan.
    • OFFSEToutput akhir adalah persatuan baris ini.
  • Jika ada lebih dari satu kolom luar yang sesuai, kesalahan akan ditampilkan.

Jika semua kolom relationditambahkan oleh fungsi tabel DAX, kesalahan akan ditampilkan.

Jika matchBy ada, OFFSET akan mencoba menggunakan kolom matchBy dan partitionBy untuk mengidentifikasi baris. Jika matchBy tidak ada dan kolom yang ditentukan dalam orderBy dan partitionBy tidak dapat mengidentifikasi setiap baris secara unik dalam relation, maka:

  • OFFSET akan mencoba menemukan jumlah kolom tambahan paling sedikit yang diperlukan untuk mengidentifikasi setiap baris secara unik.
  • Jika kolom tersebut dapat ditemukan, OFFSET akan secara otomatis menambahkan kolom baru ini ke orderBy, dan setiap partisi diurutkan menggunakan kumpulan kolom OrderBy baru ini.
  • Jika kolom tersebut tidak dapat ditemukan, kesalahan akan ditampilkan.

Tabel kosong dikembalikan jika:

  • Nilai luar yang sesuai dari kolom OrderBy atau PartitionBy tidak ada dalam relation.
  • Nilai delta menyebabkan pergeseran ke baris yang tidak ada dalam partisi.

Jika OFFSET digunakan dalam kolom terhitung yang ditentukan pada tabel yang sama dengan relation, dan orderBy dihilangkan, kesalahan akan ditampilkan.

reset hanya dapat digunakan dalam perhitungan visual, dan tidak dapat digunakan dalam kombinasi dengan orderBy atau partitionBy. Jika reset ada, axis dapat ditentukan tetapi relation tidak dapat.

Contoh 1 - kolom terhitung

Kueri DAX berikut ini:

DEFINE
VAR vRelation = SUMMARIZECOLUMNS ( 
                    DimProductCategory[EnglishProductCategoryName], 
                    DimDate[CalendarYear], 
                    "CurrentYearSales", SUM(FactInternetSales[SalesAmount]) 
                  )
EVALUATE
ADDCOLUMNS (
    vRelation, 
    "PreviousYearSales", 
    SELECTCOLUMNS(
        OFFSET ( 
                -1, 
                vRelation, 
                ORDERBY([CalendarYear]), 
                PARTITIONBY([EnglishProductCategoryName])
        ),
        [CurrentYearSales]
    )
)

Mengembalikan tabel yang meringkas total penjualan untuk setiap kategori produk dan tahun kalender, serta total penjualan untuk kategori tersebut pada tahun sebelumnya.

Contoh 2 - pengukuran

Kueri DAX berikut ini:

DEFINE
MEASURE DimProduct[CurrentYearSales] = SUM(FactInternetSales[SalesAmount])
MEASURE DimProduct[PreviousYearSales] = CALCULATE(SUM(FactInternetSales[SalesAmount]), OFFSET(-1, , ORDERBY(DimDate[CalendarYear])))
EVALUATE
SUMMARIZECOLUMNS (
    DimDate[CalendarYear],
    "CurrentYearSales", DimProduct[CurrentYearSales],
    "PreviousYearSales", DimProduct[PreviousYearSales]
)

Menggunakan OFFSET() dalam ukuran untuk mengembalikan tabel yang meringkas total penjualan untuk setiap tahun kalender dan total penjualan untuk tahun sebelumnya.

Contoh 3 - kolom terhitung

Kueri DAX berikut ini:

EVALUATE
ADDCOLUMNS (
    FactInternetSales,
    "Previous Sales Amount",
        SELECTCOLUMNS (
            OFFSET (
                -1,
                FactInternetSales,
                ORDERBY ( FactInternetSales[SalesAmount], DESC ),
                PARTITIONBY ( FactInternetSales[ProductKey] ),
                MATCHBY( FactInternetSales[SalesOrderNumber], FactInternetSales[SalesOrderLineNumber] )
            ),
            FactInternetSales[SalesAmount]
        )
)

Mengembalikan tabel FactInternetSales dengan menambahkan kolom, yang menunjukkan, untuk setiap penjualan, jumlah penjualan sebelumnya, dari produk yang sama, dalam urutan menurun dari jumlah penjualan, dengan penjualan saat ini diidentifikasi oleh SalesOrderNumber dan SalesOrderLineNumber. Tanpa MATCHBY, kueri akan mengembalikan kesalahan karena tidak ada kolom kunci dalam tabel FactInternetSales.

Contoh 4 - perhitungan visual

Kueri DAX penghitungan visual berikut:

SalesRelativeToPreviousMonth = [SalesAmount] - CALCULATE(SUM([SalesAmount]), OFFSET(-1, ROWS, HIGHESTPARENT))

Mengembalikan selisih total penjualan antara setiap bulan dan yang sebelumnya dalam tahun yang sama.

Cuplikan layar di bawah ini memperlihatkan matriks visual dan ekspresi perhitungan visual:

DAX perhitungan visual

Konten terkait

INDEX ORDERBY PARTITIONBY MATCHBY WINDOW RANK ROWNUMBER