Kueri untuk tabel StorageBlobLogs

Artikel
02/18/2025

Untuk informasi tentang menggunakan kueri ini di portal Azure, lihat tutorial Analitik Log. Untuk REST API, lihat Kueri.

Kesalahan paling umum

Daftar 10 kesalahan paling umum selama 3 hari terakhir.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

Operasi penyebab sebagian besar kesalahan

Daftar 10 operasi teratas yang menyebabkan kesalahan terbanyak selama 3 hari terakhir.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

Operasi dengan latensi tertinggi

Cantumkan 10 operasi teratas dengan latensi ujung ke ujung terpanjang selama 3 hari terakhir.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

Operasi penyebab pembatasan sisi server

Buat daftar semua operasi yang menyebabkan kesalahan pembatasan sisi server selama 3 hari terakhir.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

Tampilkan permintaan anonim

Cantumkan semua permintaan dengan akses anonim selama 3 hari terakhir.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

Bagan operasi yang sering

Bagan pai operasi yang digunakan selama 3 hari terakhir.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart

Bagikan melalui