Bagikan melalui

Mulai Cepat: Membuat akun Batch menggunakan file Bicep

  • Artikel

Memulai dengan Azure Batch menggunakan file Bicep untuk membuat akun Batch, termasuk penyimpanan. Anda memerlukan akun Microsoft Azure Batch untuk membuat sumber daya komputasi (kumpulan node komputasi) dan tugas Batch. Anda dapat menautkan akun Azure Storage dengan akun Batch Anda, yang berguna untuk menyebarkan aplikasi serta menyimpan data input dan output untuk sebagian besar beban kerja dunia nyata.

Setelah menyelesaikan mulai cepat ini, Anda akan memahami konsep kunci layanan Batch dan siap untuk mencoba Microsoft Azure Batch dengan beban kerja yang lebih realistis pada skala yang lebih besar.

Bicep adalah bahasa pemrogram khusus domain (DSL) yang menggunakan sintaks deklaratif untuk menyebarkan sumber daya Azure. Bicep menyediakan sintaks ringkas, keamanan jenis yang andal, dan dukungan untuk penggunaan kembali kode. Bicep menawarkan pengalaman penulisan terbaik untuk solusi infrastructure-as-code di Azure.

Prasyarat

Anda harus memiliki langganan Azure yang aktif.

Tinjau file Bicep

File Bicep yang digunakan dalam mulai cepat berasal dari Templat Mulai Cepat Azure.

@description('Batch Account Name')
param batchAccountName string = '${toLower(uniqueString(resourceGroup().id))}batch'

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
param storageAccountsku string = 'Standard_LRS'

@description('Location for all resources.')
param location string = resourceGroup().location

var storageAccountName = '${uniqueString(resourceGroup().id)}storage'

resource storageAccount 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountsku
  }
  kind: 'StorageV2'
  tags: {
    ObjectName: storageAccountName
  }
  properties: {
    minimumTlsVersion: 'TLS1_2'
    allowBlobPublicAccess: false
    networkAcls: {
      defaultAction: 'Deny'
    }
    supportsHttpsTrafficOnly: true
  }
}

resource batchAccount 'Microsoft.Batch/batchAccounts@2024-02-01' = {
  name: batchAccountName
  location: location
  tags: {
    ObjectName: batchAccountName
  }
  properties: {
    autoStorage: {
      storageAccountId: storageAccount.id
    }
  }
}

output storageAccountName string = storageAccount.name
output batchAccountName string = batchAccount.name
output location string = location
output resourceGroupName string = resourceGroup().name
output resourceId string = batchAccount.id

Dua sumber daya Azure ditentukan dalam file Bicep:

Menerapkan file Bicep

  1. Simpan file Bicep sebagai main.bicep ke penyimpanan lokal komputer Anda.

  2. Sebarkan file Bicep menggunakan Azure CLI atau Azure PowerShell.

    az group create --name exampleRG --location eastus
az deployment group create --resource-group exampleRG --template-file main.bicep

    Setelah penyebaran selesai, Anda akan melihat pesan yang menunjukkan penyebaran berhasil.

Memvalidasi penyebaran

Gunakan portal Microsoft Azure, Azure CLI, atau Azure PowerShell untuk mencantumkan sumber daya yang disebarkan di grup sumber daya.

az resource list --resource-group exampleRG

Membersihkan sumber daya

Jika Anda berencana melanjutkan dengan tutorial lainnya dari kami, Anda mungkin ingin membiarkan sumber daya ini tetap di tempatnya. Saat tidak lagi diperlukan, gunakan portal Azure, Azure CLI, atau Azure PowerShell untuk menghapus grup sumber daya dan semua sumber dayanya.

az group delete --name exampleRG

Langkah berikutnya

Dalam mulai cepat ini, Anda membuat akun Batch dan akun penyimpanan menggunakan Bicep. Untuk mempelajari selengkapnya tentang Azure Batch, lanjutkan ke tutorial Azure Batch.

Tutorial Azure Batch