Bagikan melalui

CONCATENATE

  • Artikel

Berlaku untuk: kolom terhitungTabel terhitungUkurPerhitungan visual

Menggabungkan dua string teks ke dalam satu string teks.

Sintaksis

CONCATENATE(<text1>, <text2>)

Parameter

Istilah Definisi
text1 String teks pertama yang akan digabungkan ke dalam string teks tunggal. String dapat menyertakan teks atau angka. Anda juga dapat menggunakan referensi kolom.
text2 String teks kedua yang akan digabungkan ke dalam string teks tunggal. String dapat menyertakan teks atau angka. Anda juga dapat menggunakan referensi kolom.

Mengembalikan nilai

String yang digabungkan.

Komentar

  • Fungsi CONCATENATE menggabungkan dua string teks ke dalam satu string teks. Item yang digabungkan dapat berupa teks, angka, nilai Boolean yang dinyatakan sebagai teks, atau kombinasi item tersebut. Anda juga bisa menggunakan referensi kolom jika kolom berisi nilai yang sesuai.

  • Fungsi CONCATENATE di DAX hanya menerima dua argumen, sedangkan fungsi Excel CONCATENATE menerima hingga 255 argumen. Jika Anda perlu menggabungkan beberapa kolom, Anda dapat membuat serangkaian perhitungan atau menggunakan operator perangkaian (&) untuk menggabungkan semuanya dalam ekspresi yang lebih sederhana.

  • Jika Anda ingin menggunakan string teks secara langsung, daripada menggunakan referensi kolom, Anda harus mengapit setiap string dalam tanda kutip ganda.

  • Fungsi ini tidak didukung untuk digunakan dalam mode DirectQuery saat digunakan dalam kolom terhitung atau aturan keamanan tingkat baris (RLS).

Contoh: Penggalian Literal

Contoh rumus membuat nilai string baru dengan menggabungkan dua nilai string yang Anda sediakan sebagai argumen.

= CONCATENATE("Hello ", "World")

Contoh: Penggalian string dalam kolom

Contoh rumus mengembalikan nama lengkap pelanggan seperti yang tercantum dalam buku telepon. Perhatikan bagaimana fungsi berlapis digunakan sebagai argumen kedua. Ini adalah salah satu cara untuk menggabungkan beberapa string ketika Anda memiliki lebih dari dua nilai yang ingin Anda gunakan sebagai argumen.

= CONCATENATE(Customer[LastName], CONCATENATE(", ", Customer[FirstName]))

Contoh: Perangkaian string bersyariah dalam kolom

Contoh rumus membuat kolom terhitung baru dalam tabel Pelanggan dengan nama pelanggan lengkap sebagai kombinasi nama depan, awal pertengahan, dan nama belakang. Jika tidak ada nama tengah, nama belakang datang langsung setelah nama depan. Jika ada nama tengah, hanya huruf pertama nama tengah yang digunakan dan huruf awal diikuti dengan titik.

= CONCATENATE( [FirstName]&" ", CONCATENATE( IF( LEN([MiddleName])>1, LEFT([MiddleName],1)&". ", ""), [LastName]))

Rumus ini menggunakan fungsi CONCATENATE dan IF berlapis, bersama dengan operator ampersand (&), untuk menggabungkan tiga nilai string secara kondisional dan menambahkan spasi sebagai pemisah.

Contoh: Penggalian kolom dengan jenis data yang berbeda

Contoh berikut menunjukkan cara menggabungkan nilai dalam kolom yang memiliki jenis data yang berbeda. Jika nilai yang Anda gabungkan adalah numerik, nilai akan dikonversi secara implisit ke teks. Jika kedua nilai numerik, kedua nilai akan ditransmisikan ke teks dan digabungkan seolah-olah keduanya adalah string.

Deskripsi produk Singkatan produk (kolom 1 kunci komposit) Nomor produk (kolom 2 kunci komposit) Kolom kunci baru yang dihasilkan
Sepeda gunung MTN 40 MTN40
Sepeda gunung MTN 42 MTN42 
= CONCATENATE('Products'[Product abbreviation],'Products'[Product number])

Fungsi CONCATENATE di DAX hanya menerima dua argumen, sedangkan fungsi Excel CONCATENATE menerima hingga 255 argumen. Jika Anda perlu menambahkan lebih banyak argumen, Anda dapat menggunakan operator ampersand (&). Misalnya, rumus berikut menghasilkan hasilnya, MTN-40 dan MTN-42.

= [Product abbreviation] & "-" & [Product number]

Konten terkait

CONCATENATEX