Mengumpulkan dan mengkueri data kualitas koneksi

Artikel
10/18/2023

Penting

Log Data Grafik Koneksi saat ini dalam pratinjau. Lihat Ketentuan Penggunaan Tambahan untuk Pratinjau Microsoft Azure untuk persyaratan hukum yang berlaku pada fitur Azure dalam versi beta, pratinjau, atau belum dirilis secara umum.

Kualitas koneksi sangat penting untuk pengalaman pengguna yang baik, jadi penting untuk dapat memantau koneksi untuk potensi masalah dan memecahkan masalah saat muncul. Azure Virtual Desktop terintegrasi dengan alat seperti Log Analytics yang dapat membantu Anda memantau kesehatan koneksi penyebaran Anda. Artikel ini akan menunjukkan kepada Anda cara mengonfigurasi pengaturan diagnostik untuk memungkinkan Anda mengumpulkan data kualitas koneksi dan data kueri untuk parameter tertentu.

Prasyarat

Untuk mulai mengumpulkan data kualitas koneksi, Anda perlu menyiapkan ruang kerja Analitik Log untuk digunakan dengan Azure Virtual Desktop.

Catatan

Biaya penyimpanan normal untuk Analitik Log akan berlaku. Pelajari selengkapnya di detail harga Log Azure Monitor.

Mengonfigurasi pengaturan diagnostik

Untuk memeriksa dan memodifikasi pengaturan diagnostik Anda di portal Azure:

Masuk ke portal Azure, lalu buka Azure Virtual Desktop dan pilih Kumpulan host.
Pilih kumpulan host tempat Anda ingin mengumpulkan data jaringan.
Pilih Pengaturan diagnostik, lalu buat pengaturan baru jika Anda belum mengonfigurasi pengaturan diagnostik Anda. Jika Anda sudah mengonfigurasi pengaturan diagnostik, pilih Edit pengaturan.
Pilih semuaLog jika Anda ingin mengumpulkan data untuk semua tabel. Parameter allLogs akan secara otomatis menambahkan tabel baru ke tabel data Anda di masa mendatang.

Jika Anda lebih suka menampilkan tabel yang lebih spesifik, pertama-tama pilih Log Data Jaringan dan Pratinjau Log Data Grafik Koneksi, lalu pilih nama tabel lain yang ingin Anda lihat.
Pilih tempat Anda ingin mengirim data yang dikumpulkan. Pengguna Azure Virtual Desktop Insights harus memilih ruang kerja Log Analytics.
Pilih Simpan untuk menerapkan perubahan Anda.
Ulangi proses ini untuk semua kumpulan host lain yang ingin Anda ukur.
Untuk memeriksa data jaringan, kembali ke halaman sumber daya kumpulan host, pilih Log, lalu jalankan salah satu kueri dalam Kueri sampel untuk Azure Log Analytics. Agar kueri Anda mendapatkan hasil, kumpulan host Anda harus memiliki pengguna aktif yang telah terhubung ke sesi sebelumnya. Perlu diingat bahwa perlu waktu hingga 15 menit agar data jaringan muncul di portal Azure.

Kueri sampel untuk Azure Log Analytics: data jaringan

Pada bagian ini, kami memiliki daftar kueri yang akan membantu Anda meninjau informasi kualitas koneksi. Anda dapat menjalankan kueri ini pada editor kueri Log Analytics.

Catatan

Untuk setiap contoh, ganti variabel userupn dengan UPN pengguna yang ingin Anda cari.

Rata-rata kueri RTT dan bandwidth

Untuk mencari rata-rata waktu bolak balik dan bandwidth:

// 90th, 50th, 10th Percentile for RTT in 10 min increments
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),RTTP50=percentile(EstRoundTripTimeInMs,50),RTTP10=percentile(EstRoundTripTimeInMs,10) by bin(TimeGenerated,10m)
| render timechart
// 90th, 50th, 10th Percentile for BW in 10 min increments
WVDConnectionNetworkData
| summarize BWP90=percentile(EstAvailableBandwidthKBps,90),BWP50=percentile(EstAvailableBandwidthKBps,50),BWP10=percentile(EstAvailableBandwidthKBps,10) by bin(TimeGenerated,10m)
| render timechart

Untuk mencari waktu bolak balik dan bandwidth per koneksi:

// RTT and BW Per Connection Summary
// Returns P90 Round Trip Time (ms) and Bandwidth (KBps) per connection with connection details.
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),BWP90=percentile(EstAvailableBandwidthKBps,90),StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=leftouter (
WVDConnections
| extend Protocol = iff(UdpUse in ("0","<>"),"TCP","UDP")
| distinct CorrelationId, SessionHostName, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion, UserName
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Data kueri untuk pengguna tertentu

Untuk mencari bandwidth untuk pengguna tertentu:

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstAvailableBandwidthKBps, TimeGenerated
| render columnchart

Untuk mencari waktu bolak balik untuk pengguna tertentu:

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
WVDConnections
| distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstRoundTripTimeInMs, TimeGenerated
| render columnchart

Untuk mencari 10 pengguna teratas dengan waktu bolak balik tertinggi:

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=avg(EstRoundTripTimeInMs),RTT_P95=percentile(EstRoundTripTimeInMs,95) by UserName
| top 10 by AvgRTT desc

Untuk mencari 10 pengguna dengan bandwidth terendah:

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps),BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Langkah berikutnya

Pelajari selengkapnya tentang kualitas koneksi di Kualitas koneksi di Azure Virtual Desktop.

Bagikan melalui