Operator in~
Berlaku untuk: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel
Memfilter kumpulan catatan untuk data dengan string yang tidak peka huruf besar/kecil.
Tabel berikut memberikan perbandingan dari operator in:
| Operator | Deskripsi | Peka Huruf Besar/Kecil | Contoh (menangguhkan true) |
|---|---|---|---|
in |
Sama dengan salah satu elemen | Ya | "abc" in ("123", "345", "abc") |
!in |
Tidak sama dengan satu pun elemen | Ya | "bca" !in ("123", "345", "abc") |
in~ |
Sama dengan salah satu elemen | No | "Abc" in~ ("123", "345", "abc") |
!in~ |
Tidak sama dengan satu pun elemen | No | "bCa" !in~ ("123", "345", "ABC") |
Catatan
Larik bersarang diratakan menjadi satu daftar nilai. Misalnya, x in (dynamic([1,[2,3]])) menjadi x in (1,2,3).
Untuk informasi lebih lanjut tentang operator lain dan untuk menentukan operator mana yang paling sesuai untuk kueri Anda, lihat operator string datatype.
Operator yang tidak peka huruf besar/kecil saat ini hanya didukung untuk teks ASCII. Untuk perbandingan non-ASCII, gunakan fungsi tolower().
Tips performa
Catatan
Ketika lebih dari 128 istilah pencarian digunakan, pengoptimalan pencarian indeks teks dinonaktifkan, yang mungkin menyebabkan penurunan performa kueri.
Catatan
Performa tergantung pada jenis pencarian dan struktur data. Untuk praktik terbaik, lihat Praktik terbaik kueri.
Jika memungkinkan, gunakan peka huruf besar/kecil.
Sintaks
Ekspresi kol in~ (T | where ...,)
Pelajari selengkapnya tentang konvensi sintaksis.
Parameter
| Nama | Tipe | Wajib | Deskripsi |
|---|---|---|---|
| T | string |
✔️ | Input tabular untuk difilter. |
| Col | string |
✔️ | Kolom yang akan difilter. |
| expression | skalar atau tabular | ✔️ | Ekspresi yang menentukan nilai yang akan dicari. Setiap ekspresi dapat berupa nilai skalar atau ekspresi tabular yang menghasilkan sekumpulan nilai. Jika ekspresi tabular memiliki beberapa kolom, kolom pertama digunakan. Pencarian akan mempertimbangkan hingga 1.000.000 nilai yang berbeda. |
Mengembalikan
Baris di T yang predikatnya adalah true.
Contoh
Daftar skalar
Kueri berikut ini memperlihatkan cara menggunakan in~ dengan daftar nilai skalar yang dipisahkan koma.
StormEvents
| where State in~ ("FLORIDA", "georgia", "NEW YORK")
| count
Hasil
| Hitung |
|---|
| 4775 |
Dynamic array
Kueri berikut ini memperlihatkan cara menggunakan in~ dengan array dinamis.
StormEvents
| where State in~ (dynamic(["FLORIDA", "georgia", "NEW YORK"]))
| count
Hasil
| Hitung |
|---|
| 4775 |
Kueri yang sama juga dapat ditulis dengan pernyataan let.
let states = dynamic(["FLORIDA", "georgia", "NEW YORK"]);
StormEvents
| where State has_any (states)
| summarize count() by State
Hasil
| Hitung |
|---|
| 4775 |
Ekspresi tabular
Kueri berikut ini memperlihatkan cara menggunakan in~ dengan ekspresi tabular sebaris. Perhatikan bahwa ekspresi tabular sebaris harus diapit dengan tanda kurung ganda.
StormEvents
| where State in~ (PopulationData | where Population > 5000000 | project State)
| summarize count() by State
Hasil
| Status | count_ |
|---|---|
| TEXAS | 4701 |
| ILLINOIS | 2022 |
| MISSOURI | 2016 |
| GEORGIA | 1983 |
| MINNESOTA | 1881 |
| ... | ... |
Kueri yang sama juga dapat ditulis dengan pernyataan let. Perhatikan bahwa tanda kurung ganda seperti yang disediakan dalam contoh terakhir tidak diperlukan dalam kasus ini.
let large_states = PopulationData | where Population > 5000000 | project State;
StormEvents
| where State in~ (large_states)
| summarize count() by State
Hasil
| Status | count_ |
|---|---|
| TEXAS | 4701 |
| ILLINOIS | 2022 |
| MISSOURI | 2016 |
| GEORGIA | 1983 |
| MINNESOTA | 1881 |
| ... | ... |