Kueri untuk tabel VIAudit

Untuk informasi tentang menggunakan kueri ini di portal Azure, lihat tutorial Analitik Log. Untuk REST API, lihat Kueri.

Audit Video Indexer menurut id akun

Tampilkan peristiwa audit untuk akun (AccountId = <GUID ID>), dengan filter opsional menurut UPN pengguna.

VIAudit
| where AccountId == "<AccountId>"  // please fill in the accountId <Guid>
// | where Upn == "<Upn>" // to to filter on a specific user upn, uncomment this line
| limit 100

Audit Video Indexer 10 pengguna teratas berdasarkan operasi

Merender bagan waktu 10 pengguna teratas berdasarkan operasi, dengan id akun opsional untuk pemfilteran.

// Trend of top 10 active Upn's
VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where TimeGenerated > ago(30d)
| summarize count() by Upn
| top 10 by count_ desc
| project Upn
| join (VIAudit
| where TimeGenerated > ago(30d)
| summarize count() by Upn, bin(TimeGenerated,1d)) on Upn
| project TimeGenerated, Upn, count_
| render timechart

Pesan kesalahan penguraian Audit Video Indexer

Tampilkan peristiwa yang gagal audit dengan id akun opsional untuk pemfilteran.

// Project failures with detailed error message.
VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where  Status == "Failure"
| parse Description with "ErrorType: " ErrorType ". Message: " ErrorMessage ". Trace" *
| project TimeGenerated, OperationName, ErrorMessage, ErrorType, CorrelationId, _ResourceId

Operasi Audit Video Indexer gagal

Tampilkan log audit dari semua upaya operasi yang gagal, dengan filter opsional menurut id akun dan UPN pengguna.

VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
// | where Upn == "<Upn>" // to to filter on a specific user upn, uncomment this line
| where Status == "Failure"
| limit 100