Sampel kueri Azure Resource Graph untuk mengakses data operasi Manajer Pembaruan Azure

Artikel
12/04/2024

Berikut ini adalah beberapa contoh kueri untuk membantu Anda mulai mengkueri penilaian pembaruan dan informasi penyebaran yang dikumpulkan dari komputer terkelola Anda. Untuk informasi selengkapnya tentang log yang dibuat dari operasi seperti penilaian pembaruan dan penginstalan, lihat gambaran umum log kueri.

Daftar pembaruan yang tersedia untuk semua komputer Anda yang dikelompokkan berdasarkan kategori pembaruan

Kueri berikut mengembalikan daftar pembaruan yang tertunda untuk komputer Anda dengan waktu ketika penilaian dilakukan, ID sumber daya untuk penilaian, jenis OS pada komputer, dan pembaruan OS yang tersedia berdasarkan klasifikasi pembaruan.

patchassessmentresources
| where type !has "softwarepatches"
| extend prop = parse_json(properties)
| extend lastTime = properties.lastModifiedDateTime
| extend updateRollupCount = prop.availablePatchCountByClassification.updateRollup, featurePackCount = prop.availablePatchCountByClassification.featurePack, servicePackCount = prop.availablePatchCountByClassification.servicePack, definitionCount = prop.availablePatchCountByClassification.definition, securityCount = prop.availablePatchCountByClassification.security, criticalCount = prop.availablePatchCountByClassification.critical, updatesCount = prop.availablePatchCountByClassification.updates, toolsCount = prop.availablePatchCountByClassification.tools, otherCount = prop.availablePatchCountByClassification.other, OS = prop.osType
| project lastTime, id, OS, updateRollupCount, featurePackCount, servicePackCount, definitionCount, securityCount, criticalCount, updatesCount, toolsCount, otherCount

Jumlah penginstalan pembaruan

Kueri berikut mengembalikan daftar penginstalan pembaruan dengan statusnya untuk komputer Anda dari tujuh hari terakhir. Hasilnya termasuk waktu ketika penyebaran pembaruan dijalankan, ID sumber daya penginstalan, detail komputer, dan jumlah pembaruan OS yang diinstal berdasarkan statusnya dan pilihan Anda.

patchinstallationresources
| where type !has "softwarepatches"
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), OS = tostring(prop.osType), installedPatchCount = tostring(prop.installedPatchCount), failedPatchCount = tostring(prop.failedPatchCount), pendingPatchCount = tostring(prop.pendingPatchCount), excludedPatchCount = tostring(prop.excludedPatchCount), notSelectedPatchCount = tostring(prop.notSelectedPatchCount)
| where lTime > ago(7d)
| project lTime, RunID=name,machineName, rgName, resourceType, OS, installedPatchCount, failedPatchCount, pendingPatchCount, excludedPatchCount, notSelectedPatchCount

Daftar penginstalan pembaruan Windows Server OS

Kueri berikut mengembalikan daftar penginstalan pembaruan untuk Windows Server dengan statusnya untuk komputer Anda dari tujuh hari terakhir. Hasilnya termasuk waktu ketika penyebaran pembaruan dijalankan, ID sumber daya penginstalan, detail komputer, dan detail penyebaran lainnya yang terkait.

patchinstallationresources
| where type has "softwarepatches" and isnull(properties.version)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), kbId = tostring(prop.kbId), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, kbId, classifications, installationState
| sort by RunID

Daftar penginstalan pembaruan Linux OS

Kueri berikut mengembalikan daftar penginstalan pembaruan untuk Linux dengan statusnya untuk komputer Anda dari tujuh hari terakhir. Hasilnya termasuk waktu ketika penyebaran pembaruan dijalankan, ID sumber daya penginstalan, detail komputer, dan detail penyebaran lainnya yang terkait.

patchinstallationresources
| where type has "softwarepatches" and isnotnull(properties.version) and isnull(properties.kbId)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), version = tostring(prop.version), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, version, classifications, installationState
| sort by RunID

Daftar catatan eksekusi pemeliharaan di tingkat VM

Kueri berikut mengembalikan daftar semua rekaman pemeliharaan yang dijalankan untuk VM

maintenanceresources 
| where ['id'] contains "/subscriptions/<subscription-id>/resourcegroups/<resource-group>/providers/microsoft.compute/virtualmachines/<vm-name>" //VM Id here
| where ['type'] == "microsoft.maintenance/applyupdates" 
| where properties.maintenanceScope == "InGuestPatch"

Langkah berikutnya

Tinjau log dan hasil pencarian dari Update Manager di Azure menggunakan Azure Resource Graph.
Memecahkan masalah di Manajer Pembaruan, lihat Pemecahan Masalah.

Bagikan melalui