Bagikan melalui

Kueri untuk tabel SigninLogs

  • Artikel

Untuk informasi tentang menggunakan kueri ini di portal Azure, lihat tutorial Analitik Log. Untuk REST API, lihat Kueri.

Semua peristiwa SiginLogs

Semua peristiwa masuk Azure.

SigninLogs
| project UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, AppId, ResourceDisplayName

Sumber daya diakses oleh pengguna

Mencantumkan sumber daya yang diakses untuk pengguna tertentu.

// Set v_Users_UPN with the UPN of the user of interest
let v_Users_UPN = "osotnoc@contoso.com";
SigninLogs
| where UserPrincipalName == v_Users_UPN
| summarize Count=count()  by ResourceDisplayName, AppDisplayName

Jumlah pengguna per Sumber Daya

Jumlah berbeda jika pengguna menurut sumber daya.

SigninLogs
| project UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, AppId, ResourceDisplayName
| summarize UserCount=dcount(UserPrincipalName) by ResourceDisplayName

Jumlah pengguna per Aplikasi

Jumlah pengguna yang berbeda menurut aplikasi.

SigninLogs
| project UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, AppId, ResourceDisplayName
| summarize UserCount=dcount(UserPrincipalName) by AppDisplayName

Alasan Masuk Gagal

Kueri mencantumkan alasan utama kegagalan masuk.

SigninLogs
| where ResultType != 0
| summarize Count=count() by ResultDescription, ResultType
| sort by Count desc nulls last

Tantangan MFA yang gagal

Menyoroti kegagalan masuk yang disebabkan oleh tantangan MFA yang gagal.

SigninLogs
| where ResultType == 50074
| project UserDisplayName, Identity,UserPrincipalName, ResultDescription,  AppDisplayName, AppId, ResourceDisplayName
| summarize FailureCount=count(), FailedResources=dcount(ResourceDisplayName), ResultDescription=any(ResultDescription) by UserDisplayName

Aplikasi Gagal mencoba masuk senyap

Upaya masuk aplikasi senyap gagal.

SigninLogs
| where ResultType == 50058
| project UserDisplayName, Identity,UserPrincipalName, ResultDescription,  AppDisplayName, AppId, ResourceDisplayName
| summarize FailureCount=count(), FailedResources=dcount(ResourceDisplayName), ResultDescription=any(ResultDescription) by UserDisplayName

Jumlah login yang gagal

Sumber daya dengan sebagian besar upaya masuk yang gagal.

SigninLogs
| where ResultType !=0
| summarize FailedLoginCount=count() by ResourceDisplayName
| sort by FailedLoginCount desc nulls last

Lokasi Masuk

Gagal dan berhasil melakukan sig in menurut lokasi sumber.

SigninLogs
| summarize Successful=countif(ResultType==0), Failed=countif(ResultType!=0) by Location

Masuk Ke Sumber Daya

Mencantumkan rincian masuk API.

SigninLogs
| where ResourceDisplayName == "Windows Azure Service Management API"
| project TimeGenerated, UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, Success=iff(ResultType==0, "Success", "Fail")