Bagikan melalui

ISINSCOPE

  • Artikel

Berlaku untuk: kolom terhitungTabel terhitungUkurPerhitungan visual

Mengembalikan true ketika kolom yang ditentukan adalah tingkat dalam hierarki tingkat.

Sintaksis

ISINSCOPE(<columnName>)

Parameter

Istilah Definisi
columnName Nama kolom yang ada, menggunakan sintaks DAX standar. Ini tidak bisa menjadi ekspresi.

Mengembalikan nilai

TRUE ketika kolom yang ditentukan adalah tingkat dalam hierarki tingkat.

Komentar

Fungsi ini tidak didukung untuk digunakan dalam mode DirectQuery saat digunakan dalam kolom terhitung atau aturan keamanan tingkat baris (RLS).

Contoh

DEFINE
MEASURE FactInternetSales[% of Parent] =
  SWITCH (TRUE(),
    ISINSCOPE(DimProduct[Subcategory]),
      DIVIDE(
        SUM(FactInternetSales[Sales Amount]),
        CALCULATE(
          SUM(FactInternetSales[Sales Amount]),
          ALLSELECTED(DimProduct[Subcategory]))
      ),
    ISINSCOPE(DimProduct[Category]),
      DIVIDE(
        SUM(FactInternetSales[Sales Amount]), 
        CALCULATE(
          SUM(FactInternetSales[Sales Amount]),
          ALLSELECTED(DimProduct[Category]))
      ),
    1
  ) * 100
EVALUATE
  SUMMARIZECOLUMNS
  (
    ROLLUPADDISSUBTOTAL
    (
      DimProduct[Category], "Category Subtotal",
      DimProduct[Subcategory], "Subcategory Subtotal"
    ),
    TREATAS(
      {"Bike Racks", "Bike Stands", "Mountain Bikes", "Road Bikes", "Touring Bikes"},
      DimProduct[Subcategory]),
    "Sales", SUM(FactInternetSales[Sales Amount]),
    "% of Parent", [% of Parent]
  )
  ORDER BY
    [Category Subtotal] DESC, [Category],
    [Subcategory Subtotal] DESC, [Subcategory]

Kembali

DimProduct[Category] DimProduct[SubCategory] [Subtotal Kategori] [Subtotal Subkataan] [Penjualan] [% Induk]
TRUE TRUE 28,397,095.65 100.00
Aksesoris FALSE TRUE 78,951.00 0.28
Aksesoris Rak Sepeda FALSE FALSE 39,360.00 49.85
Aksesoris Stan Sepeda FALSE FALSE 39,591.00 50.15
Sepeda FALSE TRUE 28,318,144.65 99.72
Sepeda Sepeda Gunung FALSE FALSE 9,952,759.56 35.15
Sepeda Sepeda Jalanan FALSE FALSE 14,520,584.04 51.28
Sepeda Sepeda Touring FALSE FALSE 3,844,801.05 13.58

Konten terkait

fungsi fungsi