Menyambungkan database Azure Cosmos DB ke aplikasi Anda di Azure Spring Apps

1. Tambahkan salah satu dependensi berikut ke file pom.xml aplikasi Anda. Pilih dependensi yang sesuai untuk jenis API Anda.

   • Jenis API: NoSQL

     <dependency>
         <groupId>com.azure.spring</groupId>
         <artifactId>spring-cloud-azure-starter-data-cosmos</artifactId>
     </dependency>
     

   • Jenis API: MongoDB

     <dependency>
         <groupId>org.springframework.boot</groupId>
         <artifactId>spring-boot-starter-data-mongodb</artifactId>
     </dependency>
     

   • Jenis API: Cassandra

     <dependency>
         <groupId>org.springframework.boot</groupId>
         <artifactId>spring-boot-starter-data-cassandra</artifactId>
     </dependency>
     

2. Perbarui aplikasi saat ini dengan menjalankan az spring app deploy, atau buat penyebaran baru untuk perubahan ini dengan menjalankan az spring app deployment create.

Semua string koneksi dan kredensial disuntikkan sebagai variabel lingkungan, yang dapat Anda referensikan dalam kode aplikasi Anda.

Untuk nama variabel lingkungan default, lihat artikel berikut ini:

• Azure Cosmos DB for Table
• Azure Cosmos DB for NoSQL
• Azure Cosmos DB untuk MongoDB
• Azure Cosmos DB untuk Gremlin
• Azure Cosmos DB untuk Cassandra

Menggunakan Azure CLI

Gunakan Azure CLI untuk mengonfigurasi aplikasi Spring Anda untuk menyambungkan ke Database Cosmos NoSQL dengan menggunakan az spring connection create perintah , seperti yang ditunjukkan dalam contoh berikut. Pastikan untuk mengganti variabel dalam contoh dengan nilai aktual.

az spring connection create cosmos-sql \
    --resource-group $AZURE_SPRING_APPS_RESOURCE_GROUP \
    --service $AZURE_SPRING_APPS_SERVICE_INSTANCE_NAME \
    --app $APP_NAME \
    --target-resource-group $COSMOSDB_RESOURCE_GROUP \
    --account $COSMOSDB_ACCOUNT_NAME \
    --database $DATABASE_NAME \
    --secret

Menggunakan portal Azure

Atau, Anda dapat menggunakan portal Azure untuk mengonfigurasi koneksi ini dengan menyelesaikan langkah-langkah berikut. portal Azure menyediakan kemampuan yang sama dengan Azure CLI dan memberikan pengalaman interaktif.

1. Pilih instans Azure Spring Apps Anda di portal Azure dan pilih Aplikasi dari menu navigasi. Pilih aplikasi yang ingin Anda sambungkan dan pilih Konektor Layanan pada menu navigasi.

2. Pilih Buat.

3. Pada tab Dasar , untuk jenis layanan, pilih Cosmos DB, lalu pilih langganan. Untuk jenis API, pilih Core (SQL), pilih akun Cosmos DB, dan database. Untuk jenis klien, pilih Java, lalu pilih Berikutnya: Autentikasi. Jika Anda belum membuat database, lihat Mulai Cepat: Membuat akun, database, kontainer, dan item Azure Cosmos DB dari portal Azure.

4. Pada tab Autentikasi , pilih String koneksi. Konektor Layanan secara otomatis mengambil kunci akses dari akun Cosmos DB Anda. Pilih Next: Networking.

5. Pada tab Jaringan, pilih Konfigurasikan aturan firewall untuk mengaktifkan akses ke layanan target, lalu pilih Berikutnya: Tinjau + Buat.

6. Pada tab Tinjau + Buat , tunggu hingga validasi lulus lalu pilih Buat. Pembuatan dapat memakan waktu beberapa menit untuk diselesaikan.

7. Setelah koneksi antara aplikasi Spring dan database Cosmos DB Anda dibuat, Anda dapat melihatnya di halaman Konektor Layanan dan memilih tombol buka untuk melihat variabel koneksi yang dikonfigurasi.

Skrip Terraform berikut menunjukkan cara menyiapkan aplikasi yang disebarkan ke Azure Spring Apps dengan akun Azure Cosmos DB.

provider "azurerm" {
  features {}
}

variable "application_name" {
  type        = string
  description = "The name of your application"
  default     = "demo-cosmosdb"
}

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "West Europe"
}

resource "azurerm_cosmosdb_account" "cosmosdb" {
  name                = "cosmosacct-${var.application_name}-001"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  offer_type          = "Standard"
  kind                = "GlobalDocumentDB"

  consistency_policy {
    consistency_level = "Session"
  }

  geo_location {
    failover_priority = 0
    location          = azurerm_resource_group.example.location
  }
}

resource "azurerm_cosmosdb_sql_database" "cosmosdb" {
  name                = "cosmos-${var.application_name}-001"
  resource_group_name = azurerm_cosmosdb_account.cosmosdb.resource_group_name
  account_name        = azurerm_cosmosdb_account.cosmosdb.name
}

resource "azurerm_spring_cloud_service" "example" {
  name                = "${var.application_name}"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
}

resource "azurerm_spring_cloud_app" "example" {
  name                = "${var.application_name}-app"
  resource_group_name = azurerm_resource_group.example.name
  service_name        = azurerm_spring_cloud_service.example.name
  is_public           = true
  https_only          = true
}

resource "azurerm_spring_cloud_java_deployment" "example" {
  name                = "default"
  spring_cloud_app_id = azurerm_spring_cloud_app.example.id
  quota {
    cpu    = "2"
    memory = "4Gi"
  }
  instance_count      = 1
  jvm_options         = "-XX:+PrintGC"
  runtime_version     = "Java_11"

  environment_variables = {
    "spring.cloud.azure.cosmos.endpoint" : azurerm_cosmosdb_account.cosmosdb.endpoint
    "spring.cloud.azure.cosmos.key" : azurerm_cosmosdb_account.cosmosdb.primary_key
    "spring.cloud.azure.cosmos.database" : azurerm_cosmosdb_sql_database.cosmosdb.name
  }
}

resource "azurerm_spring_cloud_active_deployment" "example" {
  spring_cloud_app_id = azurerm_spring_cloud_app.example.id
  deployment_name     = azurerm_spring_cloud_java_deployment.example.name
}